Microsoft 365 Double clic dans une cellule envoie vers la cellule d'une autre feuille

[mdlrt44]

Bonjour à tous,

J'aurais besoin de vos lumières parce que je sèche...
Sur un fichier (il y a déjà une macro) mon fichier est composé d'1 onglet "récap" et de plusieurs onglet "mois". L'onglet récap, récapitule certaines infos qui se trouve dans les onglets mois.
J'ai souhaité que dans l'onglet nommé "Recap" lorsqu'on double-clic sur une cellule, elle nous envoie directement sur la cellule de la feuille correspondante. Seul problème, j'ai besoin du mois de décembre de cette année et je viens de me rendre compte que les dates de décembre ne fonctionne pas...

Pourriez vous m'aider ?

Merci d'avance,

MDLRT44

 

[job75]

Bonsoir mdlrt44, bienvenue sur XLD,

Remplacez votre macro Worksheet_BeforeDoubleClick par celle-ci :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim lig&, col%, w As Worksheet, i As Variant
lig = Target.Row: col = Target.Column
If lig < 5 Or col = 1 Or Not (Cells(lig, 1) <> "" And Cells(lig + 1, 1) = "" Or Cells(lig - 1, 1) <> "" And Cells(lig, 1) = "") Then Exit Sub
Cancel = True
For Each w In Worksheets
    If w.Cells(3, col + 2) = Cells(3, col) Then 'dates
        i = Application.Match(Cells(lig + (Cells(lig, 1) = ""), 1), w.Columns(2), 0)
        If IsNumeric(i) Then
            w.Visible = xlSheetVisible 'si la feuille est masquée
            Application.Goto w.Cells(i - (Cells(lig, 1) = ""), col + 2)
        End If
        Exit For
    End If
Next
End Sub

A+

 

[job75]

Bonjour mdlrt44, le forum,

On notera que la macro précédente fonctionne bien même si dans les feuilles des mois il manque des noms de techniciens ou si les lignes 16 (NORD) et 21 (EST) sont supprimées.

Bonne journée.

 

[mdlrt44]

Bonjour Job75,

Merci beaucoup pour votre retour.
Je suis seulement ennuyé parce que le fichier que j'ai fourni n'est pas mon fichier final et je n'arrive pas à adapter la macro à mon fichier. il y a 1 onglets par mois, est ce que c'est ça qui pourrait poser problème ?

Bonne journée,

 

[job75]

Le nombre de mois n'a pas d'importance mais quand on joint un fichier il faut qu'il soit structuré comme le fichier réel.

 

[mdlrt44]

Je sais bien , mais la structure est très similaire, je pensais pouvoir faire les modifications nécessaires pour l'adapter à mon fichier final. Mais visiblement je n'y arrive pas.

Je vous joint un nouveau fichier. La structure est exactement la même, il est juste moins complet que celui dont je me servirais.

 

[job75]

Non, la structure n'est pas similaire à celle des fichiers des posts #1 et #2.

Les dates en feuille "RECAP" ont été modifiées mais tant mieux, ça m'a permis de voir que ma solution n'allait pas.

Ensuite les noms des techniciens ne correspondent pas à ceux des feuilles des mois, j'ai donc corrigé.

Enfin les couleurs des cellules ne correspondent plus, je n'ai pas corrigé.

Cette nouvelle macro dans le fichier joint doit cependant faire l'affaire :

 Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim lig&, col%, w As Worksheet, j As Variant, i As Variant
lig = Target.Row: col = Target.Column
If lig < 5 Or col < 3 Or Not (Cells(lig, 1) <> "" And Cells(lig + 1, 1) = "" Or Cells(lig - 1, 1) <> "" And Cells(lig, 1) = "") Then Exit Sub
Cancel = True
For Each w In Worksheets
    If w.Name <> Me.Name Then
        j = Application.Match(Cells(3, col), w.Rows(3), 0)
        If IsNumeric(j) Then
            i = Application.Match(Cells(lig + (Cells(lig, 1) = ""), 1), w.Columns(2), 0)
            If IsNumeric(i) Then
                w.Visible = xlSheetVisible 'si la feuille est masquée
                Application.Goto w.Cells(i - (Cells(lig, 1) = ""), j)
            End If
            Exit Sub
        End If
    End If
Next w
End Sub

 

[mdlrt44]

Bonjour,

Merci beaucoup du retour ça fonctionne !!