Consolider les infos de 6 feuille dans une (facile)

[BAT]

Bonjour à tous les Exeliens et Exéliennes !

Je cherche à faire une chose qui semble simple mais qui demande de bonnes base en VBA que je n’ai pas.

Présentation du classeur :
J’ai 5 feuilles (P1, R1, R2, R3, R4, R5). Toutes les entêtes de collone sont identiques. Elle sont complétée d’informaions saisies en ligne. J’ai une 6ème feuille (TOTAL) qui à également les mêmes en-tête.

Principe de l’action à réaliser en VBA :
Je souhaite simplement que la macro reprenne l’ensemble des informations contenues dans les 5 Feuilles (P1, R1, R2, R3, R4, 45) et me les colle les unes sous les autres dans la feuille total.

J’ai réaliser le classeur que je joint qui présente l’ergonomie des feuilles.

J’espère que vous aurez une solution à m’apporter !! En attendant je vous souhaite une très bonne journée à tous.

 

[nat54]

Re : Consolider les infos de 6 feuille dans une (facile)

Bonjour,

Voilà ce que je propose ; à mon avis le code n'est pas optimal mais ca marche

 

[Hervé]

Re : Consolider les infos de 6 feuille dans une (facile)

bonjour tout le monde

si si nat, ton code est meme tres optimisé, peut etre trop 😀

une autre solution a travers cette version :

Dim ws As Worksheet
Dim wsdesti As Worksheet
Dim plage As Range
Dim derligne As Long

Set wsdesti = Worksheets("TOTAL")

For Each ws In Worksheets
    If ws.Name <> "TOTAL" And ws.Name <> "S6 (2)" Then
        With ws.UsedRange
            Set plage = .Offset(6, 0).Resize(.Rows.Count - 6, .Columns.Count)
        End With
            derligne = wsdesti.Range("a65536").End(xlUp).Row + 1
            plage.Copy Destination:=wsdesti.Cells(derligne, 1)
    End If
Next ws

salut

 

[nat54]

Re : Consolider les infos de 6 feuille dans une (facile)

Te moquerais-tu de moi ?

ps : je comprends ton code, mais j'y serais jms arrivée

 

[Hervé]

Re : Consolider les infos de 6 feuille dans une (facile)

re

je n'oserai pas me moquer de toi nat 🙂

par contre tu m'avouera que le code que tu fournis dans ta premiere intervention est vraiment léger, LOL

bye

 

[BAT]

Re : Consolider les infos de 6 feuille dans une (facile)

GEANT !! et avec si peu de code ! MErci infiniment !

Par contre j'avoue ne pas saisir la proposition de nat ! Il y à encore moin de code mais ça ne marche pas aussi bien !! 😀

 

[nat54]

Re : Consolider les infos de 6 feuille dans une (facile)

Ah m** je viens de comprendre
l'oubli de PJ 😀 😀

 

[BAT]

Re : Consolider les infos de 6 feuille dans une (facile)

OUps !

J'ai modifié mon fichié et j'ai des feuilles en plus ! Mais celleci je ne souhaite pas les avoir dans ma consolidation. Seules les 5 feuilles initiales (P1, R1, R2, R3, R4, R5). doivent se consolider !!! Est-ce possibe en utilisant le même code ?

Nat, je n'arrive pas à ouvrir le fichier zip (fichier endommagé) !

Merci d'avance !!

 

[Hervé]

Re : Consolider les infos de 6 feuille dans une (facile)

re

peut etre comme ceci :

Dim ws
Dim wsdesti As Worksheet
Dim plage As Range
Dim derligne As Long

Set wsdesti = Worksheets("TOTAL")

For Each ws In Array("P1", "R1", "R2", "R3", "R4", "R5")
    With Sheets(ws).UsedRange
        Set plage = .Offset(6, 0).Resize(.Rows.Count - 6, .Columns.Count)
    End With
        derligne = wsdesti.Range("a65536").End(xlUp).Row + 1
        plage.Copy Destination:=wsdesti.Cells(derligne, 1)
Next ws

salut

 

[BAT]

Re : Consolider les infos de 6 feuille dans une (facile)

Total class !

Merci beaucoup Hervé !

Par ailleur j'ai essayé de bidouiller la macro et j'ai réussi en comprennant que ça c'était les feuilles à ne pas prendre en compte !!!


If ws.Name <> "TOTAL" And ws.Name <> "S6 (2)" Then

 

[Hervé]

Re : Consolider les infos de 6 feuille dans une (facile)

re 🙂

tu as tout compris

cette syntaxe :

If ws.Name <> "TOTAL" And ws.Name <> "S6 (2)" Then

permet de "sauter" des feuilles lors de boucle for each ws in worksheets

en somme :

for each ws in worksheets=pour chaque feuille du classeur
If ws.Name <> "TOTAL" And ws.Name <> "S6 (2)" Then = si le nom de la feuille n'est pas TOTAL ou S6 (2), alors....

Mais il me semble plus judicieux de ne faire la boucle que sur les feuilles voulues (2ème code) comme ca, plus de souci en cas d'ajout de feuilles.

salut