extraction du dernier mot d'une cellule

[rice]

Bonjour à tous
Un petit souci sur mon fichier qui comprend des noms de differentes longueurs et parfois à rallonge + les prénoms dans la meme cellule. J'ai besoin de sortir le prenom seul
Un petit fichier test joint

Merci d'avance [file name=test_20060530182139.zip size=1534]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/test_20060530182139.zip[/file]

 

[AV]

Salut,

Si les données ont toutes la forme de ton exemple, matricielle :

=DROITE(A2;EQUIV(' ';STXT(A2;NBCAR(A2)-LIGNE(INDIRECT('1:'&NBCAR(A2)));1);0))

PS : Cette formule n'est pas généralisable à tous les types de phrases.
Autres types sur demande
AV [aaa]

 

[rice]

Merci beaucoup pour cette formule qui me convient tres bien et pour ta rapidité
Quel autre genre de phrase évoques-tu?
Bonne continuation

 

[Temjeh]

Bonjour

Formule en B1 ...dernier mot de A1

=SI(A1='';'';STXT(A1;CHERCHE(' ';A1;1)+1;NBCAR(A1)))

A+

Temjeh

Oups bonjour AV

Oups ma formule est bonne pour 2 mots seulement

Message édité par: temjeh, à: 30/05/2006 18:43

 

[rice]

Merci également Temjeh mais la formule ne donne pas le resultat que je souhaite, elle n'extrait pas toujours le dernier mot à droite contrairement à celle de AV (par contre je ne sais pas pourquoi..)
Bonne continuation

 

[AV]

Re,

D'abord pour les réfractaires aux matricielles :
=STXT(A2;TROUVE('^^';SUBSTITUE(A2;' ';'^^';NBCAR(A2)-NBCAR(SUBSTITUE(A2;' ';''))))+1;9^9)

''...Quel autre genre de phrase évoques-tu...''

Exemples (matricielles) :
Au cas où il n'y aurait qu'un mot dans la cellule de recherche ou bien une cellule vide :

=DROITE(A2;EQUIV(' ';STXT(' '&A2;2+NBCAR(A2)-LIGNE(INDIRECT('1:'&NBCAR(A2)+1));1);0)-1)

Type de phrase tarabiscoté :
''Il est allé, à la pèche; il est revenu:bravo''

=STXT(A2;MAX(LIGNE(INDIRECT('1:'&NBCAR(A2)))*ESTNUM(CHERCHE(STXT(A2;LIGNE(INDIRECT('1:'&NBCAR(A2)));1);' ,;/:')))+1;NBCAR(A2))

Etc...
AV [aaa]

 

[rice]

Salut AV
Décidément, j'en ai plus que ce que j'esperais mais je me garde tout ça de coté pour le jour où ça se présente
La premiere formule fonctionne meme en non matricielle chez moi
Merci beaucoup et @+
Rice

 

[rice]

Bonjour AV, Temjeh et le forum
En fait la permiere formule marche tres bien pour moi sauf que j'ai oublié hier soir un petit bout de mon probleme c'est que une fois que j'ai extrait le prenom qui est donc à droite dans la cellule j'ai aussi besoin de recupérer le nom seul qui peut etre donc composé ou du type 'machin né bidule de truc' comme je l'avais mis dans mon petit fichier test
J'ai beau tournicoter les formules de AV (que je ne comprends pas tres bien dans leurs syntaxes vu mon niveau, je n'arrive pas à trouver
Merci d'avance