Derniere valeur à droite d'une ligne.

[karinette]

Bonjour à tous ....
J'ai fait plusieurs recherches, mais je n'arrive pas à trouver la solution à mon problème.
Voila mon soucis : J'ai une vingtaine de ligne avec des series de chiffres. J'aimerais savoir s'il existe une formule qui me permettrait de recuperer la dernière valeur la plus à droite d'une ligne.
Sachant que cette valeur est toujours la dernière de ma serie, mais pas toujours au même endroit (parfois en colonne J, parfois en colonne H, etc...).
Exemple en A1 = La dernière valeur de la plage B1:H1.
On m'a dit qu'il existait une formule ... Mais cela me depasse un peu ... 😱

 

[Tibo]

Re : Derniere valeur à droite d'une ligne.

Bonjour,

Tu peux essayer avec cette formule :

=RECHERCHE(9^9;A1:M1)

Plage de cellules à adapter

Formule valable pour donner le dernier nombre.

Je te laisse essayer

@+

 

[abcd]

Re : Derniere valeur à droite d'une ligne.

Bonjour,

Si la valeur est numérique : =RECHERCHE(9^9;B1:H1)
Si elle est alphabétique : =RECHERCHE("zzz";B1:H1)

abcd

 

[tototiti2008]

Re : Derniere valeur à droite d'une ligne.

Bonjour karinette,

en admettant qu'aucune de tes lignes de valeurs ne dépasse la colonne K :

=RECHERCHE(9^99;A1:K1)

 

[Raja]

Re : Derniere valeur à droite d'une ligne.

Bonjour,

Si c'est du numérique la formule suivante donnera la dernière valeur de la ligne 1 :

=RECHERCHE(9^9;1:1)

Si c'est du texte, la formule suivante :

=RECHERCHE("z";1:1)

Formules à adapter selon tes besoins.

édit : Salut abcd, tototiti2008

 

[karinette]

Re : Derniere valeur à droite d'une ligne.

Cette formule marche mais ne prend pas en compte mon chiffre lorsqu'il a un point :
Si j'ai "44", puis "45.58", il m'affiche "44" alors que le dernier est celui avec le point ...
😕

 

[tototiti2008]

Re : Derniere valeur à droite d'une ligne.

Bonjour à tous,

45.58 est-il considéré comme du texte dans Excel ? quel séparateur décimal utilises-tu ?

 

[karinette]

Re : Derniere valeur à droite d'une ligne.

Aïe !!
La valeur 45.58 est effectivement considéré comme du texte ....
Le soucis c'est que les données sont rapatriées d'un programme qui ne fait pas la difference ...
Sans le point, c'est du chiffre et avec le point c'est du texte ...
Peut-on combiner les deux formules ???
🙁

 

[tototiti2008]

Re : Derniere valeur à droite d'une ligne.

oui, sans doute. mais celà ne te posera pas de problème que ça ne soit pas considéré en numérique ? parce que si tu dois tout convertir en numérique, pas besoin de compliquer la formule.

 

[Tibo]

Re : Derniere valeur à droite d'une ligne.

re,

Il faudrait savoir si la ligne ne comporte que des données numériques (ou pseudo-numériques dû à l'import), auquel cas, on recherche la dernière valeur alphanumérique avec RECHERCHE("zzz";....

Par contre, si on a à la fois des données pseudo-numériques et alphanumériques, ça se complique un peu. Sans doute une possibilité avec une formule matricielle.

Je regarderai en fonction de ta réponse et de ton besoin

Bon app

@+

 

[karinette]

Re : Derniere valeur à droite d'une ligne.

En fait, je ne travaillerais pas les chiffres, il seront juste imprimés ...

 

[tototiti2008]

Re : Derniere valeur à droite d'une ligne.

peut-être :

=SI(ESTERREUR(RECHERCHE(9^9;A1:H1));RECHERCHE("zzz";A1:H1);SI(ESTERREUR(RECHERCHE("zzz";A1:H1));RECHERCHE(9^9;A1:H1);INDEX(A1:H1;1;MAX(EQUIV(RECHERCHE(9^9;A1:H1);A1:H1;0);EQUIV(RECHERCHE("zzz";A1:H1);A1:H1;0)))))


Edit : à noter que si la même valeur se répète 2 fois sur la même ligne, ça peut poser des soucis...

 

[karinette]

Re : Derniere valeur à droite d'une ligne.

Ca marche !!!!
Vraiment très fort, tototiti2008 .....
Bravo et merci !!
🙂

 

[abcd]

Re : Derniere valeur à droite d'une ligne.

Bonjour,

Il y aussi pour la dernière valeur de la plage A1:A1000 :

=INDIRECT("A"&SOMMEPROD((LIGNE(A1:A1000)<=MAX((A1:A1000<>"")*LIGNE(A1:A1000)))*1))

abcd

 

[Monique]

Re : Derniere valeur à droite d'une ligne.

Bonjour,

Une autre

La dernière valeur (nombre ou texte) à droite dans la plage A1:H1
=INDEX(A1:H1;(MAX(SI(A1:H1<>"";COLONNE(A1:H1)))))

Formule matricielle, à valider par ctrl, maj et entrée