Formule après la dernièere valeur trouvé

[Temjeh]

Bonjour et merci d'avance

Je cherche en formule excel (pas VBA) la suite qui se trouve après le dernier "/"

J'ai après le premier rencontrer mais pas après le dernier rencontrer.

EX: Ce lien n'existe plus j'aimerais le jjj.zip

Pas droite 7 car la fin peut changer de longeur

Merci de votre temps

 

[CISCO]

Re : Formule après la dernièere valeur trouvé

Bonjour

Pour le moment, ton fichier n'est pas accessible. Et puis, cela serait tellement mieux avec un petit fichier exemple bien choisi directement sur le forum.

@ plus

 

[Temjeh]

Re : Formule après la dernièere valeur trouvé

Voici un démo plus clair

L'adresse n'était pas un lien mais juste une idée de ce que je voulais faire 🙂
Isolé le nom après le dernier /

Merci à tous

Temjeh

 

[david84]

Re : Formule après la dernièere valeur trouvé

Bonsoir, salut Cisco,
à tester :

=STXT(B3;TROUVE("*";SUBSTITUE(B3;"/";"*";NBCAR(B3)-NBCAR(SUBSTITUE(B3;"/";""))))+1;99)

A+

 

[CISCO]

Re : Formule après la dernièere valeur trouvé

Bonsoir

Essayes avec

=DROITE(B3;NBCAR(B3)-MAX(SI(STXT(B3;LIGNE(INDIRECT("1:"&NBCAR(B3)));1)="/";LIGNE(INDIRECT("1:"&NBCAR(B3))))))

en matriciel, donc à valider avec Ctrl+maj tempo+entrer (Il doit y avoir des accolades devant et derrière la formule).

@ plus

P.S : Bonsoir David84. J'oublie trop souvent le dernier paramètre de la fonction SUBSTITUE, bien utile ici pour éviter une matricielle.

 

[Victor21]

Re : Formule après la dernièere valeur trouvé

Bonjour, Temjeh.

Peut-être :

=SI(ESTERREUR(TROUVE("/";B2));B2;STXT(B2; TROUVE(CAR(1);SUBSTITUE(B2;"/";CAR(1); NBCAR(B2)-NBCAR(SUBSTITUE(B2;"/";""))))+1; NBCAR(B2)))

Validation conventionnelle.

Edit : Bonjour, CISCO 🙂

 

[job75]

Re : Formule après la dernièere valeur trouvé

Bonjour Temjeh, CISCO, Patrick,

Voyez le fichier joint et cette formule :

=STXT(B3;TROUVE("µ";SUBSTITUE(B3;"/";"µ";NBCAR(B3)-NBCAR(SUBSTITUE(B3;"/";))))+1;9^9)

Edit : salut David, je ne t'avais pas vu 🙄

A+

 

[CISCO]

Re : Formule après la dernièere valeur trouvé

Bonsoir à tous

Et bien, tu as le choix, Temjel 🙂 même si les propositions de David84 et de Job75 se ressemblent beaucoup.

@ plus

 

[Victor21]

Re : Formule après la dernièere valeur trouvé

Re, Bonjour Gérard, David 🙂

Puisqu'Excel 2010 :

=SIERREUR(STXT(B2; TROUVE(CAR(1);SUBSTITUE(B2;"/";CAR(1); NBCAR(B2)-NBCAR(SUBSTITUE(B2;"/";""))))+1; NBCAR(B2));B2)

 

[Temjeh]

Re : Formule après la dernièere valeur trouvé

OUFFFF

Après les 4 tests, les 4 sont exellentes

Maintenent si possible une formule aléatoire pour m'aider à choisir

ALÉA(david84 ,CISCO,job75,Victor21)

A+
Merci beaucoup pour votre temps

Temjeh

 

[Victor21]

Re : Formule après la dernièere valeur trouvé

Re, Temjeh.

En fait, tu n'as que deux possibilités, celles de Gérard de David et la mienne étant identiques (à un " ", "*","µ" près) 🙂