Fonction qui vérifie si un caractère est présent dans une cellule

[excelentille]

Bonjour,
J'étais parvenu récemment à faire une fonction qui vérifiait la présence d'un caractère spécial dans une cellue. Il me semble que j'avais fait cela assez simplement avec la fonction esttexte(). Problème, manque de temps, trop de boulot, je ne l'ai pas noté et n'arrive pas à retrouver la méthode...

Ce que je cherche :
Si telle cellule contient le caractère ".", alors alerte, sinon "".

Une idée ?

Merci d'avance 🙂

 

[hoerwind]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Bonjour,

Essaie ceci :

=SI(ESTNUM(CHERCHE(A1;"."));"";"alerte")

 

[ROGER2327]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Bonjour excelentille

Ceci, peut-être ?

[COLOR=DarkSlateGray][B]=CHOISIR(1+ESTNUM(CHERCHE(".";A1));"";"Alerte !")[/B][/COLOR]

ou

[B][COLOR=DarkSlateGray]=SI(ESTNUM(CHERCHE(".";A1));"Alerte !";"")[/COLOR][/B]

ROGER2327
#4484

Vendredi 6 As 138 (Saint Omnibus, satyre, SQ)
18 Brumaire An CCXIX
2010-W45-1T13:39:34Z

 

[excelentille]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Merci, ta deuxième formule fonctionne, Roger.
Par contre j'ai essayé d'y ajouter un ou(), en première position, dans le cherche(), dans lequel je mets les différents caractères à proscrire. Et ça semble ne pas fonctionner.
Reste que je commence à loucher au delà de 3 fonctions imbriquées...

 

[ROGER2327]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Re...

Merci, ta deuxième formule fonctionne, Roger.
Par contre j'ai essayé d'y ajouter un ou(), en première position, dans le cherche(), dans lequel je mets les différents caractères à proscrire. Et ça semble ne pas fonctionner.
Reste que je commence à loucher au delà de 3 fonctions imbriquées...

Ne serait-il pas plus simple de poser complètement le problème à résoudre plutôt que d'en poser un autre qui ne se pose pas ?
​

ROGER2327
#4487

Vendredi 6 As 138 (Saint Omnibus, satyre, SQ)
18 Brumaire An CCXIX
2010-W45-1T14:30:25Z

_____________________________
Postscriptum : La première formule fonctionne elle aussi…

 

[hoerwind]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Re, salut Roger,

Oups, j'avais inversé les arguments sous la fonction CHERCHE !
Comme quoi, vérifier évite d'écrire des âneries !

Pour vérifier plusieurs conditions, une formule du type suivant devrait répondre à la demande :
=SI(OU(ESTNUM(CHERCHE({",";"."};A1)));"";"alerte")
Si un . (point) ou une , (virgule) est présent en A1 la formule renvoie "", si non "alerte".

Si les deux caractères doivent être présents :
=SI(ET(ESTNUM(CHERCHE({",";"."};A1)));"";"alerte")

On n'est pas limité par le nombre de caractères, il suffit de les placer entre les {}, en les entourant de "" (c'est du texte) et en les séparant par un ; (point-virgule).

 

[ROGER2327]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Bonjour hoerwind

D'accord avec vous, à condition d'inverser l'ordre des messages…

[B][COLOR=DarkSlateGray]=SI(OU(ESTNUM(CHERCHE({",";"."};A1)));"Alerte !";"")[/COLOR][/B]

Bonne soirée,

ROGER2327
#4488

Vendredi 6 As 138 (Saint Omnibus, satyre, SQ)
18 Brumaire An CCXIX
2010-W45-1T15:10:47Z

 

[excelentille]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Ça ne semble pas fonctionner pour moi. J'ai besoin de cette opération pour purifier une liste d'emails.
J'ai donc adapté la formule de telle manière :

=si(ou(estnum(cherche({",";";";"?";"/";"+";"=";"ù";"%";"£";"`";"ê";"*";"$";"€";"°";")";"à";"ç";"!";"è";"§";"(";"'";""";"é";"&";"#"};B1)));'Problème";"OK")

Avec cette formule, il me retourne toujours Problème, alors que ma base est saine.

Y a t'il une erreur de syntaxe ?

 

[hoerwind]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Re,

Peux-tu mettre en pièce jointe quelques lignes d'emails (bidons) avec la formule à côté, ce sera plus facile pour te venir en aide.

 

[excelentille]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

voilà, un fichier en pièce jointe

 

[natorp]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Bjr excelentille, Hoerwind, Roger

excelentille : il te faut entourer les parenthèses que tu testes entre 3 guillemets et remplacer l'apostrophe devant problème par un guillemet

cordialement, Gérard

 

[bof]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

bonjour,
une solution :

=SI(OU(ESTNUM(CHERCHE({",";";";"~?";"/";"+";"=";"ù";"%";"£";"`";"ê";"~*";"$";"€";"°";")";"à";"ç";"!";"è";"§";"(";"é";"&";"#"};A1)));"Alerte !";"")

à noter qu'il faut un "tilde" (~) devant ? et *
A+

 

[excelentille]

Re : Fonction qui vérifie si un caractère est présent dans une cellule

Ah !! C'était ça, ça fonctionne. Merci bof, et aux autres aussi !