Convertir des heures au format 1h25min3s au format 01:25:03

[juanmarco]

Bonjour,

Depuis peu mes factures de téléphonie comportent non plus les temps au format Excel mais sous la forme 39s, ou 38min1s ou 1h24min3s....
J'ai trouvé comment transformer par les formules suivantes chacun des cas de figure mais je n'arrive pas à trouver une formule qui soit valable pour tous les cas de figures, (uniquement des secondes, min+s ou h+min+s)

Pour l'hypothèse ou j'ai en A1 la valeur :
1) 39s, j'utilise la formule =SI(TROUVE("s";A1);SUBSTITUE(A1;"s";"")/(3600*24))

2) 38min1s, j'utilise =SI(TROUVE("min";A2);SUBSTITUE(SUBSTITUE(A2;"min";":");"s";"")/60)

3) 1h24min3s, j'utilise
=SI(TROUVE("h";A3);SUBSTITUE(SUBSTITUE(SUBSTITUE(A3;"h";":");"min";":");"s";"")*1)

Merci de bien vouloir m'indiquer comment unifier ces formules dans une seule pour l'utiliser quelle que soit la durée en A1.

Merci d'avance.

 

[eddy51]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonjour,
Pourquoi vouloir les unifié si en A1 tu veut toujours des seconde en A2 des minute et en A 3 des heures ?

 

[juanmarco]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonjour Eddy,

Je veux pouvoir avec des valeurs en A1, A2, A3...sous forme 3h25min3s..., les transformer en format hh:mm:ss pour en faire ensuite une somme (durée totale des valeurs de toutes les lignes (voir fichier joint)

 

[eddy51]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Un SI a 3 condition avec une condition pour les secondes une pour minutes secondes une pour secondes minute heure.

 

[juanmarco]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

J'entends bien, mais la question est celle de la syntaxe d'imbrication du "SI(OU(TROUVE(SUBSTITUE" pour les 3 cas de figure, le tout étant d'avoir une formule unique quel que soit le contenu des lignes de la colonne A. Telle est ma problématique.

 

[Lolote83]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonjour,

Peut être une solution ici :

=SI(NBCAR(A3)>8;SUBSTITUE(SUBSTITUE(SUBSTITUE(A3;"h";":");"min";":");"s";"")*1;SI(NBCAR(A3)>3;SUBSTITUE(SUBSTITUE(A3;"min";":");"s";"")/60;SUBSTITUE(A3;"s";"")/(3600*24)))

Explication : Si il y a plus de 8 caractères, c'est que l'on a des heures, donc j'ai repris ta formule des heures
Sinon,
Si il y a plus de 3 caractères, c'est qu'il y a des minutes, donc j'ai repris ta formule des minutes
Sinon,
C'est qu'il y a uniquement des secondes et j'ai repris ta formule des secondes.

En espérant avoir bien compris ta demande
Cordialement
Lolote83

 

[ROGER2327]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonjour à tous

Un essai :​

=SI(A1="";"";--SUBSTITUE(SUBSTITUE(SUBSTITUE(
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=0;A1;"")&
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=1;"0:"&A1;"")&
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=2;SUBSTITUE(A1;"h";":0:");"")&
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=3;"0:0:"&A1;"")&
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=4;A1;"")&
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=5;"0:"&A1;"")&
SI(ESTERR(CHERCHE("h";A1))+2*ESTERR(CHERCHE("min";A1))+4*ESTERR(CHERCHE("s";A1))=6;A1;"");
"h";":");"min";":");"s";""))

Comment ça, c'est lourd ?​

ROGER2327
#5986

Mercredi 4 Gidouille 139 (Sainte Tripe, républicaine - fête Suprême Quarte)
30 Prairial An CCXX, 6,2029h - chariot
2012-W25-1T14:53:13Z

 

[tototiti2008]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonjour juanmarco, Bonjour eddy, bonjour Lolote, Bonjour Roger 🙂,

Dans la mesure où il semble y avoir toujours des secondes, un essai

=SUBSTITUE(SUBSTITUE(SUBSTITUE(SI(ESTNUM(CHERCHE("h";A1));"";"00h")&SI(ESTNUM(CHERCHE("min";A1));"";"00min")&A1;"s";"");"min";":");"h";":")*1

 

