Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

[serras]

Bonjour à tous,

Je me heurte à une difficulté liée aux nombre de conditions que je souhaite mettre en oeuvre sur un calcul. Ces difficultés résultent de plusieurs contraintes : vu l'origine et la forme des données sources et la forme du tableau de calcul, le résultat de la triple condition doit apparaitre dans une cellule unique.

Je joins un fichier qui montre plus clairement ces éléments. Le but est de calculer le nombre de personnes présentes sur 4 villes, en fonction du nombre de participants, de la date de la réunion et de l'origine du public concerné.

D'avance, merci de votre aide.

Serras.

 

[Genii]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Utilise tout simplement la fonction SI qui permet de mixer tes 4 conditions.

 

[ERIC S]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Bonjour

je pense que les Si ne sufiront pas

sans doute une possibilité avec sommeprod

=SOMMEPROD((Feuil2!$A$2:$A$101=Feuil1!A2)*(Feuil2!$B$2:$B$101<60)*(Feuil2!$C$2:$C$101>=DATEVAL("1/3/2012"))*(Feuil2!$C$2:$C$101<DATEVAL("1/5/2012"))*(Feuil2!$D$2:$D$101="Consommateur (8)"))+SOMMEPROD((Feuil2!$A$2:$A$101=Feuil1!A2)*(Feuil2!$B$2:$B$101<60)*(Feuil2!$C$2:$C$101>=DATEVAL("1/3/2012"))*(Feuil2!$C$2:$C$101<DATEVAL("1/5/2012"))*(Feuil2!$D$2:$D$101="Professionnel (7)"))

Mais je suis convaincu que la solution réside dans les TCD, mais là il faut que je fouille car c'est une grosse lacune chez moi

 

[ROGER2327]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Bonjour à tous

Une formule :​

=SOMMEPROD((feuil2!$A$2:$A$19=A2)*(DATE(2012;2;29)<feuil2!$C$2:$C$19)*(feuil2!$C$2:$C$19<DATE(2012;5;1))*(feuil2!$B$2:$B$19<61)*((GAUCHE(feuil2!$D$2:$D$19;3)="Con")+(GAUCHE(feuil2!$D$2:$D$19;3)="Pro")))

(testée)​

ROGER2327
#5807

Jeudi 5 Palotin 139 (Sainte Poignée, veuve et SainteJutte, recluse - fête Suprême Quarte)
5 Floréal An CCXX, 3,8359h - rossignol
2012-W17-2T09:12:22Z

 

[serras]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Merci beaucoup c'est exactement ce que je souhaitais et cela fonctionne parfaitement !!!

J'ai un peu l'impression d'abuser mais mes tentatives pour mixer cette formule SOMMEPROD avec SOMME.SI ne fonctionnent pas...je souhaiterais ajouter une autre colonne (C) sur ma feuille 1 qui fasse l'addition du nombre de participants quand l'ensemble des conditions vues précemment sont remplies. J'ajoute un fichier modifié qui présente cette nouvelle colonne C (avec une colonne D qui comporte le chiffre à obtenir -que j'ai vaillament calculé à la main- pour vérifier la formule).

D'avance merci de votre précieuse aide.

Serras.

 

[ERIC S]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

re

=SOMMEPROD((feuil2!$A$2:$A$101=feuil1!A2)*(feuil2!$B$2:$B$101<60)*(feuil2!$C$2:$C$101>=DATEVAL("1/3/2012"))*(feuil2!$C$2:$C$101<DATEVAL("1/5/2012"))*(feuil2!$D$2:$D$101="Consommateur (8)")*(feuil2!$B$2:$B$101))+SOMMEPROD((feuil2!$A$2:$A$101=feuil1!A2)*(feuil2!$B$2:$B$101<60)*(feuil2!$C$2:$C$101>=DATEVAL("1/3/2012"))*(feuil2!$C$2:$C$101<DATEVAL("1/5/2012"))*(feuil2!$D$2:$D$101="Professionnel (7)")*(feuil2!$B$2:$B$101))

on ajoute *(feuil2!$B$2:$B$101) à chaque somme prod

Note : le principe doit être le même avec la proposition de Robert (non testé)

 

[ROGER2327]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Suite...

=SOMMEPROD((feuil2!$A$2:$A$19=A2)*(DATE(2012;2;29)<feuil2!$C$2:$C$19)*(feuil2!$C$2:$C$19<DATE(2012;5;1))*(feuil2!$B$2:$B$19<61)*((GAUCHE(feuil2!$D$2:$D$19;3)="Con")+(GAUCHE(feuil2!$D$2:$D$19;3)="Pro"))*feuil2!$B$2:$B$19)

ROGER2327
#5808

Jeudi 5 Palotin 139 (Sainte Poignée, veuve et SainteJutte, recluse - fête Suprême Quarte)
5 Floréal An CCXX, 4,1188h - rossignol
2012-W17-2T09:53:06Z

 

[ERIC S]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

re

bien vu Roger

je suis sur une présentation powerpoint et je n'avais pas eu l etemps d'optimiser le sommeprod (un essai avec OU, au lieu de +, s'était soldé par un échec)

 

[serras]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Merci pour ces nouveaux éléments. Je travaille à partir de la formule communiquée par ROGER. Je rencontre uen difficulté pour intégrer la dernière formule (celle qui fait l'addition du nombre de participants quand l'ensemble des conditions vues précemment sont remplies). Lorsque je la colle dans mon tableau j'obtiens #VALEUR!

Il me semble pourtant que j'ai repris la formule communiquée par ROGER (en changeant les colonnes vers lesquelles pointent la formule) et en modifiant la date de référence (j'ai mis supérieur au 31 décembre 2011) et en augmentant le nombre de lignes à prendre en compte (19000 au lieu de 19).

Je commets une erreur...mais où ? ( à noter : j'ai modifié la première formule, celle de SOMEPROD seul, de la même manière c'est à dire colonne / date de référence / nombre de ligne et cela fonctionne)

Je vous adresse le fichier concerné et sollicite à nouveau votre aide (en colonne B la formule retouchée qui fonctionne, en colonne C celle que je ne parviens pas à faire fonctionner et en colonne D le résultat que devrait afficher la formule de la colonne C).

Merci.

 

[ERIC S]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

re

commence tes zones en 14 et non en 2 car les lignes 2 à 14 ne contiennent pas des nombres pour les dates et qtés (titre = texte)

 

[serras]

Re : Excel peut-il calculer une TRIPLE condition sans tableau croisé dynamique ?

Un grand merci à ERIC et ROGER, mon fichier fonctionne parfaitement. J'espère mieux maitriser SOMMEPROD et SOMMESI.