XL 2016 formule pour compter nombre valeurs différentes d'une plage

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 8 Novembre 2022

• #2

Bonjour Coucoud,
Essayez :

VB:

=SOMME(SI(FREQUENCE(C3:C10;C3:C10)>0;1))

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 8 Novembre 2022

• #3

Bonjour à tous,

Si tu as des données "texte", tu peux utiliser cette matricielle

VB:

=SOMME(SI(FREQUENCE(SI($C$3:$C$10<>"";EQUIV($C$3:$C$10;$C$3:$C$10;0));LIGNE($C$3:$C$10)-LIGNE($C$2));1))

JHA

 

Pièces jointes

• nb val colonne.xlsx

  11 KB · Affichages: 5

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 8 Novembre 2022

• #4

Bonjour à tous,
On peut aussi faire sans validation matricielle que ce soit sur des données texte ou nombre :

Code:

=SOMMEPROD(SIERREUR(1/NB.SI(E3:E10;E3:E10);""))

Cordialement

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 8 Novembre 2022

• #5

Bonjour à tous,

Ne possédant pas la version 365, il me faut valider la formule de @ALS35 (qui donne le bon résultat également) par les 3 touches malgré le sommeprod

VB:

=SOMME(SIERREUR(1/NB.SI(C3:C10;C3:C10);""))

JHA

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 8 Novembre 2022

• #6

Re,
Bien vu @JHA, l'ajout du SIERREUR impose la validation matricielle par Ctrl+Maj+Entrée.
Avec 365 la vie est plus simple et on oublie toutes ces vérifications.
Cordialement

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 9 Novembre 2022

• #7

Bonjour @ tous,

ALS35, ta formule est matricielle avec ou sans SIERREUR(), mais sous Excel pour Microsoft 365 la validation matricielle n'est plus indispensable.
En plus, sur une grande plage de données, ta formule renverra un faux résultat (avec des virgules), ce qui n'est pas le cas sur la formule de notre cher ami JHA.
On peut réécrire la formule de JHA :

VB:

=NB(1/FREQUENCE(SI(C3:C10<>"";EQUIV(C3:C10;C3:C10;0));LIGNE(INDIRECT("1:"&LIGNES(C3:C10)))))

@ valider par Ctrl+Maj+Entree
L'utilisation de la fonction EQUIV() est indispensable si les valeurs ne sont pas numériques.


Bien cordialement

 

Vote positif 0 Vote négatif

A

ALS35

XLDnaute Impliqué

• 14 Novembre 2022

• #8

Bonjour à tous,

@R@chid

R@chid à dit:

ALS35, ta formule est matricielle avec ou sans SIERREUR(), mais sous Excel pour Microsoft 365 la validation matricielle n'est plus indispensable.

Cliquez pour agrandir...

Diantre, aurais-je dit le contraire ??

R@chid à dit:

En plus, sur une grande plage de données, ta formule renverra un faux résultat (avec des virgules), ce qui n'est pas le cas sur la formule de notre cher ami JHA.

Cliquez pour agrandir...

Intéressant, mais peux-tu préciser ton propos, parce que sans exemple ... (enfin si les temps de calculs ne sont pas trop prohibitifs)
Cordialement

 

Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc

Supporter XLD

• 14 Novembre 2022

• #9

Surtout pour vous saluer tous ,

VB:

=SOMMEPROD(--SIERREUR(EQUIV(C3:C10;C3:C10;0)=LIGNE(C3:C10)-LIGNE(C$3)+1;0))

 

Vote positif 0 Vote négatif