Faire une recherche dans deux colonnes

[zephir94]

Bonjour à tous,

Continuant à chercher une solution de vérification dans deux colonnes j'ai un peu progressé mais il me reste un point à corriger, j'arrive à trouver deux valeurs et la ligne ou elles sont écrites.
Mon soucis est que si j'ai deux Lambert l'un Didier et l'autre Antoine ma recherche va s'arrêter sur le premier Lambert voici mon code :

Sub CommandButton1_Click()
Dim Nom As String, Cell As Range, DC&
Dim x As Range, a As String, i As Integer
Dim L As Integer
Dim V As Integer
Dim prenon As String
Application.ScreenUpdating = False

Nom = InputBox("Veuillez Saisir le Nom")
prenom = InputBox("Veuillez Saisir le prénom ")
If Nom = "" Then
    MsgBox "Vous n'avez pas saisi de Nom !!!", _
    "test", vbExclamation
    Exit Sub
End If
If prenom = "" Then
Exit Sub
End If



L = Columns("B").Find(Nom, lookat:=xlWhole).Row
V = Columns("c").Find(prenom, lookat:=xlWhole).Row
MsgBox L ' test de la valeur de la ligne
MsgBox V ' teste de la valeur de la ligne

If L = V Then Exit Sub ' si les deux valeurs sont sur la même ligne
MsgBox " trouvé"

End Sub

Si il n'y a qu'un seul Lambert ou un seul Antoine ça marche, si non très logiquement il s'arrête à la première valeur trouvée ! je pense sans le maitriser que je dois faire une boucle peut-être en comparant ligne par ligne ?
Merci pour vos aides

 

[phlaurent55]

Re : Faire une recherche dans deux colonnes

Bonjour Zephir,

voir fichier joint

à+
Philippe

Edit: fais un test avec le prénom Michel, il s'y trouve plusieurs fois
tu peux compléter les colonnes B & C avec d'autres noms

Edit 2: nouveau fichier ( réparation d'une faute d'orthographe)

 

[job75]

Re : Faire une recherche dans deux colonnes

Bonjour zephir94,

Si vous avez un peu de mémoire ceci devrait vous rappeler quelque chose :

Option Compare Text 'la casse est ignorée

Private Sub CommandButton1_Click()
Dim nom$, prenom$, t, x$, i&
nom = InputBox("Veuillez saisir le nom")
If nom = "" Then Exit Sub
prenom = InputBox("Veuillez saisir le prénom")
If prenom = "" Then Exit Sub
With Sheets("base2") 'nom de la feuille à adapter
  t = Intersect(.[B:C], .Range("A1", .UsedRange).EntireRow)
End With
x = nom & Chr(1) & prenom
For i = 1 To UBound(t)
  If t(i, 1) & Chr(1) & t(i, 2) = x Then
    MsgBox "Trouvés en ligne n° " & i
    Exit Sub
  End If
Next
MsgBox "Pas trouvés..."
End Sub

Edit : hello Philippe, pas rafraîchi...

A+

 

[Robert]

Re : Faire une recherche dans deux colonnes

Bonjour le fil, bonjour le forum,

Bien en retard, j'envoie malgré tout ma proposition qui utilise une UserForm. Un double-clic dans un élément de la ListBox1 permet de sélectionner la ligne dans le tableau.

Le fichier :

 

[zephir94]

Re : Faire une recherche dans deux colonnes

Un grand merci pour ces deux fichiers, je vais essayer de comprendre la prog,
merci pour tout