Autres créer une chaîne numérique formaté en fonction du nombre de caractères

patricktoulon · 25 Octobre 2019

bonjour a tous
je simplifie mes macros
aujourd'hui je cherche a formater une chaîne numérique par groupe de 3 quelque soit le nombre de caractères

12345: doit donner 012 345

1234567: doit donner 001 234 567

j'ai tenté mod mais ca match pas a tout les coups

VB:

Sub test()
   Dim chaine$, adding$
    chaine = "12345678910111213182"
    adding = String(Len(chaine) Mod 3 + IIf(Len(chaine) Mod 3 > 0, 1, 0), "0")
    chaine = Format(adding & chaine, Application.Rept(" @@@ ", Len(chaine)))
    MsgBox chaine
End Sub

quelqu'un a une idée sans boucle

danielco · 25 Octobre 2019

Bonjour,

S'il s'agit de nombres :

VB:

    chaine = "12345678910111213182"
    chaine = IIf(Len(chaine) Mod 3 > 0, "0", "") & Format(chaine, "0,000")

Cordialement.

Daniel

patricktoulon · 25 Octobre 2019

bonjour danielco
non ca marche pas dans tout les cas

VB:

Sub test()
   Dim chaine$, adding$
    chaine = "1234567891011121318221"
    chaine = IIf(Len(chaine) Mod 3 > 0, "0", "") & Format(chaine, "0,000")
MsgBox chaine
End Sub

danielco · 25 Octobre 2019

Peut-être :

VB:

    chaine = "12345678910111213182"
    txt = Format(chaine, "0,000")
    txt = InStr(1, txt, Chr(160))
    chaine = Application.Rept("0", 4 - txt) & Format(chaine, "0,000")

Daniel

job75 · 25 Octobre 2019

Bonjour patricktoulon, danielco,

Fichier joint avec cette fonction VBA :

VB:

Function F(n As Variant) As String
F = RTrim(Format(n, Application.Rept("000 ", Application.RoundUp(Len(CStr(n)) / 3, 0))))
End Function

A+

patricktoulon · 25 Octobre 2019

bonjour Job75
woah il fallait y penser (formater avec avec une forme calculé) et non calculer les"0" en plus pour construire le pattern de format
c'est bien ca ?
les zero s'ajoute en fonction de format

+++

patricktoulon · 26 Octobre 2019

bonsoir a tous
ou lala!! Job75
c'est pas résolu du tout

VB:

Sub test1()
Dim chaine
chaine = ("551561571581591501570268354298")
Debug.Print RTrim(Format(chaine, Application.Rept("000 ", Application.RoundUp(Len(CStr(chaine)) / 3, 0))))
End Sub

resultat
551 561 571 581 592 000 000 000 000 000

ça va plus du tout

job75 · 27 Octobre 2019

Bonsoir patricktoulon,

Oui la fonction Format convertit n en nombre et il y a une limite.

Avec ce code il n'y a bien sûr plus de limite :

VB:

Function F(n As String) As String
Dim ub%, a$(), i%
ub = Application.RoundUp(Len(n) / 3, 0)
ReDim a(1 To ub)
For i = Len(n) - 2 To 1 Step -3
    a(ub) = Mid(n, i, 3)
    ub = ub - 1
Next
If a(1) = "" Then a(1) = Left(String(Abs(i) + 1, "0") & n, 3)
F = Join(a)
End Function

Les caractères peuvent d'ailleurs être quelconques...

Fichier (2).

Bonne nuit.

Dranreb · 27 Octobre 2019

Bonsoir.
Celle ci fonctionne jusqu'à '79228162514264337593543950335 (2^96 - 1) :

VB:

Function Groupe3(ByVal Txt As String) As String
   Groupe3 = Format(CDec(Txt), "0,000")
   End Function

patricktoulon · 27 Octobre 2019

re
voila ce dont je me sert depuis dix ans
je voulais juste savoir si on pouvait encore simplifier

VB:

Sub test()
chaine = "1234567831"
If Len(chaine) Mod 3 <> 0 Then chaine = Application.Rept("0", 3 - Len(chaine) Mod 3) & chaine    'on formate l'entier a 3 chiffre par tranche
MsgBox Format(chaine, Application.Rept(" 000", Len(chaine) / 3))
End Sub

bonjour @Dranreb je vais tester

patricktoulon · 27 Octobre 2019

@Dranreb ca ne rajoute pas les zero manquants

VB:

Sub test2()

chaine = "1234567831123654785654784521"
Debug.Print Format(CDec(chaine), "0,000")
End Sub

resultat
1 234 567 831 123 654 785 654 784 521

patricktoulon · 27 Octobre 2019

re
je pensait que l'on allait trouver mieux dix ans apres mais non
comme ça je suis illimité

VB:

Sub test()
chaine = "1234567831123654785654784521425654122145232564"
If Len(chaine) Mod 3 <> 0 Then chaine = Application.Rept("0", 3 - Len(chaine) Mod 3) & chaine    'on formate l'entier a 3 chiffre par tranche
MsgBox Format(chaine, Application.Rept(" @@@", Len(chaine) / 3))
End Sub

Dranreb · 27 Octobre 2019

Comme ça alors :

VB:

Function Groupe3(ByVal Txt As String) As String
   Groupe3 = String((30 - Len(Txt)) Mod 3, "0") & Format(CDec(Txt), "0,000")
   End Function

Mais ça ne convient pas pour des textes de plus de 29 chiffres.

Dranreb · 27 Octobre 2019

Pour que ça convienne à des textes jusqu'à 300 de long (augmentable) :

VB:

Function Groupe3(ByVal Txt As String) As String
   Txt = String((300 - Len(Txt)) Mod 3, "0") & Txt
   Groupe3 = Format(Txt, WorksheetFunction.Rept(" @@@", Len(Txt) / 3))
   End Function

Mais on en vient tout doucement à ce que tu avais fait.

patricktoulon · 27 Octobre 2019

re
et oui je suis obligé de travailler en string je vais jusqu'au sextillion (30 caractères)

123 456 789 123 456 789 123 456 789 123

avec cdec j'ai 2 chiffres en trop(dépassement de capacité)
cela dit je pourrais très bien m’arrêter au milliard ou billiard

Autres créer une chaîne numérique formaté en fonction du nombre de caractères

patricktoulon

XLDnaute Barbatruc

danielco

XLDnaute Accro

patricktoulon

XLDnaute Barbatruc

danielco

XLDnaute Accro

job75

XLDnaute Barbatruc

Pièces jointes

patricktoulon

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

Dranreb

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Dranreb

XLDnaute Barbatruc

Dranreb

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc