conversion heure minutes secondes

[uhaina]

bonsoir

j'ai un tableau avec une colonne sensée contenir les heures mais sous la forme de nombre comme :

154332 pour 15 heures 43 mn 32 sec

comment convertir ces nombres au format excel 15:43:32

merci de me venir en aide

 

[Catrice]

Re : conversion heure minutes secondes

Bonsoir,

en A1 : 154332

en B1 :
=TEMPS(GAUCHE(A2;SI(NBCAR(A2)=6;2;1));STXT(A2;SI(NBCAR(A2)=6;3;2);2);DROITE(A2;2))

fonctionne aussi avec 54332

Si les heures sont tjs sur 6 digits, plus simple :
=TEMPS(GAUCHE(A1;2);STXT(A1;3;2);DROITE(A1;2))

 

[Monique]

Re : conversion heure minutes secondes

Bonjour,

Ou bien à essayer

Avec la cellule qui reçoit le résultat au format heure :
=(STXT(A1;1;2)&":"&STXT(A1;3;2)&":"&STXT(A1;5;2))*1
ou bien
=(ENT(A1/10000)+ENT(MOD(A1;10000)/100)/60+MOD(A1;100)/3600)/24

Mais…
Si par exemple 1 minute 23 secondes est écrit 123, la 1ère ne fonctionnera pas
Pour qu'elle fonctionne, il faut que A1 soit du texte et 1 min 23 sec écrit 000123
La 2ème devrait fonctionner, que A1 soit du texte ou une valeur numérique

 

[Monique]

Re : conversion heure minutes secondes

Re,

Celle-ci est plus courte, en fin de compte :
=TEXTE(A1;"00"":""00"":""00")*1

Ce sont des doubles guillemets qui entourent les deux points

 

[Catrice]

Re : conversion heure minutes secondes

Arghh ...
Monique m'a pris de court !

=CNUM(TEXTE(A1;"00"":""00"":""00"))

Et en plus fonctionne dans tous les cas de figure...

 

[uhaina]

Re : conversion heure minutes secondes

merci beaucoup pour la réponse c'est super

uhaina