XL 2019 Copier le contenu d'un MsgBox ou d'une variable

Sub calcul()
  Dim ligori As Long
  Dim cumul As Long
  ligori = 1
  While Cells(ligori, 1) <> ""
    cumul = Cells(ligori, 1) + cumul
    ligori = ligori + 1
  Wend
  MsgBox "Le total est de " & cumul
  On Error Resume Next
  Dim Rng As Range
OnRecommence:
  Set Rng = Application.InputBox("Sélectionnez la cellule dans laquelle coller le résulat", "CHOIX CELLULE", Type:=8)
  If Err <> 0 Then
    Err.Clear
    MsgBox "Vous devez sélectionner une cellule !"
    GoTo OnRecommence
  End If
  Rng.Value = cumul
End Sub

Option Explicit
Private Declare Function OpenClipboard Lib "user32.dll" (ByVal hWnd As Long) As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Declare Function IsClipboardFormatAvailable Lib "user32.dll" (ByVal wFormat As Long) As Long
Private Declare Function GetClipboardData Lib "user32.dll" (ByVal wFormat As Long) As Long
Private Declare Function SetClipboardData Lib "user32.dll" (ByVal wFormat As Long, ByVal hMem As Long) As Long
Private Declare Function GlobalAlloc Lib "kernel32.dll" (ByVal wFlags As Long, ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32.dll" (ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32.dll" (ByVal hMem As Long) As Long
Private Declare Function GlobalSize Lib "kernel32" (ByVal hMem As Long) As Long
Private Declare Function lstrcpy Lib "kernel32.dll" Alias "lstrcpyW" (ByVal lpString1 As Long, ByVal lpString2 As Long) As Long
Public Property Let PressePapier(ByVal sUniText As String)
   Dim iStrPtr As Long
   Dim iLen As Long
   Dim iLock As Long
   Const GMEM_MOVEABLE As Long = &H2
   Const GMEM_ZEROINIT As Long = &H40
   Const CF_UNICODETEXT As Long = &HD
   OpenClipboard 0&
   EmptyClipboard
   iLen = LenB(sUniText) + 2&
   iStrPtr = GlobalAlloc(GMEM_MOVEABLE Or GMEM_ZEROINIT, iLen)
   iLock = GlobalLock(iStrPtr)
   lstrcpy iLock, StrPtr(sUniText)
   GlobalUnlock iStrPtr
   SetClipboardData CF_UNICODETEXT, iStrPtr
   CloseClipboard
   End Property
Public Property Get PressePapier() As String
   Dim iStrPtr As Long
   Dim iLen As Long
   Dim iLock As Long
   Dim sUniText As String
   Const CF_UNICODETEXT As Long = 13&
   OpenClipboard 0&
   If IsClipboardFormatAvailable(CF_UNICODETEXT) Then
      iStrPtr = GetClipboardData(CF_UNICODETEXT)
      If iStrPtr Then
         iLock = GlobalLock(iStrPtr)
         iLen = GlobalSize(iStrPtr)
         sUniText = String$(iLen \ 2& - 1&, vbNullChar)
         lstrcpy StrPtr(sUniText), iLock
         GlobalUnlock iStrPtr
         End If
      PressePapier = sUniText
      End If
   CloseClipboard
   End Property

Public Function ClearPressePapier()
With CreateObject("htmlfile").parentwindow.clipboardData.clearData("Text"): End With
End Function
Public Property Let PressePapier(valeur)
With CreateObject("htmlfile").parentwindow.clipboardData.setData("Text", valeur): End With
End Property
Public Property Get PressePapier()
PressePapier = CreateObject("htmlfile").parentwindow.clipboardData.GetData("TEXT")
End Property

Sub calcul()
Dim ligori As Long
Dim cumul As Long
ligori = 1
While Cells(ligori, 1) <> ""
cumul = Cells(ligori, 1) + cumul
ligori = ligori + 1
Wend
'MsgBox "Le total est de " & cumul
ClearPressePapier
PressePapier = CStr(cumul)  'cumul se retrouve dans le pressePapier
End Sub

Sub Calcul()
Dim ligori As Long, cumul As Long
   With Sheets("Feuil1")
      ligori = 1: Do Until .Cells(ligori, "a") = "": cumul = cumul + .Cells(ligori, "a"): ligori = ligori + 1: Loop
   End With
   ActiveCell = cumul
End Sub

Sub Calcul()
Dim ligori&, cumul&, i&, j&, DataObj As New DataObject
   With Sheets("Feuil1")
      ligori = 1: Do Until .Cells(ligori, "a") = "": cumul = cumul + .Cells(ligori, "a"): ligori = ligori + 1: Loop
      DataObj.SetText cumul: DataObj.PutInClipboard
      MsgBox "Le cumul : " & Format(cumul, "#,##0") & " a été copié dans le presse-papier."
   End With
End Sub