Erreur formule matricielle #N/A

[fenec]

Bonjour le forum,

Comme l'indique le titre je rencontre une erreur que je parviens pas à résoudre.
Dans mon tableau j'utilise cette formule qui fonctionne très bien (formule matricielle)

=SI(OU($B$7={"SD";"1 - SD";"2 - SD";"1 - 3x8";"2 - 3x8";"3 - 3x8";"1 - 5x8";"2 - 5x8";"3 - 5x8";"4 - 5x8";"5 - 5x8"});SOMME(SI(Calendrier!$D$3:$AK$33="SST";SI(JOURSEM(Calendrier!$B$3:$AI$33;2)>=1;0.5;"");0))*8;0)+SI(OU($B$7={"1 - 3x8";"2 - 3x8";"3 - 3x8";"1 - 5x8";"2 - 5x8";"3 - 5x8";"4 - 5x8";"5 - 5x8";"SD";"1 - SD";"2 - SD"});SOMME(SI(Calendrier!$D$3:$AK$33="CACES";SI(JOURSEM(Calendrier!$B$3:$AI$33;2)>=1;0.5;"");0))*8;0)

Voulant faire plus court? je l'ai modifié comme suis mais la excel me renvoie une erreur #N/A

=SI(OU($B$7={"SD";"1 - SD";"2 - SD";"1 - 3x8";"2 - 3x8";"3 - 3x8";"1 - 5x8";"2 - 5x8";"3 - 5x8";"4 - 5x8";"5 - 5x8"});SOMME(SI(Calendrier!$D$3:$AK$33={"SST";"CACES"};SI(JOURSEM(Calendrier!$B$3:$AI$33;2)>=1;0.5;"");0))*8;0)

Merci de votre aide sur cette erreur

Cordialement ...

Philippe

 

[Staple1600]

Re : Erreur formule matricielle #N/A

Bonjour à tous

fenec
Si tu joignais un fichier Excel afin qu'on puisse tester ta formule sur nos PC, cela nous aiderait bien, non?

 

[fenec]

Re : Erreur formule matricielle #N/A

Re et bonjour Staple1600,

Oups, j'ai oublié de le joindre

 

[job75]

Re : Erreur formule matricielle #N/A

Bonjour fenec, hello JM,

Formule en H12, à valider matriciellement :

