formule plus limpide ? et nom d'onglet

[hellle]

Bonjour !
Merci pour tout ce que vous m'avez déjà apporté sans même que je n'ai à poser de questions... jusqu'à aujourd'hui.
J'ai débuté dans excel il y a 4-5 mois, aussi suis-je toute fière d'avoir trouvé cette formule qui fonctionne, mais dont j'ai comme l'impression qu'elle pourrait être... plus légère, non ? La voici :

=SI(NON(ESTNA(INDEX(G$5:G$32;EQUIV(L43;G$5:G$32;0))));DECALER(INDEX(G$5:G$32;EQUIV(L43;G$5:G$32));0;2);SI(INDEX(AH$5:AH$32;EQUIV(L43;AH$5:AH$32;0));DECALER(INDEX(AH$5:AH$32;EQUIV(L43;AH$5:AH$32));0;1);"FAUX"))
Il s'agit de récupérer automatiquement des liaisons entre un planning source construit sur 28 jours, et un planning calendaire, qui lui, sert de base de calcul à des compteurs.

D'autre part, je cherche si il y a moyen de nommer les onglets de façon "intuitive" pour les utilisateurs lambda (ces noms pouvant évoluer au fil des années), mais de conserver la dénomination "feuille 1" etc... pour les liaisons d'un classeur à l'autre ?
J'ai bien consulté un lien de ce site concernant les noms locaux et globaux, mais j'avoue que la traduction automatique n'aide pas beaucoup à la compréhension !😛

Merci à vous d'avance !

 

[JNP]

Re : formule plus limpide ? et nom d'onglet

Bonjour Hellle 🙂,
Pour la formule, je suis désolé, mais ce n'est pas ma spécialité 😱...
Pour le référencement des onglets, je ne pense pas que dans les formules tu puisses faire référence au nom absolu de la feuille (mais qui sait, quelqu'un d'autre aura peut-être une solution). Via VBA, tu as le choix entre Name (nom de l'onglet) et CodeName (nom de la feuille en temps qu'objet). Il est vrai que la référence à l'onglet est modifiée dans les formules automatiquement, même pour les références dans un autre classeur, à condition que les 2 classeurs soient ouverts (ce qui logiquement devrait être le cas pour la mise à jour des liaisons). Par contre, effectivement, si ce qui t'intéresse, c'est le récap de classeurs qui sont ouverts seuls, le risque de perdre les liaisons est important. Pour contourner le problème, tu peux jeter un oeil à ce fil https://www.excel-downloads.com/threads/interdire-de-renommer-un-onglet.117213/
Bonne journée 😎

 

[Monique]

Re : formule plus limpide ? et nom d'onglet

Bonjour,

Si j'ai bien compris

A la place de
=NON(ESTNA(INDEX(G$5:G$32;EQUIV(L43;G$5:G$32;0))))
plus simple comme ça :
=ESTNUM(EQUIV(L43;G$5:G$32;0))
plus court :
=NB.SI(G$5:G$32;L43)

A la place de Decaler(Réf;0;2)
INDEX(I$5:I$32;EQUIV(L43;G$5:G$32;0))
ou bien
=INDEX(G$5:I$32;EQUIV(L43;G$5:G$32;0);3)
si tu veux du Decaler :
=DECALER(G$4;EQUIV(L43;G$5:G$32;0);2)

En fin de compte, ça donnerait :
=SI(NB.SI(G$5:G$32;L43);INDEX(I$5:I$32;EQUIV(L43;G$5:G$32;0));SI(NB.SI(AH$5:AH$32;L43);INDEX(AI$5:AI$32;EQUIV(L43;AH$5:AH$32;0));"FAUX"))

 

[hellle]

Re : formule plus limpide ? et nom d'onglet

Merci à tous deux de vos réponses rapides et efficaces !

JNP : j'avais remarqué que les classeurs concernés devaient être ouverts pour toute modif, mais je n'y avais pas pensé pour le nom d'onglet !
Par ailleurs, tu appuies juste là où ça fait mal ( 😀 ) : en effet, une macro actualisant les liaisons à l'ouverture du fichier source serait un réel soulagement !! ( = une vingtaine de fichiers source, et pour chacun, environ 15 fichiers de destination qui, hors l'actualisation des liaisons, ont vocation à n'être ouverts que par les utilisateurs...)

Monique : non seulement tu as fort bien tout compris, mais ta formule est lumineuse, 🙂
...et ne donne pas la migraine comme la mienne 🙁
Les possibilités d' " index(equiv " me semblent d'un coup nettement plus intéressantes...
Par contre, je ne comprends pas "DECALER(G$4...". Si j'osais, je te demanderais bien une petite explication supplémentaire 😱

Bonne soirée à tous deux !

 

[Monique]

Re : formule plus limpide ? et nom d'onglet

Bonjour,

DECALER(Réf ; nb de lignes ; nb de colonnes)

Tu pars de G4
Tu descends G4:G32 jusqu'à ce que tu trouves le contenu de L43
Tu vires à droite de 2 colonnes
Et tu es arrivée

Le nb de lignes à "descendre" :
EQUIV(L43;G$5:G$32;0)

 

[hellle]

Re : formule plus limpide ? et nom d'onglet

Pardon, Monique, d'être aussi nulle 😱 ... en fait, ce que je ne comprends pas, c'est de devoir décaler à partir de G4 pour cette formule imbriquée(même si je vois bien qu'en partant de G5, le résultat est faux).
Pourtant, dans la fonction "DECALER" seule, la cellule de référence est bien la cellule du décalage, et non celle qui précéde... C'est là dessus que je bloque.


Par ailleurs, si quelqu'un a une lumière concernant la nomination apparente d'un onglet, et l'utilisation de son nom absolu pour les liaisons, je suis toujours preneuse 😉

 

[JNP]

Re : formule plus limpide ? et nom d'onglet

Re 🙂,

Par ailleurs, si quelqu'un a une lumière concernant la nomination apparente d'un onglet, et l'utilisation de son nom absolu pour les liaisons, je suis toujours preneuse 😉

Via VBA ?
Bonne journée 😎

 

[hellle]

Re : formule plus limpide ? et nom d'onglet

N'y connaissant quick aux macros (juste capable d'en enregistrer une, quand elle veut bien fonctionner droit, ou d'en rentrer une "toute cuite" 😱 ). Je ne demande qu'à apprendre, mais bon, je crains qu'il ne me faille un peu de temps !

Dans ce cas de figure, une macro permettrait-hellle 😀 d'utiliser le nom absolu des feuilles source, dans les formules des classeurs de destination (et chemins d'accés) ?
Je pose la question, car je n'ai pas la moindre idée du comment ça pourrait fonctionner ?

 

[Monique]

Re : formule plus limpide ? et nom d'onglet

Bonjour,

Pourtant, dans la fonction "DECALER" seule, la cellule de référence est bien la cellule du décalage, et non celle qui précéde... C'est là dessus que je bloque.

On peut partir de cette cellule ou de celle du dessous.
Si on part de celle du dessous :
Tu pars de G5
Tu descends (ou tu ne descends pas) G5:G32 jusqu'à ce que tu trouves le contenu de L43
Tu vires à droite de 2 colonnes
Et tu es arrivée

Le nb de lignes à "descendre" :
EQUIV(L43;G$5:G$32;0) - 1

Si c'est en G5 que se trouve le contenu de L43,
EQUIV(L43;G$5:G$32;0) - 1 = 0