compter le nombre de valeur texte unique avec "nb.si.ens"

[brice59]

Bonjour,

Je cherche comment compter le nombre de valeur unique en utilisant la formule =nb.si.ens(.....)

si quelqu'un a la réponse, ça serait super sympa.

Merci d'avance

 

[R@chid]

Re : compter le nombre de valeur texte unique avec "nb.si.ens"

Bonjour,
pas facile de répondre sans fichier exemple,

Si la Plage contient de cellules vides,

=SOMME(SI(Plage<>"";1/NB.SI(Plage;Plage)))

@ valider par Ctrl+Maj+Entree

Sinon,

=SOMMEPROD(1/NB.SI(Plage;Plage))

Validation Classique

Amicalement

 

[brice59]

Re : compter le nombre de valeur texte unique avec "nb.si.ens"

désolé, voici le fichier

Merci

 

[R@chid]

Re : compter le nombre de valeur texte unique avec "nb.si.ens"

Bonjour,
Voir si ca te convient
Amicalement

 

[R@chid]

Re : compter le nombre de valeur texte unique avec "nb.si.ens"

Bonjour,
J'ai fait le calcul par Période et par Secteur,
si tu veux juste le nombres de code par Période,

=NB(1/FREQUENCE(SI(Col_Periode=J8;EQUIV(Col_Codes;Col_Codes;0));LIGNE(INDIRECT("1:"&LIGNES(Col_Codes)))))

Formule matricielle @ valider par Ctrl+Maj+Entree
Amicalement

 

[brice59]

Re : compter le nombre de valeur texte unique avec "nb.si.ens"

ce n'est pas ce que je recherche,

J'ai changé un peu la base pour simplifier un peu.

voici la formule que j'utilise, mais il faudrait remplacer le "unique" pour compter le nombre de valeur unique en fait.

=NB.SI.ENS($A:$A;H$5;$C:$C;$G6;B:B;"unique")

il y a peut être une autre solution, mais je ne sèche plus, je suis complétement desséché.

Merci d'avance

 

[R@chid]

Re : compter le nombre de valeur texte unique avec "nb.si.ens"

Bonjour,
Tu peux essayer avec,
en E2 @ tirer vers le bas,

=SI(SOMMEPROD((A$2:A2=A2)*(B$2:B2=B2)*(C$2:C2=C2))=1;1;"")

en H6 @ tirer vers le bas et vers la droite,

=NB.SI.ENS($A:$A;H$5;$C:$C;$G6;$E:$E;1)

Amicalement

 

[Yasser MENJAOUI]

Bonjour,

J'ai un fichier Excel où j'ai construit des tableaux avec des formules pour ensuite construire des graphiques.
Je suis bloqué sur une formule que je n'arrive pas à trouver.

Ma plage de données contient des colonnes. Chaque colonne contient plusieurs critéres.
Exemple: Colonne B "Nom fournisseur" = IMT HOLLANDE, NESTLE, REDBULL....
Colonne C "Mois de campagne" = 01/2022, 02/2022, 03/2022....11/2022
Colonne E "Taxe" = DDS, Boissons, Recylum, Taxes d'enregistrements.....
Colonne K "Statut" = RETOUR OK, Rejet 1, Rejet 2, Rejet 3, Abandon, Relance 1....
Colonne L "Date Statut" = Janvier, février, Mars..... Novembre

Dans le tableau que j'ai construit, je dois pouvoir afficher le nombre de fournisseurs en se basant sur plusieurs critères.

Si quelqu'un peut m'apporter une solution, je peux lui partager mon fichier excel.

Cordialement,

 

[job75]

Bonsoir Yasser MENJAOUI; bienvenue sur XLD;

Une formule avec SOMMEPROD devrait suffire.

Et mettez le tableau sous forme de tableau structuré.

A+

 

[Yasser MENJAOUI]

Bonsoir Yasser MENJAOUI; bienvenue sur XLD;

Une formule avec SOMMEPROD devrait suffire.

Et mettez le tableau sous forme de tableau structuré.

A+

Bonjour,

Je vous mets deux captures d'écrans de mon fichiers.
Le but est d'avoir une formule qui prend dans la colonne B Le nombre de fournisseurs, en se basant sur les critères des colonnes C "02/2022", colonne E "Déchets diffus spéc. ménagers", colonne K "RETOUR OK", colonne L "les dates du mois de mars".

Le résultat est 2 fournisseurs (sans doublons).

Pouvez- vous me montrer comment faire ?

Merci.

 

[job75]

Bonjour,

Avec des captures d'écran on ne peut rien tester, déposez un fichier Excel.

A+

 

[Yasser MENJAOUI]

Bonjour,

Avec des captures d'écran on ne peut rien tester, déposez un fichier Excel.

A+

Re-bonjour,

Mon fichier est très volumineux, car j'ai un nombre de ligne important + formules.
Laissez-moi une adresse mail que je puisse l'envoyer.

Merci.

 

[job75]

Allégez votre fichier et anonymisez les données confidentielles.

 

[job75]

Bonjour le forum,

Vu le manque de réaction voyez le fichier joint et cette formule en Calcul!B3 :

=SOMMEPROD(--ESTNUM(LN(EQUIV(BDD!$A$2:$A$9&$A3&B$2;BDD!$A$2:$A$9&BDD!$B$2:$B$9&BDD!$C$2:$C$9;0)=LIGNE(BDD!$A$2:$A$9)-1)))

A tirer à droite et vers le bas.

A+

 

[job75]

Avec le nom T défini dynamiquement la formule devient :

=SOMMEPROD(--ESTNUM(LN(EQUIV(INDEX(T;;1)&$A3&B$2;INDEX(T;;1)&INDEX(T;;2)&INDEX(T;;3);0)=LIGNE(T)-1)))