Feuil SOMMAIRE

[pitou67]

Bonjour à tous et à toutes

Je souhaiterais dans un classeur avec une feuil dit sommaire

Que le classeur s'ouvre toujours su la cellule A1
Que les noms des feuils s’inscrivent toujours sur les même cellules (ex :b17 ,b19;b21 ,,,)
Que si je clique sur le nom de la feuil la feuil s'ouvre
que les nouvelle feuil s'inscrivent automatiquement
J'ai essayé divers procédure retrouvées dans le forum mais aucune ne donnent le résultat que je souhaite mais,
La plus proche est celle que j’utilise là
Merci pour votre aide
Pitou67

 

[vgendron]

Re : Feuil SOMMAIRE

Hello

ci dessous une proposition de code

Private Sub Workbook_Open()
Sheets("Sommaire").Activate

'For i = 8 To 44 Step 2
'Cells(i, 2) = ""
'Next i

'on peut effacer toute la colonne d'un coup
Range("B:B").Clear

'pour chaque feuille (considérant que la feuille1 est la feuille "Sommaire"
'on créé un lien hypertexte vers la feuille
For i = 2 To Sheets.Count
    Cells(8 + ((i - 2) * 2), 2).Select
    ActiveSheet.Hyperlinks.Add Anchor:=Selection, Address:="", SubAddress:=Sheets(i).Name & "!A1", TextToDisplay:=Sheets(i).Name
Next i
End Sub

 

[vgendron]

Re : Feuil SOMMAIRE

pour ton code dans l'évènement workbook_SheetActivate()

Peux tu expliquer ce que c'est censé faire?
etait ce un essai?

note: la ligne
If ActiveSheet.Name <> "sommaire" Then Exit Sub
sera toujours vraie ;-)
parce que ta feuille sommaire est écrite en majuscule.. et vba fait une différence entre minuscule et majuscule
pour s'en affranchir, il faut écrire
If ActiveSheet.Name <> ucase("sommaire") Then Exit Sub

 

[camarchepas]

Re : Feuil SOMMAIRE

Bonjour Vgendron , Pitou ,

Et hop , une autre option possible :

Private Sub Workbook_Open()
Menu
End Sub

Sub Menu()
Dim Onglet As Worksheet
Dim Ligne As Long
If ActiveSheet.Name = "SOMMAIRE" Then
 For Each Onglet In ThisWorkbook.Worksheets
  If Onglet.Name <> "SOMMAIRE" Then
   With Sheets("Sommaire")
    .Range("B" & 17 + Ligne).Select
    .Hyperlinks.Add Anchor:=Selection, Address:="", SubAddress:=Onglet.Name & "!A1", TextToDisplay:=Onglet.Name
   End With
  Ligne = Ligne + 2
  End If
 Next Onglet
End If
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
Menu
End Sub

 

[pitou67]

Re : Feuil SOMMAIRE

Merci à tous

tout fonctionne comme je le souhaite .Pour info Vgendron ce n'est pas un essai mais je suis en train de mette en place un suivi de stagiaires dans notre association pour être capable de rendre des comptes précis aux différentes administrations.
Merci encore
Pitou67

 

[pitou67]

Re : Feuil SOMMAIRE

J'ai été un peux vite :

Sur b22 et b23 dans la feuil "sommaire " lorsque je clique dessus j'ai " référence invalide "

Merci merci de regarder ce qui ce passe.

J'ai joint l'intégralité du classeur c'est plus facile pour vous

Pitou67

 

[vgendron]

Re : Feuil SOMMAIRE

au hasard.. je pense que les liens hypertextes n'aiment pas les espaces..
renomme tes onglets Suivi emploi et Presence signature avec des "_" (touche 8) au lieu de simples espaces

 

[camarchepas]

Re : Feuil SOMMAIRE

Re ,

Et oui pour les miens avec espace , il faut encadrer avec des apostrophes,

j'ai modifié un ptit peu le code de la routine Menu

Sub Menu()
Dim Onglet As Worksheet
Dim Ligne As Long
If ActiveSheet.Name = "SOMMAIRE" Then
  For Each Onglet In ThisWorkbook.Worksheets
   If Onglet.Name <> "SOMMAIRE" Then
    With Sheets("Sommaire")
     .Range("B" & 17 + Ligne).Select
     .Hyperlinks.Add Anchor:=Selection, Address:="", SubAddress:="'" & Onglet.Name & "'" & "!A1", TextToDisplay:=Onglet.Name
    End With
   Ligne = Ligne + 2
   End If
  Next Onglet
End If
End Sub

 

[pitou67]

Re : Feuil SOMMAIRE

Merci à tous les deux
Vraiment vous m'avez beaucoup aidé
Merci encore
Pitou67