Formule matricielle avec deux conditions

[poulie]

Bonjour à tous,

J'ai donc un tableau (colonnes A à F). Ainsi qu'un second tableau (colonnes J à N).
Je souhaiterais extraire des données du premier tableau dans le second tableau selon 2 conditions (cellules H3 et H6).
J'arrive à extraire des données mais qu'avec la première condition

=INDEX(B$2:B$100;PETITE.VALEUR(SI($A$2:$A$100=$H$3;LIGNE($A$2:$A$100)-1);LIGNE(G1)))

J'ai testé avec la fonction ET mais sans succés.

Pourriez-vous donc me dépanner ? L'idéal serait avec la formule ci-dessus (enrichit de la seconde condition).

Merci

 

[chris]

Re : Formule matricielle avec deux conditions

Bonjour


La valeur recherchée n'existe pas donc Index renvoie une erreur à gérer.

Edit : correction

 

[david84]

Re : Formule matricielle avec deux conditions

Bonjour,
pour la condition "ET" en matriciel, utiliser le "*", donc :

=INDEX(B$2:B$100;PETITE.VALEUR(SI(($A$2:$A$100=$H$3)*($E$2:$E$100=$H$6);LIGNE($A$2:$A$100)-1);LIGNE(G1)))

A+
Edit : bonjour Chris

 

[poulie]

Re : Formule matricielle avec deux conditions

Bonjour chris, david84,

Merci pour vos réponses.

Sur le même principe ( avec le signe multiplication * ), je peux effectuer une recherche avec 1, 2 ou plus de conditions ?.

 

[david84]

Re : Formule matricielle avec deux conditions

Re

Sur le même principe ( avec le signe multiplication * ), je peux effectuer une recherche avec 1, 2 ou plus de conditions ?

oui
"*" signifie "et"
"+" signifie "ou"*
tu peux même conjuguer les 2 au sein d'une même formule :

(plage1=cond1)*(plage2=cond2)*((plage3=cond3)+(plage4=cond4))

A+

 

[chris]

Re : Formule matricielle avec deux conditions

Bonjour
Salut à David

J'avais corrigé ma proposition de multiplication car cela ne gérait pas l'erreur

Pour gérer l'erreur

=SI(ESTERREUR(PETITE.VALEUR(SI(($A$2:$A$100=$H$3)*($E$2:$E$100=$H$6);LIGNE($A$2:$A$100)-1);LIGNE(G1)));"";INDEX(B$2:B$100;PETITE.VALEUR(SI(($A$2:$A$100=$H$3)*($E$2:$E$100=$H$6);LIGNE($A$2:$A$100)-1);LIGNE(G1))))

à valider en matricielle

 

[poulie]

Re : Formule matricielle avec deux conditions

david84, chris,

Merci encore à vous pour cet apprentissage.

Bonne journée.