=SI(OU($B$7={"SD";"1 - SD";"2 - SD";"1 - 3x8";"2 - 3x8";"3 - 3x8";"1 - 5x8";"2 - 5x8";"3 - 5x8";"4 - 5x8";"5 - 5x8"});SOMME(SI((Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES");SI(JOURSEM(Calendrier!$B$3:$AI$33;2)>=1;0,5;"");0))*8;0)

A+

 

[job75]

Re : Erreur formule matricielle #N/A

Re, dans

Dans votre formule SI(JOURSEM(Calendrier!$B$3:$AI$33;2)>=1;0,5;"") ne va pas.

En effet le JOURSEM est forcément >=1 ou égal à #VALEUR!, il suffit de faire F9 dans la formule.

Voyez ceci :

=N(SI(OU($B$7={"SD";"1 - SD";"2 - SD";"1 - 3x8";"2 - 3x8";"3 - 3x8";"1 - 5x8";"2 - 5x8";"3 - 5x8";"4 - 5x8";"5 - 5x8"});SOMMEPROD(((Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES"))*ESTNUM(JOURSEM(Calendrier!$B$3:$AI$33)))*4))

La validation matricielle n'est plus nécessaire.

Edit : noter que =N(SI(test;nombre)) est plus "léger" que =SI(test;nombre;0) : 4 octets de moins.

A+

 

[Regueiro]

Re : Erreur formule matricielle #N/A

Bonsoir le Forum
Encore une plus courte

=SI(NB.SI(Equipes;$B$7)=1;SOMMEPROD((Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES");ESTNUM(JOURSEM(Calendrier!$B$3:$AI$33))/2)*8)

A+

 

[job75]

Re : Erreur formule matricielle #N/A

Re,

Si l'on veut la somme pour un jour de semaine particulier, par exemple le lundi (JOURSEM=2) :

=N(SI(OU($B$7={"SD";"1 - SD";"2 - SD";"1 - 3x8";"2 - 3x8";"3 - 3x8";"1 - 5x8";"2 - 5x8";"3 - 5x8";"4 - 5x8";"5 - 5x8"});SOMMEPROD(((Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES"))*ESTNUM(LN(JOURSEM(Calendrier!$B$3:$AI$33)=2)))*4))

A+

 

[job75]

Re : Erreur formule matricielle #N/A

Re,

Regueiro a tout à fait raison, utilisez la plage nommée Equipes :

=4*SOMMEPROD(NB.SI(Equipes;$B$7)*ESTNUM(JOURSEM(Calendrier!$B$3:$AI$33));(Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES"))

ou si l'on s'intéresse seulement au lundi (JOURSEM=2) :

=4*SOMMEPROD(NB.SI(Equipes;$B$7)*ESTNUM(LN(JOURSEM(Calendrier!$B$3:$AI$33)=2));(Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES"))

A+

 

[Regueiro]

Re : Erreur formule matricielle #N/A

Bonsoir
Merci Job75
Pour ma gouverne pourquoi :
=4*SOMMEPROD(NB.SI(Equipes;$B$7)*
A+

 

[job75]

Re : Erreur formule matricielle #N/A

Re,

On pourrait sortir le NB.SI du SOMMEPROD :

=4*NB.SI(Equipes;$B$7)*SOMMEPROD(ESTNUM(JOURSEM(Calendrier!$B$3:$AI$33))*((Calendrier!$D$3:$AK$33="SST")+(Calendrier!$D$3:$AK$33="CACES")))

Mais comme on le voit le point virgule (1 octet) doit alors être remplacé par *() qui "pèse" 3 octets.

A+

 

[Regueiro]

Re : Erreur formule matricielle #N/A

Bonsoir à Tous
Le but de la question étant de faire une formule très courte :

=4*NB.SI(Equipes;$B$7)*SOMMEPROD(ESTNUM(JOURSEM(CAL2))*((CAL=$K$14)+(CAL=$K$15)))

Soit 81 caractères

CAL =Calendrier!$D$3:$AK$33
CAL2 =Calendrier!$B$3:$AI$33
K14 = SST
K15 = CACES

A+

 

[Staple1600]

Re : Erreur formule matricielle #N/A

Bonsoir à tous

[joke]
Soyons anglophiles et nous serons un peu plus court 😉
=4*NB.SI(Team;$B$7)*SOMMEPROD(ESTNUM(JOURSEM(CAL2))*((CAL=$K$14)+(CAL=$K$15)))
[/joke]

Ok je sors 😉

 

[job75]

Re : Erreur formule matricielle #N/A

Bonjour le fil, le forum,

La formule devant être placée en H10, il faut sans doute tenir compte des dates en E10 et F10 :

=4*NB.SI(Equipes;B$7)*SOMMEPROD((Calendrier!B$3:AI$33>=E10)*(Calendrier!B$3:AI$33<=F10);(Calendrier!D$3:AK$33="SST")+(Calendrier!D$3:AK$33="CACES"))

Nota : le "poids" d'une formule se mesure en octets, pas du tout en nombre de caractères :

https://www.excel-downloads.com/threads/nombre-doctets-dune-formule-calcule-par-macro-vba.148601/

Les noms Equipes et Team ont le même poids : 4 octets.

Bonne journée et A+

 

[fenec]

Re : Erreur formule matricielle #N/A

Bonjour le forum, Staple1600, Job75

Merci pour vos réponses, je teste vos divers propositions et vous tiens au courant dès que possible.

Job,

Ta dernière solution est pertinante, je n'avais pas pensé aux dates. Je regarde ca de plus près

Bon dimanche à tous

Cordialement ...

Philippe.

 

[job75]

Re : Erreur formule matricielle #N/A

Re,

J'ai modifié la formule du post #13, ESTNUM(LN()) était tout à fait inutile...

A+