Consolidation d'une liste d'entrées

[adesport]

Bonjour,

Je cherche à effectuer une consolidation mais je ne trouve pas le terme exacte pour trouver une solution sur ce forum.

L'idée est de faire un résumé d'une plage de lignes pour obtenir une somme.
Ce n'est a priori pas ce qu'on appelle une consolidation avec Excel.

Je sais le faire avec des RECHERV ou SOMME.SI mais c'est trop contraignant lorsque les données sources changent souvent. Il faudrait aussi que ce soit dynamique.

Exemple simple manuel en PJ.

Merci pour votre aide.

 

[Pierrot93]

Re : Consolidation d'une liste d'entrées

Bonjour,

ton fichier en retour avec un tableau croisé dynamique.

bon après midi
@+

 

[adesport]

Re : Consolidation d'une liste d'entrées

Merci Pierrot...

 

[job75]

Re : Consolidation d'une liste d'entrées

Bonjour adesport, salut Pierrot,

1) Formule matricielle en E3 :

=SI(LIGNES(E$2:E2)>SOMMEPROD(1/NB.SI(Nom;Nom));"";INDEX(B:B;MIN(SI(NB.SI(E$2:E2;Nom)=0;LIGNE(Nom)))))

A valider par Ctrl+Maj+Entrée et tirer vers le bas.

2) Formule en F3 :

=SI(E3="";"";NB.SI(Nom;E3))

Fichier joint.

A+

 

[job75]

Re : Consolidation d'une liste d'entrées

Re,

Si en colonne C il y a d'autres valeurs que des 1 utiliser en F3 :

=SI(E3="";"";SOMME.SI(Nom;E3;DECALER(Nom;;1)))

Fichier (2).

Nota : bien sûr vous avez compris que grâce au nom défini Nom le tableau est dynamique.

A+

 

[job75]

Re : Consolidation d'une liste d'entrées

Re,

Sur versions Excel 2007 et suivantes une variante pour la formule matricielle en E3 :

=SIERREUR(INDEX(B:B;EXP(LN(MIN(SI(NB.SI(E$2:E2;Nom)=0;LIGNE(Nom))))));"")

Fichier (3).

A+

 

[job75]

Re : Consolidation d'une liste d'entrées

Bonjour adesport, le forum,

S'il y a des "trous" dans la liste des noms, il faut modifier la définition de Nom.

Fichier (4).

Edit : noter qu'il serait possible, avec une formule plus compliquée, de classer les noms alphabétiquement.

A+

 

[adesport]

Re : Consolidation d'une liste d'entrées

Bonjour,

OUhaou, je ne comprends pas tout au premier coup d'oeil, je vais regarder en détail.

Merci,

 

[job75]

Re : Consolidation d'une liste d'entrées

Re,

Une formule matricielle en E3 qui classe les noms alphabétiquement :

=SIERREUR(INDEX(Nom;EQUIV(MIN(SI(ESTTEXTE(Nom)*(NB.SI(E$2:E2;Nom)=0);NB.SI(Nom;"<"&Nom)));SI(ESTTEXTE(Nom)*(NB.SI(E$2:E2;Nom)=0);NB.SI(Nom;"<"&Nom));0));"")

Fichier (5).

A+

 

[job75]

Re : Consolidation d'une liste d'entrées

Re,

Avec le nom défini matrice, cette formule en E3 ne nécessite plus de validation matricielle :

=SIERREUR(INDEX(Nom;EQUIV(MIN(matrice);matrice;0));"")

Fichier (6).

A+