XL 2021 enregistrer xltm en xlsm avec chemin automatiquement

sbrun · Hier à 10:02

Bonjour à tous !
Tout nouveau sur le forum j'ai une question a poser
Je souhaite enregistrer un modèle existant (xltm) en xlsm par macro
Cette macro doit nommer mon classeur avec la valeur récupérée d'une cellule précisée ( toujours la même) - ca c'est ok
Cette macro doit donner l'extension xlsm - c'est ok
Cette macro doit enregistrer mon classeur dans un répertoire précis automatiquement sans ouvrir de fenêtre - Pas ok
Elle m'ouvre la box "enregistrer sous", avec le bon nom de fichier et la bonne extension mais ne propose pas le bon répertoire !!!
Que faire pour - 1 ne pas avoir de box ?
2 enregistrer dans le bon chemin ?
Merci à vous

Mon code :

Sub enregistdernierN°BdC()
' enregistrement classeur entier nommé avec valeur cellule dans chemin précis
Sheets("Se").Range("F3").Value = Sheets("BdC").Range("C6").Value
Dim Path As String
Dim filename As String
Path = "C:\Utilisateurs\sb\Téléchargements\Marcel\"
filename = ActiveSheet.Range("C16")
r = Application.GetSaveAsFilename(filename, Filefilter:=" fichier xlsm,*.xlsm")
ActiveWorkbook.SaveAs r
End Sub

Dranreb · Hier à 15:31

Fais quand même un essai …
Pour moi ce code devrait marcher :

VB:

