Microsoft 365 formule INDEX ( EQUIV

[dd_76]

Bonjour,

Besoin d'aide sur une formule : j'ai voulu utiliser la combinaison de la formule INDEX et EQUIV mais le résultat n'est pas concluant.
je vous ramener le taux horaire (inscrit dans une table sur un autre onglet) en fonction de deux critères (catégorie salarié et année)

ci joint le fichier exemple
besoin de vous
merci

 

[sylvanu]

Bonjour DD,
Un essai en PJ avec :

=SIERREUR(INDEX(BDD_TXMOYEN[Taux horaire (moyen)];EQUIV(G2&L2;BDD_TXMOYEN[Catégorie]&BDD_TXMOYEN[Année];0));"")

A valider par Maj+Ctrl+Entrée sur les anciennes versions XL, inutile sur .365.
A noter que j'ai mis la formule en colonne Z, je ne sais pas s'il faut la mettre en Z ou en AA.

 

[sylvanu]

Re,
Ou encore plus simple avec :

=SOMME.SI.ENS(BDD_TXMOYEN[Taux horaire (moyen)];BDD_TXMOYEN[Catégorie];BDD!G2;BDD_TXMOYEN[Année];[Année Formation])

Format personnalisé : 0.00;; pour éviter l'affichage de valeurs nulles.

 

[fanfan38]

Bonjour
La formule c'est
=INDEX(BDD_TXMOYEN[Taux horaire (moyen)]; EQUIV([@Catégorie] & [@[Année Facturation]]; BDD_TXMOYEN[Catégorie] & BDD_TXMOYEN[Année]; 0))
Mais tu n'as pas Ouvriers dans table...
A+ François

 

[ALS35]

Bonjour à tous,
Deux autres formules possibles, valables à partir d'Excel 2021 :

=FILTRE(BDD_TXMOYEN[Taux horaire (moyen)];(BDD_TXMOYEN[Catégorie]=[@Catégorie])*(BDD_TXMOYEN[Année]=[@[Année Formation]]);"")
ou
=RECHERCHEX([@Catégorie]&[@[Année Formation]];BDD_TXMOYEN[Catégorie]&BDD_TXMOYEN[Année];BDD_TXMOYEN[Taux horaire (moyen)];"")

Cordialement

 

[Nain porte quoi]

merci du retour
il n'y a pas une autre solution que d'utiliser une formule matricielle?
car ce fichier est mis à disposition auprès de personne qui ne maitrise pas excel et ne feront jamais la manipulation

merci

Hello,

la 2ème formule de Sylvanu (✋ hello) avec SOMME.SI.ENS n'a pas besoin de validation matricielle bien que ce soit une formule matricielle, mais si vous avez des utilisateurs qui savent manipuler les fonction INDEX/EQUIV c'est qu'ils ne sont pas des débutants