XL 2019 direct plus rapide

[frederio]

Bonsoir a tous

Tu vous connais comment faire code vba

Je voudrais copie toujours la plage G5 à H375 Sur la 1ère feuille "JUPILER PRO LEAGUE" Et Sur la 2ère feuille "%" coller I5 à J409

La macro s'exécute en 0,10 seconde et peut aller plus vite.

Si tu veux être d’accord avec moi ??? vous m’aidez a expliqué comme Excel Merci

 

[job75]

Bonjour frederio,

Si tu veux être d’accord avec moi ???

Ben moi pas d'accord, c'est G4 et pas G5...

Et vous pourriez vous arranger pour qu'il y ait le même nombre de lignes vides entre les tableaux, non ?.

Mais bof lancez cette macro du Module1 :

Sub Transfert()
Dim source As Range, dest As Range, jour%
Set source = Sheets("JUPILER PRO LEAGUE").[G4:H12]
Set dest = Sheets("%").[I5:J13]
Application.ScreenUpdating = False
For jour = 1 To 34
    dest(0, -1) = "JOURNEE " & jour 'titre
    dest = source.Value 'copie les valeurs
    Set source = source.Offset(11)
    Set dest = dest.Offset(12)
Next
End Sub

Chez moi sur Win 11 Excel 2019 elle s'exécute en 3,6 secondes.

A+

 

[job75]

En ajoutant les Application.Calculation l'exécution se réduit à 0,20 seconde :

Sub Transfert()
Dim source As Range, dest As Range, jour%
Set source = Sheets("JUPILER PRO LEAGUE").[G4:H12]
Set dest = Sheets("%").[I5:J13]
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
For jour = 1 To 34
    dest(0, -1) = "JOURNEE " & jour 'titre
    dest = source.Value 'copie les valeurs
    Set source = source.Offset(11)
    Set dest = dest.Offset(12)
Next
Application.Calculation = xlCalculationAutomatic
End Sub

 

[frederio]

c'est parfait ! j ai fait déjà tous 8 fichier Excel vba

oublie ajouter ôtez la protection VB

 

[job75]

Si la feuille de destination est protégée il faut connaître le mot de passe, si c'est "toto" :

Sub Transfert()
Dim source As Range, dest As Range, jour%
Set source = Sheets("JUPILER PRO LEAGUE").[G4:H12]
Set dest = Sheets("%").[I5:J13]
Application.ScreenUpdating = False
Application.Calculation = xlCalculationManual
dest.Parent.Protect "toto", UserInterfaceOnly:=True
For jour = 1 To 34
    dest(0, -1) = "JOURNEE " & jour 'titre
    dest = source.Value 'copie les valeurs
    Set source = source.Offset(11)
    Set dest = dest.Offset(12)
Next
Application.Calculation = xlCalculationAutomatic
End Sub

 

[frederio]

merci beaucoup job75