Formule matricielle et fonction NB [Résolu]

[Hub3rt]

Bonjour à toutes et à tous,


Je souhaite utiliser la fonction suivante :

{=NB((Support_1!$B$2:$B$65535>=DATEVAL("01/01/13"))*(Support_1!$B$2:$B$65535<=DATEVAL("31/01/13"))*(Support_1!A$2:A$65535))}

Seulement, cela me ressort un résultat complètement incohérent, à savoir 65534. Ce qui correspond en gros à la plage que je lui ai donné en 3ème paramètre...

Quelqu'un aurait-il une idée ?

Merci pour vos retours.

 

[genialo4000]

Re : Formule matricielle et fonction NB

Bonjour,

J'en ai une toute simple : remplace NB par SOMMEPROD (formule normale, pas matricielle)

Ca marche ?

 

[JCGL]

Re : Formule matricielle et fonction NB

Bonjour à tous,

Peux-tu essayer :

=SOMMEPROD(($B$2:$B$65535>=DATEVAL("01/01/13"))*('F1'!$B$2:$B$65535<=DATEVAL("31/01/13"))*'F1'!A$2:A$65535)

A+ à tous

 

[Hub3rt]

Re : Formule matricielle et fonction NB

Bonjour,

Le problème avec un SOMMEPROD est qu'il m'additionne les valeurs dans les cellules, alors que je souhaiterai simplement compter le nombre de lignes pleines entre les dates données.

 

[Monique]

Re : Formule matricielle et fonction NB

Bonjour,

Un essai

=SOMMEPROD(($B$2:$B$65535>="1/1/13"*1)*($B$2:$B$65535<="31/1/13"*1)*($A$2:$A$65535<>""))

Avec NB() mais en validant par ctrl, maj et entrée :
=NB(SI(($B$2:$B$65535>="1/1/13"*1)*($B$2:$B$65535<="31/1/13"*1)*($A$2:$A$65535<>"");1))

Tu as besoin de tant de lignes ?

 

[JCGL]

Re : Formule matricielle et fonction NB

Bonjour à tous,

Je pense que NB.SI.ENS() est disponible sous XL 2007.
Choix des bornes.

A+ à tous

 

[Hub3rt]

Re : Formule matricielle et fonction NB

Bonjour,

Un essai

Avec NB() mais en validant par ctrl, maj et entrée :
=NB(SI(($B$2:$B$65535>="1/1/13"*1)*($B$2:$B$65535<="31/1/13"*1)*($A$2:$A$65535<>"");1))

Tu as besoin de tant de lignes ?

Je ne sais pas de combien de ligne je peux avoir besoin, le tout étant d'en prendre un maximum.

En revanche merci pour le (NB(SI)) ça fonctionne au poil en forme matricielle.

Bonjour à tous,

Je pense que NB.SI.ENS() est disponible sous XL 2007.
Choix des bornes.

A+ à tous

Excellent ! Cela m'évite même les problèmes que je rencontre après en mode matricielle avec les macros !

Merci encore à vous toutes/tous pour votre précieuse aide. 😀