fonctions si(et(

[titiraf]

Bonjour,
j'ai du mal à construire une formule imbriquée avec si(et.
- entre 4 et 8 la cellule vaut 0.25
- entre 9 et 12 la cellule vaut 0.5
- si c'est supérieur à 12 alors la cellule vaut 1

merci de votre aide
Cordialement
T

 

[wilfried_42]

Re : fonctions si(et(

bonjout titiraf

=si(valeur>=4;si(valeur>8;si(valeur>12;1;0);,5);,25)

 

[JHA]

Re : fonctions si(et(

Bonjour Titiraf, le forum,

avec teste de valeur en B9:

=SI(ET(B9>=4;B9<=8);0,25;SI(ET(B9>=9;B9<=12);0,5;SI(B9>12;1;"En dehors des limites")))

JHA

 

[stemsy]

Re : fonctions si(et(

Bonjour ,

=SI(A1>12;1;SI(ET(A1<=12;A1>=9);0,5;SI(ET(A1<=8;A1>=4);0,25;"hors règles")))

Bon courage
Stéphane

 

[jeanpierre]

Re : fonctions si(et(

Bonjour titiraf, Wilfriend, JHA,

Peut-être plus court avec : =SI(A1>12;1;SI(A1>=9;0,5;0,25))

Bonne soirée.

Jean-Pierre

 

[JHA]

Re : fonctions si(et(

Bonjour JP , Wilfried,

Attention, le calcul débute à 4 et non à 0.

JHA

 

[titiraf]

Re : fonctions si(et(

Merci à tous pour votre aide si rapide.
Vraiment sympa de votre part.
Merci
Thierry

 

[jeanpierre]

Re : fonctions si(et(

Re, JHA,

Merci pour cette précision que j'avais occultée...

=SI(E11>12;1;SI(E11>=9;0,5;SI(E11<4;"hors limites";0,25))), ce qui n'est plus très court, il est vrai.

Bonne soirée.

Jean-Pierre

 

[Tibo]

Re : fonctions si(et(

Bonsoir à tous,

histoire de participer au jeu de la plus courte 😀 :

=(A1>=4)*0.25+(A1>=9)*0.25+(A1>=12)*0.5

@+

 

[Cousinhub]

Re : fonctions si(et(

Bonsoir à tous,
je peux jouer, moi aussi?

=0,25*((A1>=4)+(A1>=9)+2*(A1>12))

6 de moins que Tibo 😉

 

[wilfried_42]

Re : fonctions si(et(

Bonsoir à tous

Joli concours, 1 de moins en mettant >8 plutot que >=9

 

[Cousinhub]

Re : fonctions si(et(

Bonsoir, wilfried
d'accord, mais 8.5?

une autre :

=((A1>=4)+(A1>=9)+2*(A1>12))/4

-3

 

[wilfried_42]

Re : fonctions si(et(

re:

Dans l'enoncé, entre 4 et 8; entre 9 et 12, et > 12

Si nous n'avons pas affaire à des entiers, il y a un trou entre 8 et 9 ce qui ne me parait pas logique

Bonne soirée