Formule Multi Critéres et intervalle de plage

[Armand11]

Bonjour à toute la communauté Excel Download,

J'ai besoin de trouver la meilleure formule à mon problème: Je souhaite obtenir le montant des charges d'un tableau d'emprunt, 1: par exercice en fonction de ma date d'arrêté que j'ai choisi 2: prenant en compte les intérêts courus de fin de période éventuellement etc...

J'ai illustré ma demande par le biais de ce tableau. en soumettant les 2 hypothèses de résultat attendu au 30/09/2017 et au 30/09/2018...

j'ai développé mes formules pour les ICNE mais ma demande étant plus dense au niveau conditionnel que je n'arrive pas à l'appréhender correctement.

 

[CISCO]

Bonsoir

Est-ce qu'il faut tenir compte de la date de début, de la date de fin, des deux ?

@ plus

 

[Armand11]

Bonjour CISCO, Désolé pour mon retard je suis en cloture annuelle et en pleine liasse fiscale...
Pour mn problème il faut tenir compte des deux dates, c'est comme si je prenais l'évolution de mon compte de charge cumulé en fonction de la date d'arrêté avec bien entendu la prise en compte des ICNE (int courus)...Mes deux hypothèses en colonne M & O reflètent bien mon but à atteindre...

Merci encore CISCO cette fois ci je guette ta réponse... désolé

 

[Dugenou]

Bonjour,
en M8 : =SI(ET(INDEX($F$2:$F$4;EQUIV($C$4;$G$2:$G$4;0))<B8;C8<$C$4);G8;SI(H8>0;I8))
avec en H8 : =SIERREUR(SI(ET($C$4>B8;$C$4<C8);($C$4-B8);SI(ET(INDEX($F$2:$F$4;EQUIV($C$4;$G$2:$G$4;0))>B8;INDEX($F$2:$F$4;EQUIV($C$4;$G$2:$G$4;0))<C8);C8-INDEX($F$2:$F$4;EQUIV($C$4;$G$2:$G$4;0))+1;""));"")
La partie INDEX($F$2:$F$4;EQUIV($C$4;$G$2:$G$4;0)) pourrait être nommée pour faciliter la lecture

Cordialement

Edit : il manque une autre modif : je fignole la pj

 

[Dugenou]

Volà la pj complète
il y a aussi en I8 : =SI(ET($C$4>B8;$C$4<C8);(D8*E8*H8/360);0)
la feuille copiée contient la même formule mais avec la partie INDEX($F$2:$F$4;EQUIV($C$4;$G$2:$G$4;0)) nommée Debut Arrete (formules/gestionnaire de nom

Cordialement

 

[job75]

Bonsoir Armand11, CISCO, Dugenou,

Voyez le fichier joint et cette formule en H8 :

=MAX(MIN(C8;C$4)-MAX(B8;DATE(ANNEE(C$4)-1;MOIS(C$4);JOUR(C$4)));)

PS : vous calculez le taux journalier en divisant le taux annuel par 360, c'est légal ça ?

Alors pour le calcul du nombre de jours peut-être faudrait-il utiliser JOURS360 plutôt que soustraire les dates...

A+

 

[job75]

Re,

Dans ce fichier (2) on utilise JOURS360, les résultats sont assez différents.

A+

 

[job75]

Bonjour le forum,

Les solutions précédentes supposent que l'heure de début et de fin est 24:00.

Si l'heure de début est 00:00 et l'heure de fin 24:00 il faut ajouter 1 jour.

Fichiers (1 bis) et (2 bis).

Bonne journée.

 

[Armand11]

Bonjour CISCO, JOB75 et DUGENOU,
Je regarde vos tableaux et reviens vers vous rapidement en tout cas merci d'avance.
A tout à l'heure....

 

[Armand11]

Je viens d'analyser votre présentation, c'est impressionnant en ce sens où j'était partie pour vouloir créer une et une seule formule (une hérésie de ma part ....) alors que vous avez décomposé en calculant les jours décomptés en fonction de chaque exercice ! je n'avais pas pensé à réfléchir de la sorte... En tout cas c'est formidable car cela me permettra en un seul clic de calculer à n'importe quel moment le montant de mes charges financières....
EN REPONSE à JOB75: oui c'est légal les 360 jours, dans notre milieu financier on applique ce nombre de jours. Il peut être contractuel également c'est à dire que l'on peut spécifier 360 ou 365 jours.... Tout est possible sur les marchés financiers....

Merci infiniment à vous tous et la communauté d'EXCEL DOWN LOAD, grâce à votre aide et vos astuces je me perfectionne également et remodèle vos formules en fonction de mes besoins d'hier, d'aujourd'hui et de demain.... Bravo à tous vous n'imaginez pas à quel point cela va me faire en temps d'analyse, d'efficacité et de précision .... Bon week end à vous tous , à très bientôt !

Armand

 

[job75]

Re,

On peut tout rassembler en une seule cellule, G2 et suivantes.

Avec cette jolie formule matricielle, à valider par Ctrl+Maj+Entrée :

=SOMME(D$8:D$16*E$8:E$16*SI(SI(C$8:C$16<F2;C$8:C$16;F2)>SI(B$8:B$16>DATE(ANNEE(F2)-1;MOIS(F2);JOUR(F2));B$8:B$16;DATE(ANNEE(F2)-1;MOIS(F2);JOUR(F2)));SI(C$8:C$16<F2;C$8:C$16;F2)-SI(B$8:B$16>DATE(ANNEE(F2)-1;MOIS(F2);JOUR(F2));B$8:B$16;DATE(ANNEE(F2)-1;MOIS(F2);JOUR(F2))))/360)

Fichiers (3) et (3 bis).

A+

 

[CISCO]

Bonsoir à tous, Dugenou et Job75

Comme Dugenou et Job75 ont pris la relève, je pense que tu as de quoi faire, Armand11. Je suis un peu trop occupé en ce moment...

@ plus