Compter le nombre d'entrées différentes dans un tableau

[Excelleur]

Bonjour,

Je cherche une formule pour compter le nombre d'entrées différentes dans un tableau qui tiendrait compte des filtres que j'applique. Lorsque je n'applique pas de filtre la formule suivante fait l'affaire : =SOMMEPROD(1/NB.SI(Rencontres[ORGANISME];Rencontres[ORGANISME])) mais elle me renvoie toujours le même total lorsque j'applique un filtre quelconque. Y a-t-il un moyen de corriger ça ?

Voir l'exemple ci-joint et particulièrement le total en cellule B198

Merci aux experts qui voudront bien me donner de l'aide.

 

[david84]

Re : Compter le nombre d'entrées différentes dans un tableau

Bonsoir,
formule matricielle à valider par Ctrl, Maj et entrée :

=SOMME(N(FREQUENCE(SI(SOUS.TOTAL(3;DECALER(B3;LIGNE(Rencontres[ORGANISME])-LIGNE(B3);));EQUIV(Rencontres[ORGANISME];Rencontres[ORGANISME];0));LIGNE(B1:B197))>0))

A+

 

[Excelleur]

Re : Compter le nombre d'entrées différentes dans un tableau

Merci infiniment de ton aide. C'est très apprécié !

 

[david84]

Re : Compter le nombre d'entrées différentes dans un tableau

Re
Ceci-dit, bien que je trouve la 1ère formule plus "sûr" de manière général sur le calcul prenant en compte du texte, tu peux aussi dans ton cas utiliser :

=SOMME(SI(SOUS.TOTAL(3;DECALER(B3;LIGNE(Rencontres[ORGANISME])-LIGNE(B3);));1/NB.SI(Rencontres[ORGANISME];Rencontres[ORGANISME])))

qui semble donner les mêmes résultats (toujours en matriciel).

Concernant le test conditionnel, l'utilisation de DECALER peut être remplacé par INDIRECT(ADRESSE, peut-être plus facile à comprendre dans son principe, ce qui donnerait :

=SOMME(N(FREQUENCE(SI(SOUS.TOTAL(3;INDIRECT(ADRESSE(LIGNE(Rencontres[ORGANISME]);COLONNE(Rencontres[ORGANISME]))));EQUIV(Rencontres[ORGANISME];Rencontres[ORGANISME];0));LIGNE(B1:B197))>0))

ou

=SOMME(SI(SOUS.TOTAL(3;INDIRECT(ADRESSE(LIGNE(Rencontres[ORGANISME]);COLONNE(Rencontres[ORGANISME]))));1/NB.SI(Rencontres[ORGANISME];Rencontres[ORGANISME])))

A+