Exporter cellule d'un classeur A vers classeur B

[mletourn]

Bonsoir à tous,

Je souhaite copié/collé la donnée d'une cellule d´un ClasseurA Feuille1 C8 vers un Classeur B Feuille1 C9, voici la macro que j'ai fais mais excel me renvoi une erreur au niveau de "Range("C9").Select"

Private Sub CommandButton3_Click()
Dim cell As Range
Workbooks.Open Filename:="C:\Users\Hector\Desktop\Hojas_FFS\HOJAS_ANALYSIS\Parte_6_BETA.xlsx"
Windows("DATOS_FFS.xlsm").Activate
Sheets("Parte 6").Select
Range("C8").Select
Selection.Copy
Windows("Parte_6_BETA.xlsx").Activate
Sheets("DATOS").Select
Range("C9").Select
ActiveSheet.Paste

End Sub

 

[mapomme]

Re : Exporter cellule d'un classeur A vers classeur B

Bonsoir mletourn,

Essayez ce code:

Private Sub CommandButton3_Click()
Dim xSource As Worksheet, xPuits As Worksheet
  Set xPuits = Workbooks.Open(Filename:="C:\Users\Hector\Desktop\Hojas_FFS\HOJAS _ANALYSIS\Parte_6_BETA.xlsx").Sheets("DATOS")
  Set xSource = Workbooks("DATOS_FFS.xlsm").Sheets("Parte 6")
  xSource.Range("C8").Copy Destination:=xPuits.Range("C9")
End Sub

Edit: Bonsoir Staple1600 🙂

 

[mletourn]

Re : Exporter cellule d'un classeur A vers classeur B

Merci ca fonctionne

 

[Staple1600]

Re : Exporter cellule d'un classeur A vers classeur B

Bonjour à tous , salut mapomme 😉

Ceci devrait aussi fonctionner
(j'espère juste que seule la valeur (et pas son format) de de C9 t'intéresse 😉 )

Sub CommandButton3_Click()
Dim Fic$, CLASSEURB As Workbook
Fic$ = "C:\Users\Hector\Desktop\Hojas_FFS\HOJAS _ANALYSIS\Parte_6_BETA.xlsx": Set CLASSEURB = Workbooks.Open(Fic)
CLASSEURB.Sheets("DATOS").[C9] = ThisWorkbook.Sheets("Parte 6").[C8]
End Sub

 

[mletourn]

Re : Exporter cellule d'un classeur A vers classeur B

Et si la cellule à copier comporte une formule utilisant d'autre données de la page comment copier la valeur de la cellule vers le nouveau classeur ?

 

[Staple1600]

Re : Exporter cellule d'un classeur A vers classeur B

Re

Tu as essayé le code de mon précédent message?

 

[mapomme]

Re : Exporter cellule d'un classeur A vers classeur B

(re)Bonjour mletour,

Et si la cellule à copier comporte une formule utilisant d'autre données de la page comment copier la valeur de la cellule vers le nouveau classeur ?

De manière similaire au code de Staple1600 (que je salue 🙂), remplacer l'instruction:

xSource.Range("C8").Copy Destination:=xPuits.Range("C9")

par l'instruction:

xPuits.Range("C9")=xSource.Range("C8")

 

[mletourn]

Re : Exporter cellule d'un classeur A vers classeur B

Super merci a vous ca fonctionne tres bien ! 😀