Création d'une fonction

[Sebwan]

Bonjour le forum,

Après avoir crée quelques macro VBA, j'aimerais construire une fonction, et je rencontre quelques problèmes (quelle dimension utilisée,...). L'idée est de partie de 2 vecteurs de nombres (mis en lignes ou en colonnes), afin d'en calculer une valeur actuelle...Mais je ne sais pas:

*quelle dimension utilisée pour les vecteurs
*comment aller rechercher l'élément i du vecteur
*comment aller rechercher la longueur de mes vecteurs (longueur variable, mais identique entre les 2 variables)...

Voici mon début de programmation (avec quelques erreurs...)

Function actu(tabl As Range, vale As Range)

a = Length(tabl)
somm = 0
taux1 = 1 / (1 + tabl(1))
valeur1 = vale(1)

For j = 1 To a

If j = 1 Then
taux1 = tabl(1)
valeur1 = vale(1)
somm = valeur1 / taux1
tauxjmoins1 = taux1

Else
tauxj = tauxjmoins1 * tabl(j)
somm = somm + vale(j) / tauxj
tauxjmoins1 = tauxj
End If
Next
End Function

Merci d'avance!

 

[job75]

Re : Création d'une fonction

Bonjour Sebwan,

Ben dites donc, faut travailler un peu VBA...

Cela dit, si vous nous disiez clairement ce que vous voulez que la fonction vous renvoie, on pourrait peut-être vous aider.

A+

 

[Sebwan]

Re : Création d'une fonction

Pour vous permettre de mieux visualiser ce que je souhaite faire, voici un exemple en excel...

 

[Compte Supprimé 979]

Re : Création d'une fonction

Salut Job75 😉
Bonjour Sebwan

En plus de ce qu'a dis Job75, une petite feuille avec des données et le résultat excompté serait la bienvenue

A+

 

[Sebwan]

Re : Création d'une fonction

L'idée par rapport à mon exemple, c'est d'avoir actu(B2:B5;C2:C5) qui me donne le résultat en C8!

 

[mromain]

Re : Création d'une fonction

bonjour Sebwan, Bruno, job,

voici un essai :

Public Function actu(zone1 As Range, zone2 As Range) As Double
Dim i As Integer, j As Integer, tmp As Double
'zone1 et zone2 doivent être des données sous formes de colonnes
Set zone1 = zone1.Resize(zone1.Rows.Count, 1)
Set zone2 = zone2.Resize(zone2.Rows.Count, 1)
'si zone1 et zone2 ne font pas la même taille, quitter la fonction
If zone1.Cells.Count <> zone2.Cells.Count Then Exit Function
For i = 1 To zone1.Cells.Count
    tmp = 1
    For j = 1 To i
        tmp = tmp * (1 + zone2(j))
    Next j
    actu = actu + zone1(i) / tmp
Next i
End Function

a+

 

[Sebwan]

Re : Création d'une fonction

Super, ça fonctionne! (ça me permet au passage d'apprendre un peu le VBA ;-) )

Un grand merci à vous!

 

[job75]

Re : Création d'une fonction

Re, salut mromain, tu es rapide 🙂

Ma solution (avec des plages dynamiques nommées dans la feuille) :

Function Actu(taux As Range, vale As Range) As Double
Dim prod As Double, i As Long
prod = 1
For i = 1 To taux.Count
prod = prod * (1 + taux.Cells(i, 1))
Actu = Actu + vale.Cells(i, 1) / prod
Next
End Function

Edit : peut-être peut-on se passer de VBA, avec une formule générale dans la feuille (quelque soit la dimension des vecteurs) ?

A+