Formule min,max,moyen d'une série (colonne)

[JJ1]

Bonjour,

J'ai commencé une "usine à gaz" pour obtenir le minimum, maximum et la moyenne de 4 nombres dans une colonne (ici B ) par séquence.
Auriez-vous dans votre trousse à outil une formule pour compléter mon tableau en B80😀83.
J'ai fait l'exemple du 0 manuellement.
La colonne A a été rajoutée pour explication mais n'existe pas dans mon tableau.
Merci de votre astuce.

Bon lundi

 

[job75]

Re : Formule min,max,moyen d'une série (colonne)

Bonjour JJ1,

Avec uniquement des formules je n'ai pas de solution.

Mais avec cette fonction macro pas de problème :

Function MATSERIE(plage As Variant, x As Variant)
Dim ub&, i&, j&, tablo&(), n&
plage = Application.Transpose(plage) 'matrice, plus rapide
ub = UBound(plage)
For i = 1 To ub
  If plage(i) = x Then
    For j = i To ub
      If plage(j) <> x Then Exit For
    Next
    ReDim Preserve tablo(n)
    tablo(n) = j - i
    n = n + 1
    i = j
  End If
Next
MATSERIE = tablo
End Function

On l'aura compris, elle renvoie une matrice utilisée dans les formules de la feuille de calcul.

Fichier joint.

A+

 

[job75]

Re : Formule min,max,moyen d'une série (colonne)

Re,

Une remarque : Application.Transpose n'accepte pas plus de 65536 lignes.

Dans ce cas utiliser :

Function MATSERIE(plage As Variant, x As Variant)
Dim ub&, i&, j&, tablo&(), n&
plage = plage 'matrice, plus rapide
ub = UBound(plage)
For i = 1 To ub
  If plage(i, 1) = x Then
    For j = i To ub
      If plage(j, 1) <> x Then Exit For
    Next
    ReDim Preserve tablo(n)
    tablo(n) = j - i
    n = n + 1
    i = j
  End If
Next
MATSERIE = tablo
End Function

A+

 

[JJ1]

Re : Formule min,max,moyen d'une série (colonne)

Re bonjour,
Je n'ai que peu de lignes, je vais utiliser ton premier code cet AM et voir à quoi ressemble cette matrice?
Encore merci à toi.

A+