Compteur sans doublon

G

Guest

Guest

• 25 Avril 2014

• #2

Re : Compteur sans doublon

bonjour,

Je préfère joindre un exemple en PJ plutot que de me perdre dans des explications.

Cliquez pour agrandir...

Nous sommes nombreux à n'ouvrir les fichiers QUE s'il y a explications dans la demande!

A+

 

Vote positif 0 Vote négatif

G

Gelinotte

XLDnaute Accro

• 25 Avril 2014

• #3

Re : Compteur sans doublon

Bonjour,

À tester :

=SOMME(SI(FREQUENCE(EQUIV(C8:C23;C8:C23;0);EQUIV(C8:C23;C8:C23;0))>0;1))

Cliquez pour agrandir...

 

Vote positif 0 Vote négatif

G

Guesh

XLDnaute Occasionnel

• 25 Avril 2014

• #4

Re : Compteur sans doublon

Ok !
donc en fait je voudrais avoir une formule en F3 qui me permette pour le Projet dit "A" (en colonne B) de compter le nombre de dites "désignation" en colonne C, mais sans compter les doublons.
donc dans mon exemple le résultat devrait être 8, mais comment le générer automatiquement ?

merci !

 

Vote positif 0 Vote négatif

G

Guest

Guest

• 25 Avril 2014

• #5

Re : Compteur sans doublon

Re,

Je vois que Gelinotte dans son immense esprit de solidarité, t'a déjà donné une réponse (incomplète).

A+

 

Dernière modification par un modérateur: 25 Avril 2014

Vote positif 0 Vote négatif

G

Guesh

XLDnaute Occasionnel

• 25 Avril 2014

• #6

Re : Compteur sans doublon

oui, merci !

 

Vote positif 0 Vote négatif

G

Guesh

XLDnaute Occasionnel

• 25 Avril 2014

• #7

Re : Compteur sans doublon

Hasco à dit:

Re,

Je vois que Gelinotte dans son immense esprit de solidarité, t'a déjà donné une réponse (incomplète).

A+

Cliquez pour agrandir...

Juste une petite question supp svp ...
La formule fonctionne, mais comment faire pour qu'elle soit rattachée au fait que le résultat correspond au Projet dit "A".
Car dans la réalité je peux avoir les mêmes désignations pour un projet dit B ou C.
Or ici je souhaite vraiment qu'il y ait un lien dans la formule avec le fait que l'on parle du Projet A.
j'ai complété mon exemple en PJ

merci

 

Pièces jointes

• test_compteur sans doublon v2.xls

  20.5 KB · Affichages: 29

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 25 Avril 2014

• #8

Re : Compteur sans doublon

Bonjour à tous,

La solution de Gélinotte ne tient aucun compte de la colonne B...

Code:

=SOMMEPROD((B$8:B$23=E3)*(LIGNE(C$8:C$23)=EQUIV(C$8:C$23;C:C;0)))

en tient compte.

Nota : sans la colonne B la méthode classique est celle-ci :

Code:

=SOMMEPROD(1/NB.SI(C$8:C$23;C$8:C$23))

A+

 

Dernière édition: 25 Avril 2014

Vote positif 0 Vote négatif

G

Guesh

XLDnaute Occasionnel

• 25 Avril 2014

• #9

Re : Compteur sans doublon

job75 à dit:

Bonjour à tous,

La solution de Gélinotte ne tient aucun compte de la colonne B...

Code:

=SOMMEPROD((B$8:B$23=E3)*(LIGNE(C$8:C$23)=EQUIV(C$8:C$23;C:C;0)))

en tient compte.



Nota : sans la colonne B la méthode classique est celle-ci :

Code:

=SOMMEPROD(1/NB.SI(C$8:C$23;C$8:C$23))

A+

Cliquez pour agrandir...

merci pour ton aide.
cependant qd j'applique la formule (=SOMMEPROD((B$8:B$23=E4)*(LIGNE(C$8:C$23)=EQUIV(C$8:C$23;C:C;0)))) en F4 je devrais avoir 2 comme résultat ... non ?

c'est pas ce que j'ai ...

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 25 Avril 2014

• #10

Re : Compteur sans doublon

Re,

Ah pardon, il faut traiter chaque projet séparément, donc formule matricielle en F3 :

Code:

=SOMME((B$8:B$23=E3)*ESTNUM(LN(LIGNE(C$8:C$23)=EQUIV(C$8:C$23;SI(B$8:B$23=E3;C$8:C$23);0)+MIN(LIGNE(C$8:C$23))-1)))

A valider par Ctrl+Maj+Entrée.

Fichier joint.

A+

 

Pièces jointes

• test_compteur sans doublon(1).xls

  23.5 KB · Affichages: 36

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 25 Avril 2014

• #11

Re : Compteur sans doublon

Bonjour @ tous,
Salut Job75,
En F3,

Code:

=NB(1/FREQUENCE(SI(B$8:B$23=E3;EQUIV(C$8:C$23;C$8:C$23;0));LIGNE(INDIRECT("1:"&LIGNES(C$8:C$23)))))

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

@ + +

 

Vote positif 0 Vote négatif

G

Guesh

XLDnaute Occasionnel

• 25 Avril 2014

• #12

Re : Compteur sans doublon

super !
merci !!!!

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 25 Avril 2014

• #13

Re : Compteur sans doublon

Re,

En fait le 1er test était inutile, ceci suffit :

Code:

=SOMME(--ESTNUM(LN(LIGNE(C$8:C$23)=EQUIV(C$8:C$23;SI(B$8:B$23=E3;C$8:C$23);0)+MIN(LIGNE(C$8:C$23))-1)))

Fichier (2).

Edit : hello R@chid

A+

 

Pièces jointes

• test_compteur sans doublon(2).xls

  23.5 KB · Affichages: 32

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 25 Avril 2014

• #14

Re : Compteur sans doublon

Re,

Ah mais bien sûr R@chid, avec NB c'est plus simple :

Code:

=NB(LN(LIGNE(C$8:C$23)=EQUIV(C$8:C$23;SI(B$8:B$23=E3;C$8:C$23);0)+MIN(LIGNE(C$8:C$23))-1))

Fichier (3).

A+

 

Pièces jointes

• test_compteur sans doublon(3).xls

  23.5 KB · Affichages: 29

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 25 Avril 2014

• #15

Re : Compteur sans doublon

Re,

@R@chid

Tu utilises INDIRECT, j'essaie quand c'est possible de l'éviter de même que DECALER car ce sont des fonctions volatiles.

C'est pour ça que j'utilise MIN(LIGNE(xxx)) pour déterminer la 1ère ligne de la plage...

A+

 

Vote positif 0 Vote négatif