evenement mousedown avec un textbox crée par vba ?

[linked]

Bonjour,

Je n'arrive pas à trouver comment utiliser l'evenement mousedown avec des textbox qui sont generé sur un userform de cette facon:

'date
Set Obj = Me.Controls.Add("forms.Textbox.1")
With Obj
.Name = "textbox_" & Categorie & "_" & c
.Left = 280
.Top = Y
.Width = 50
.Height = 20
End With

J'aimerais faire apparaitre un userform avec calendrier si on clique sur chacune des ces box.

 

[MichelXld]

Re : evenement mousedown avec un textbox crée par vba ?

bonjour


Je n'ai pas bien compris: au debut tu parles de l'evenement mousemove et ensuite de l'evenement Click (dans un textbox ce sera plutot doubleclick...)


Tu peux adapter cette procédure qui gère l'evenement MouseMove pour un ensemble de TextBox créés dynamiquement:

 '--------------------------------------
'Procédure de création des TextBoxs à placer dans l'UserForm.
'L'UserForm doit préalablement contenir un bouton nommé CommandButton1
'Et un Label nommé Label1
Option Explicit

Private Sub CommandButton1_Click()
Dim Obj As Control
Dim Cl As Classe1
Dim i As Integer

Set Collect = New Collection

For i = 1 To 3 'boucle pour la création des TextBox
    Set Obj = Me.Controls.Add("forms.Textbox.1")
    With Obj
        .Name = "monTextbox" & i
        .Left = 140
        .Top = 30 * i + 10
        .Width = 50
        .Height = 20
    End With
    
    'ajout de l'objet dans la classe
    Set Cl = New Classe1
    Set Cl.TxtBx = Obj
    Collect.Add Cl
Next i

End Sub
'--------------------------------------

 '--------------------------------------
'A placer dans un module standard
Option Explicit

Public Collect As Collection
'--------------------------------------

 '--------------------------------------
'A placer dans un module de classe nommé "Classe1"
'
Option Explicit

Public WithEvents TxtBx As MSForms.TextBox

'Exemple pour gérer l'évènement mousemove sur les objets type TextBox
Private Sub TxtBx_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, _
    ByVal X As Single, ByVal Y As Single)
    UserForm1.Label1.Caption = TxtBx.Name & " " & X & ":" & Y
End Sub

Bonne soirée
MichelXld

 

[linked]

Re : evenement mousedown avec un textbox crée par vba ?

Ouah ça marche 🙂
Merçi beaucoup michel