Sub enregistdernierN°BdC()
' enregistrement classeur entier nommé avec valeur cellule dans chemin précis
   Sheets("Se").Range("F3").Value = Sheets("BdC").Range("C6").Value
   ChDrive "C": ChDir "C:\Utilisateurs\sb\Téléchargements\Marcel"
   On Error Resume Next
   ActiveWorkbook.SaveAs ActiveSheet.Range("C16").Value, FileFormat:=xlOpenXMLWorkbookMacroEnabled
   If Err Then MsgBox "Erreur " & Err & " en tentant : " _
      & vbLf & "ActiveWorkbook.SaveAs """ & ActiveSheet.Range("C16").Value & """, FileFormat:=xlOpenXMLWorkbookMacroEnabled" _
      & vbLf & "CurDir :" & vbLf & CurDir _
      & vbLf & Err.Description, vbExclamation, "enregistdernierN°Bcd"
   End Sub

patricktoulon · Hier à 10:19

bonjour
avant le dialog fait un

Code:

 chdrive left(path,1)
 chdir path

Dranreb · Hier à 11:28

Bonjour.
Remarque: Left est inutile, ChDrive ne considérant que la lettre de début.

Nicolas JACQUIN · Hier à 11:42

Bonjour à tous,
J'avais une autre optique, mais peut-être pas la bonne.

VB:

Sub enregistdernierN°BdC()

    Sheets("Se").Range("F3").Value = Sheets("BdC").Range("C6").Value
    
    Dim chemin As String
    Dim nomFichier As String
    
    chemin = "C:\Utilisateurs\sb\Téléchargements\Marcel\"
    nomFichier = Sheets("Se").Range("C16").Value & ".xlsm"
    
    Application.DisplayAlerts = False
    
    ActiveWorkbook.SaveAs _
        Filename:=chemin & nomFichier, _
        FileFormat:=xlOpenXMLWorkbookMacroEnabled
    
    Application.DisplayAlerts = True

End Sub

Bonne continuation

Nicolas

sbrun · Hier à 11:57

patricktoulon à dit:
bonjour
avant le dialog fait un

Code:

chdrive left(path,1) chdir path

Bonjour et merci pour ta réponse.....
Mais ne sais pas ou la placer....
J'ai essayé différentes solutions mais message erreurs
Novice en vba :-(

Dranreb · Hier à 11:59

C'est à mettre devant l'utilisation de la méthode GetSaveAsFilename
Celle ci démarre en effet sur le CurDir positionné par ces deux instructions.

sbrun · Hier à 12:06

Dranreb à dit:
C'est à mettre devant l'utilisation de la méthode GetSaveAsFilename
Celle ci démarre en effet sur le CurDir positionné par ces deux instructions.

Comme ceci ?
filename = ActiveSheet.Range("C16")
ChDrive Left(Path, 1)
ChDir Path
r = Application.GetSaveAsFilename(filename, Filefilter:=" fichier xlsm,*.xlsm")
ActiveWorkbook.SaveAs r
Erreur 76 chemin introuvable.

Dranreb · Hier à 12:08

Il faut bien entendu remplacer Path par une constant String du bon chemin.
Ou bien l'y affecter. Vous l'aviez fait dans le code cité :

Path = "C:\Utilisateurs\sb\Téléchargements\Marcel\"

Vérifiez si ce chemin existe bien.

sbrun · Hier à 12:50

Dranreb à dit:
Il faut bien entendu remplacer Path par une constant String du bon chemin.
Ou bien l'y affecter. Vous l'aviez fait dans le code cité :
Vérifiez si ce chemin existe bien.

Désolé je n'avais mis qu'une partie de ma macro
la voici en totalité mais erreur 76 : chemin d'Accès introuvable

Sub enregistdernierN°BdC()
'enregistrement classeur entier en rapport avec valeur cellule dans chemin précis
Sheets("Se").Range("F3").Value = Sheets("BdC").Range("C6").Value
Dim Path As String
Dim filename As String
Path = "C:\Utilisateurs\sb\Téléchargements\Marcel\"
filename = ActiveSheet.Range("C16")
ChDrive Left(filename, 1)
ChDir filename
r = Application.GetSaveAsFilename(filename, Filefilter:=" fichier xlsm,*.xlsm")
ActiveWorkbook.SaveAs r

End Sub

sbrun · Hier à 13:08

Dranreb à dit:
Il faut bien entendu remplacer Path par une constant String du bon chemin.
Ou bien l'y affecter. Vous l'aviez fait dans le code cité :
Vérifiez si ce chemin existe bien.

Pour le chemin j'ai essayé - Path = "C:\Utilisateurs\sb\Téléchargements\Marcel\"
et aussi celui indiqué dans l'explorateur de fichiers : Path = "C:\Users\sb\Downloads\Marcel\"

Dranreb · Hier à 13:20

Testez If VarType(R) <> VbString Then au cas où aucun nom n'aurait été choisi ni saisi.

patricktoulon · Hier à 13:21

re comme ça

VB:

Sub enregistdernierN°BdC()
    'enregistrement classeur entier en rapport avec valeur cellule dans chemin précis
    'Sheets("Se").Range("F3").Value = Sheets("BdC").Range("C6").Value
  
    Dim Path$, filename$, Fullpath$, ReturnDialog
    'instruction des variables
    'Dossier de destination
    Path = "C:\Utilisateurs\sb\Téléchargements\Marcel\"
    If Dir(Path, vbDirectory) = "" Then MsgBox "Le dossier de destination n'existe pas" & vbCrLf & "Veuillez verifier": Exit Sub
  
    'Nom du fichier
    filename = ActiveSheet.Range("C16")
  
    'Chemin complet à integrer dans le filname du dialog
    Fullpath = Path & filename
  
    'positionner le dossier courant
    ChDrive Left(Path, 1)
    ChDir Path
  
    'Ouverture de dialogue Save As
    ReturnDialog = Application.GetSaveAsFilename(Fullpath, Filefilter:=" fichier xlsm,*.xlsm")
    'au cas ou on annule dans le dialog
    If ReturnDialog = False Then MsgBox "Annulation d'enregistrement du fichier", vbInformation: Exit Sub
  
    'Et enfin on enregistre le classeur avec returnDialog
    ActiveWorkbook.SaveAs _
                   Filename:=ReturnDialog, _
                   FileFormat:=xlOpenXMLWorkbookMacroEnabled
  
End Sub

j'ajouterais que je ne sais pas sous quelle version office et windows tu travaille ,mais j'ai un doute sur le path en français
Path ="C:\Utilisateurs\sb\Téléchargements\Marcel\"
chez moi ce serait plutot ça
Path ="C:\users\sb\Downloads\Marcel\"

TooFatBoy · Hier à 13:21

Bonjour,

sbrun à dit:
Désolé je n'avais mis qu'une partie de ma macro
la voici en totalité mais erreur 76 : chemin d'Accès introuvable

As-tu testé #4 ?

PS : quand tu postes du code VBA dans tes messages sur le forum, n'hésite pas à l'encadrer de la balise code avec le paramètre vb pour qu'il soit plus lisible.

Exemple :
[ code=vb ]
ici ton code
[ /code ]
(sans les espaces, bien sûr)

sbrun · Hier à 13:41

patricktoulon à dit:

re comme ça

VB:

Sub enregistdernierN°BdC()
    'enregistrement classeur entier en rapport avec valeur cellule dans chemin précis
    'Sheets("Se").Range("F3").Value = Sheets("BdC").Range("C6").Value
  
    Dim Path$, filename$, Fullpath$, ReturnDialog
    'instruction des variables
    'Dossier de destination
    Path = "C:\Utilisateurs\sb\Téléchargements\Marcel\"
    If Dir(Path, vbDirectory) = "" Then MsgBox "Le dossier de destination n'existe pas" & vbCrLf & "Veuillez verifier": Exit Sub
  
    'Nom du fichier
    filename = ActiveSheet.Range("C16")
  
    'Chemin complet à integrer dans le filname du dialog
    Fullpath = Path & filename
  
    'positionner le dossier courant
    ChDrive Left(Path, 1)
    ChDir Path
  
    'Ouverture de dialogue Save As
    ReturnDialog = Application.GetSaveAsFilename(Fullpath, Filefilter:=" fichier xlsm,*.xlsm")
    'au cas ou on annule dans le dialog
    If ReturnDialog = False Then MsgBox "Annulation d'enregistrement du fichier", vbInformation: Exit Sub
  
    'Et enfin on enregistre le classeur avec returnDialog
    ActiveWorkbook.SaveAs ReturnDialog
  
End Sub

j'ajouterais que je ne sais pas sous quelle version office et windows tu travaille ,mais j'ai un doute sur le path en français
Path ="C:\Utilisateurs\sb\Téléchargements\Marcel\"
chez moi ce serait plutot ça
Path ="C:\users\sb\Downloads\Marcel\"

sbrun · Hier à 13:49

Bonjour et merci de ton aide
pour le chemin j'ai mis "C:\Users\sb\Downloads\Marcel\"
Voici ce que j'obtiens dans l'ordre :

Ca c'est bon mais après......

XL 2021 enregistrer xltm en xlsm avec chemin automatiquement

sbrun

XLDnaute Nouveau

Dranreb

patricktoulon

XLDnaute Barbatruc

Dranreb

XLDnaute Barbatruc

Nicolas JACQUIN

XLDnaute Accro

sbrun

XLDnaute Nouveau

Dranreb

XLDnaute Barbatruc

sbrun

XLDnaute Nouveau

Dranreb

XLDnaute Barbatruc

sbrun

XLDnaute Nouveau

sbrun

XLDnaute Nouveau

Dranreb

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

TooFatBoy

XLDnaute Barbatruc

sbrun

XLDnaute Nouveau

sbrun

XLDnaute Nouveau

Discussions similaires

XL 2021 enregistrer xltm en xlsm avec chemin automatiquement

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Accro

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Nouveau

XLDnaute Nouveau

Discussions similaires

Privacy & Transparency

Privacy & Transparency