XL 2013 Formule avec deux conditions entre 2 valeurs

CISCO

XLDnaute Barbatruc

• 9 Janvier 2018

• #2

Bonjour

Essayes avec

Code:

=SI(((220<=H25)*(H25<230))+((250<H25)*(H25<=280));1;SI((230<=H25)*(H25<=250);1,5;0))

en positionnant autrement les signes = si besoin est.

@ plus

 

Vote positif 0 Vote négatif

N

Noel Bedard

XLDnaute Occasionnel

• 9 Janvier 2018

• #3

CISCO à dit:

Bonjour

Essayes avec

Code:

=SI(((220<=H25)*(H25<230))+((250<H25)*(H25<=280));1;SI((230<=H25)*(H25<=250);1,5;0))

en positionnant autrement les signes = si besoin est.

@ plus

Cliquez pour agrandir...

WOW!, j'aime bien votre raisonnement CISCO, moi j'airais plutôt pensé comme suit:

Code:

=SI(ET(H25<220;H25>280);0;SI(ET(H25>=230;H25<=250);1,5;SI(ET(H25>=220;H25<=280);1;0)))

J'ai comparé les deux choix et le résultat est le même, si vous pourriez m'éclaircir sur votre façon de faire, moi je n'ai vraiment pas d'expérience sur Excel.

Merci et Bravo pour votre excellent travail

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 9 Janvier 2018

• #4

Bonjour à tous,

On peut raccourcir la formule de Noël Bedard

Code:

=SI(OU(H25<220;H25>280);0;SI(ET(H25>=230;H25<=250);1,5;1))

JHA

 

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 9 Janvier 2018

• #5

Bonsoir à tous, JHA et Noel

Noel Bedard à dit:

...et le résultat est le même, si vous pourriez m'éclaircir sur votre façon de faire, moi je n'ai vraiment pas d'expérience sur Excel.

Merci et Bravo pour votre excellent travail

Cliquez pour agrandir...

Ta méthode n'est pas mal, non plus, et, plus courte, une fois simplifiée comme l'a fait JHA.

Pour comprendre la mienne, il suffit de constater, ou de savoir qu'en logique, le * peut très souvent remplacer le ET, et le + le OU.

@ plus

 

Vote positif 0 Vote négatif

N

Noel Bedard

XLDnaute Occasionnel

• 9 Janvier 2018

• #6

Merci beaucoup, * = et, + = OU, nouveau pour moi. Je me demandais pourquoi qu'il effectue un calcul comme ça...

Et effectivement JHA c'est bien mieux abrégée et plus facile à interpréter.
Merci encore.

 

Vote positif 0 Vote négatif

CISCO

XLDnaute Barbatruc

• 9 Janvier 2018

• #7

Bonjour

Pour le fun, une autre manière de faire

Code:

=SIERREUR(CHOISIR(EQUIV(H25;{220;230;250;280};1);1;1,5;1);0)

ou encore

Code:

=CHOISIR(EQUIV(H25;{0;220;230;250;280};1);0;1;1,5;1;0)

formules à peaufiner en fonction de ce qu'on veut avoir dans les cas limites.

@ plus

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 10 Janvier 2018

• #8

Bonjour à tous,
Bonjour Cisco🙂

Comme le dit CISCO, pour se rapprocher de ta demande il faut adapter:

Code:

=SIERREUR(CHOISIR(EQUIV(H25;{220;230;250,1;280,1};1);1;1,5;1);0)

et

Code:

=CHOISIR(EQUIV(H25;{0;220;230;250,1;280,1};1);0;1;1,5;1;0)

JHA

 

Vote positif 0 Vote négatif