formule excel - nbre occurence ss doublon

[VBA_DEAD]

Bonjour le forum

je bloque sur un calcul de frequences/occurences ss doublons

question:
combien de comptes existents par mois sachant que pour chaque mois j`ai le compte qui apparait plusieurs fois. (compter ss doublon et par mois)

Nombre de fois que le compte apparait par mois

j`ai fait un exemple avec les resultat attendu.

Merci de votre aide car je tourne en rond avec les countif, sumif et sumproduct

cordialement

bonjour a Monique au passage.... 😉

VBA_DEAD

 

[Monique]

Re : formule excel - nbre occurence ss doublon

Bonjour,

En nommant Date et Cpte A3:A50 et B8:B50,
en F11 :
=SOMME((FREQUENCE(SI(Date=$E11;EQUIV(Cpte;Cpte;0));LIGNE($A$1:$A$50))>0)*1)
Formule matricielle, à valider par ctrl, maj et entrée

En nommant Montt la plage C8:C50,
en G11 :
=SOMMEPROD((Date=$E11)*1;Montt)/F11

Après, je ne comprends rien.
Des tranches de quoi ?
Pourquoi est-ce que tu dis qu'il y a deux (comptes), 142 et 152, dans la tranche qui va de 400 à l'infini ?
Si les tranches sont des tranches du montant,
le montant max de janvier est de 310, rien à voir avec supérieur à 400
et c'est le cpte 1452, rien à voir avec 142 et 152
Moralité : rien compris à l'histoire

 

[Monique]

Re : formule excel - nbre occurence ss doublon

Re,

Suite

Le tableau du bas (j'avais renoncé à comprendre)

La formule en F11 modifiée (s'il y a d'autres dates que les 1ers de chaque mois)

Le tableau du haut, si les tranches sont des tranches du montant.

 

[JeanMarie]

Re : formule excel - nbre occurence ss doublon

Bonjour VBA_DEAD, Monique

Ayant la même formule proposée par Monique sur le calcul du nombre d'occurrences de compte dans un mois.

Je n'ai pas encore trouvé l'autre formule qui calculerait le nombre de compte dont la somme dans un mois serait entre 0 à 100; 101 à 200; 201 à 300; 301 à 400; et au-delà. Je pense qu'il faut passer par une colonne intermédiaire.

@+Jean-Marie

 

[VBA_DEAD]

Re : formule excel - nbre occurence ss doublon

Bonjour Monique et Jeanmarie
merci pour votre aide tout d`abord.

j`ai regarde la premiere solution et ca ne macthe pas totalement

😛Our janvier, si on prend le compte 152, le montant que detien tce client est egale a 1040 donc je voudrais que le nombre 1 apparaisse pour un tranche comprise entre 1000 et 10000 par exemple

enfait l`objectif est de faire un rapport qui permet de voir le montant achete par client en moyenne (d`ou le fait de sommer les 4 lignes deu comptes 152 pour janvier).
c pour faire des rapports de vente. Donc ds mon cas, j`ai 4 comptes differents (ca j`ai le bon resultat - merci) mais pour chaque compte, le montant detenu ne sort pas bien :
j`ai 1 compte qui a un montant de 210, 1 compte qui a 310, 1 compte qui a 1040 et n compte qui a 510.
donc en mettant mes tranches, faudrait que j`ai le nombre de comptes alloues au bon endroit. Il s`agit pas ds ma premiere question de faire la moyenne mais vraiment la somme par compte et de dire combine j`ai de comptes par tramche

je suis + clair?

merci pour votre aide?

je veux bien passer par une etape intermediaire! 🙂

VBA_DEAD

 

[Monique]

Re : formule excel - nbre occurence ss doublon

Bonjour,

Le tableau du haut revu et corrigé,
avec une colonne intermédiaire (le total par mois et par client)

 

[JeanMarie]

Re : formule excel - nbre occurence ss doublon

Bonjour

Voici ma proposition, avec une colonne supplémentaire.

Formule en G11 à valider les touches Ctrl+Shfit+Entrée

=SOMME((FREQUENCE(SI(MOIS($A$8:$A$46)=I19;EQUIV($B$8:$B$46;$B$8:$B$46;0));LIGNE(A1:A46))>0)*1)

Formule en H11

=SI(G11;SOMME.SI($A$8:$A$46;$F11;$C$8:$C$16)/$G11;0)

Formule I11, à valider part les touches Ctrl+SHift+Entrée, en ayant sélectionné au préalable la plage I11:M11

=SI(G11;TRANSPOSE(FREQUENCE(SI($A$8:$A$46=F11;D$8:D$46);I$10:L$10));0)

Formule en I20 à valider par les trois touches (à glisser vers la droite)

=SOMME((FREQUENCE(SI($A$8:$A$46=$F20;EQUIV($B$8:$B$46;$B$8:$B$46;0));LIGNE(A$1:A$46))=I$19)*1)

Pour la formule en colonne M, le comparateur de nombre est différent

=SOMME((FREQUENCE(SI($A$8:$A$46=$F20;EQUIV($B$8:$B$46;$B$8:$B$46;0));LIGNE(F$1:F$46))>M$19)*1)

Désolé, Monique je n'avais pas rafraîchit.

@+Jean-Marie

 

[VBA_DEAD]

Re : formule excel - nbre occurence ss doublon

Bonsoir Monique et Jean Marie

je regarde demain matin vos solutions.
ca sera super, j`en suis sur! 😉

merci encore et a demain
bonne nuit a tous

VBA_DEAD