XL 2016 EQUIV sensible à la casse ?

[amgue]

Bonjour,

Dans l'exemple fourni, la fonction EQUIV renvoie la ligne 7, ce qui est incorrect. La ligne 10 est la ligne qui correspond au mot recherché en majuscule, "INV". J'ai bien précisé le type de recherche (correspondance exacte à 0), mais la fonction EQUIV, de ce qui paraît, n'est pas sensible à la casse.

=EQUIV($G1;C5:C10;0)+4

Qu'est-ce qu'il faut changer dans la formule pour la rendre sensible à la casse ?

Merci d'avance.

 

[R@chid]

Bonjour,

=EQUIV(VRAI;EXACT(G1;C5:C10);0)+4

@ valider par Ctrl+Maj+Entrée

Cordialement,

 

[amgue]

Bonjour Rachid,

Merci pour la réponse.

Cependant, est-il possible d'obtenir le même résultat sans passer par la recherche matricielle ?

 

[R@chid]

Re,

Cependant, est-il possible d'obtenir le même résultat sans passer par la recherche matricielle ?

C'est possible sous Excel pour Microsoft 365, mais je ne suis pas sûr si c'est le cas sous Excel 2016.

Je n'ai pas Excel 2016 sous les mains, essaie avec cette formule si cela pourrait marcher :

=AGREGAT(14;;EXACT(G1;C$5:C$10)*LIGNES(C5:C10);1)

Cordialement

 

[amgue]

Bonjour,

J'ai trouvé cette formule pour éviter les matricielles :

=EQUIV(VRAI;INDEX(EXACT(G1;C1:C6););0)+4

et voici un classeur récapitulatif des toutes les solutions proposées :

 

[mapomme]

Bonsoir 🙂,

Chez moi, la formule avec agrégat peut donner un résultat faux.
Essayez avec "iNv" en G1.

 

[amgue]

Bonsoir ma pomme,

En fait, toutes les formules donnent soit une erreur, soit un mauvais résultat.

 

[mapomme]

En fait, toutes les formules donnent soit une erreur, soit un mauvais résultat.

On ne peut pas considérer #N/A comme erreur de formule. C'est la marque que le texte n'a pas été trouvé.
Mais agrégat retourne une valeur fausse au lieu d'une erreur.

 

[ALS35]

Bonjour à tous,
La formule avec AGREGAT ne donne pas de résultat faux mais d'abord elle est erronée, et devrait être (LIGNE au lieu de LIGNES) :

=AGREGAT(14;;EXACT(G1;C$5:C$10)*LIGNE(C5:C10);1)

Ensuite en cas de non correspondance la formulation matricielle :

EXACT(G1;C$5:C$10)*LIGNE(C5:C10)

renvoie une matrice de 0, dont la plus grande valeur est 0 et non une valeur d'erreur.

On pourrait éventuellement l'aménager comme ceci :

=AGREGAT(14;6;LIGNE(C5:C10)/EXACT(G1;C$5:C$10);1)

qui génère bien une erreur en cas de non correspondance, que l'on peut traiter avec SIERREUR.
Cordialement