[ROGER2327]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Re...

D'accord, c'est lourd ! Allégeons :​

=SI(B3="";"";--SUBSTITUE(SUBSTITUE(SUBSTITUE(
SI(ESTERR(CHERCHE("h";B3))+2*ESTERR(CHERCHE("min";B3))=2;SUBSTITUE(B3;"h";":0:");
SI(ESTERR(CHERCHE("h";B3))+2*ESTERR(CHERCHE("min";B3))=1;"0:"&B3;"")&
SI(ESTERR(CHERCHE("h";B3))*ESTERR(CHERCHE("min";B3));"0:0:"&B3;"")&
SI(ESTERR(CHERCHE("h";B3));"";B3));
"h";":");"min";":");"s";""))

ROGER2327
#5987

Mercredi 4 Gidouille 139 (Sainte Tripe, républicaine - fête Suprême Quarte)
30 Prairial An CCXX, 7,0886h - chariot
2012-W25-1T17:00:45Z

 

[job75]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonjour à tous,

Une solution par fonction VBA :

Function CONV(txt$) As Date
txt = Replace(txt, " ", "") 'sécurité
CONV = R(txt, "h") / 24 + R(txt, "min") / 1440 + R(txt, "s") / 86400
End Function

Function R&(txt$, t$)
Dim pos%, i%
pos = InStr(txt, t)
If pos = 0 Then Exit Function
For i = pos - 1 To 1 Step -1
  If Not IsNumeric(Mid(txt, i, 1)) Then Exit For
Next
R = Val(Mid(txt, i + 1))
End Function

Fichier joint.

A+

 

[juanmarco]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonsoir à Eddy, Lolote, Tototiti et Roger,

Vous avez fait un excellent travail dont je vous remercie très sincèrement.

Cependant les résultats bien que très satisfaisants ne sont pas encore parfaits dans tous les cas de figure. J'ai bien essayé de modifier les formules mais je tombe de Charybde en Scylla !
Aussi, je joins un fichier qui reprend vos formules et les résultats obtenus afin que vous puissiez les optimiser autant que faire se peut.

Merci d'avance pour vos résultats dont je ne doute pas.

Bien cordialement
juanmarco

 

[job75]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Re,

Un léger oubli j'espère.

Edit : quant à ROGER c'est un philosophe qui en a vu d'autres, mais quand même !

A+

 

[juanmarco]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonsoir Job75,

Toutes mes excuses, mais je n'avais pas retenu votre solution dans la mesure où j'utilise open office et que je ne peux pas importer les macros issues d'Excel. Vous n'avez pas démérité pour autant. Je vous suis reconnaissant pour l'aide apportée.

Bien cordialement
juanmarco

 

[Modeste geedee]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bobsour®

Aussi, je joins un fichier qui reprend vos formules et les résultats obtenus afin que vous puissiez les optimiser autant que faire se peut.

autre proposition 😎

 

[ROGER2327]

Re : Convertir des heures au format 1h25min3s au format 01:25:03

Bonsoir à tous

Bonsoir à Eddy, Lolote, Tototiti et Roger,

Vous avez fait un excellent travail dont je vous remercie très sincèrement.

Cependant les résultats bien que très satisfaisants ne sont pas encore parfaits dans tous les cas de figure. J'ai bien essayé de modifier les formules mais je tombe de Charybde en Scylla !
Aussi, je joins un fichier qui reprend vos formules et les résultats obtenus afin que vous puissiez les optimiser autant que faire se peut.

Merci d'avance pour vos résultats dont je ne doute pas.

Bien cordialement
juanmarco

Mort de rire, le Roger ! J'en ai déjà vu pas mal, mais celle-là, on ne me l'avait jamais faite !

Merci à vous juanmarco : les occasions de rigoler ne sont pas tellement nombreuses ces temps-ci.

J'ai optimisé à donf dans le classeur joint. Bonne nuit !​

ROGER2327
#5989

Mercredi 4 Gidouille 139 (Sainte Tripe, républicaine - fête Suprême Quarte)
30 Prairial An CCXX, 9,1290h - chariot
2012-W25-1T21:54:34Z