XL pour MAC Fonction SI avec condition (Excel 2011)

Laffitte · 30 Novembre 2018

Bonjour les excelleurs,
Je suis tout neuf dans le forum et je viens vers vous car je n'arrive pas à faire ce que je veux avec mon fichier excel et après 2/3 jours de test/recherche je sature...

Je suis en train de créer un tableau pour remplir directement des notes en fonction de condition de résultats et j'ai presque réussi mais il me reste un petit détail ou je bloque...
Je m'explique, en fonction de résultat de pourcentage (de course) de mes élèves, une note leur est attribué (ça c'est bon !!) mais j'aimerai rajouter une condition (attribution des points différemment) en fonction de si l'élève est une fille ou un garçon et c'est là que je coince...

Voici ma formule:

=SI(D34>13;4;SI(D34>11;3;SI(D34>9;2;SI(D34<=9;1)))) pour les Filles

=SI(D34>15;4;SI(D34>12;3;SI(D34>=10;2;SI(D34<=10;1)))) pour les Garçons

Mais j'aimerai les combinés avec la reconnaissance du F ou M d'une autre case directement, est-ce possible?
Et est ce que j'ai été assez claire?...
Je met l'exemple de mon tableau.

En gros je voudrais: Si F dans C34 alors application de ma Formule pour les Filles
et Si M dans C34 alors application de ma Formule pour les Garçons.

Merci d'avance pour votre aide,
Et vive Excel..!!
Thibaud

M12 · 30 Novembre 2018

Bonjour,

Teste ceci

Code:

=SI(C34="";"";SI(C34="F";SI(D34>13;4;SI(D34>11;3;SI(D34>9;2;SI(D34<=9;1))));SI(D34>15;4;SI(D34>12;3;SI(D34>=10;2;SI(D34<=10;1))))))

job75 · 30 Novembre 2018

Bonjour Laffitte, bienvenue sur XLD, salut M12,

La formule de M12 prend 271 octets en mémoire, celle-ci en prend 169 :

Code:

=SI((C34<>"M")*(C34<>"F");"";SI(D34>13+2*(C34="M");4;SI(D34>11+(C34="M");3;SI(D34>9+(C34="M");2;1))))

Les fonctions SI "pèsent" lourd...

A+

M12 · 30 Novembre 2018

Re bonjour
Salut Job75
La formule de Job75 prend 169 octets en mémoire, celle-ci en prend 155 :

Code:

=SI(C34="";"";SI(D34>13+2*(C34="M");4;SI(D34>11+(C34="M");3;SI(D34>9+(C34="M");2;1))))

job75 · 30 Novembre 2018

Re,

M12 à dit:
La formule de Job75 prend 169 octets en mémoire, celle-ci en prend 155 :

Oui mais ton test initial SI(C34="" ne va pas, réfléchis 5 secondes...

A moins que "M" ou "F" soient entrés à l'aide d'une liste de validation

Laffitte · 30 Novembre 2018

Merci beaucoup pour vos réponse, j'ai l'impression qu'elles fonctionnent toutes!
Maintenant que ça marche je vais me pencher dessus pour les comprendre histoire d'être capable de les ressortir.

M12 · 30 Novembre 2018

job75 à dit:
Re,

Oui mais ton test initial SI(C34="" ne va pas, réfléchis 5 secondes...

A moins que "M" ou "F" soient entrés à l'aide d'une liste de validation

Re, J'ai lu et réfléchi en lisant la demande

Code:

Mais j'aimerai les combinés avec la reconnaissance du F ou M d'une autre case directement

Et comme c'est pour des "éléves", je suppose qu'il n'existe pas de "transgenre" à cet âge

Dranreb · 30 Novembre 2018

Bonjour.
Moi j'aurais dit
En E34 :

Code:

=EQUIV($D34;SI($C34="F";{-2E+99;9,0000001;11,0000001;13,0000001};{-2E+99;10;12,0000001;15,0000001});1)

M12 · 30 Novembre 2018

Salut Dranreb

Record d'octet battu 132 BRAVO!

Dranreb · 30 Novembre 2018

Elle pourrait probablement être considérablement raccourcie si la règle pouvait n'être exprimée qu'avec des >= au lieu de >
Parce que le EQUIV ne marche toujours qu'en 'À partir de Xi', jamais en 'Jusqu'à Xi inclus'
Sinon on peut quand même déjà la raccourcir un peu comme ça :
En E34 :

Code:

=5-EQUIV(-$D34;SI($C34="F";{-2E+99;-15;-12;-9,9999999};{-2E+99;-13;-11;-9});1)

XL pour MAC Fonction SI avec condition (Excel 2011)

Laffitte

XLDnaute Nouveau

M12

XLDnaute Accro

job75

XLDnaute Barbatruc

M12

XLDnaute Accro

job75

XLDnaute Barbatruc

Laffitte

XLDnaute Nouveau

M12

XLDnaute Accro

Dranreb

XLDnaute Barbatruc

M12

XLDnaute Accro

Dranreb

XLDnaute Barbatruc

Discussions similaires