Compter des valeurs séparées par un point virgule

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Juin 2014

• #2

Re : Compter des valeurs séparées par un point virgule

Bonjour,
Si tes valeurs sont en A1:A3 :

Code:

=SOMMEPROD(NBCAR(A1:A3)-NBCAR(SUBSTITUE(A1:A3;";";))+1)

@ + +

 

Vote positif 0 Vote négatif

P

pierre974

XLDnaute Nouveau

• 26 Juin 2014

• #3

Re : Compter des valeurs séparées par un point virgule

Bonjour Rachid,

je te remercie de ta réponse mais je n'arrive pas à faire fonctionner ta formule.

je te joint un fichier exemple qui pourra me permettre de mieux comprendre.

Merci bien !

Pierre

 

Pièces jointes

• exp Pierre.xlsx

  8.3 KB · Affichages: 39
• exp Pierre.xlsx

  8.3 KB · Affichages: 52
• exp Pierre.xlsx

  8.3 KB · Affichages: 48

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Juin 2014

• #4

Re : Compter des valeurs séparées par un point virgule

Bonjour,
Si j'ai bien compris, en D3,

Code:

=NB(1/N(NBCAR(A$3:A$9)-NBCAR(SUBSTITUE(A$3:A$9;";";))+1=LIGNES($3:3)))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

Vote positif 0 Vote négatif

Efgé

XLDnaute Barbatruc

• 26 Juin 2014

• #5

Re : Compter des valeurs séparées par un point virgule

Bonjour pierre974 Salut Rachid

Je crois que pierre974 cherche ceci:

=SOMMEPROD(NBCAR($A$3:$A$9)-NBCAR(SUBSTITUE($A$3:$A$9;C2;"")))

Avec fioritures pour le tableau

Cordialement

 

Pièces jointes

• ex_Pierre(3).xlsx

  8.4 KB · Affichages: 46

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 26 Juin 2014

• #6

Re : Compter des valeurs séparées par un point virgule

Bonjour pierre974, salut R@chid, Edit : Efgé aussi,

Formule en D3 à tirer vers le bas :

Code:

=SOMMEPROD((NBCAR(";"&A$3:A$11&";")-NBCAR(SUBSTITUE(";"&A$3:A$11&";";";"&C3&";";)))/(2+NBCAR(C3)))

Fichier joint, noter en colonne C le format personalisé "nbre de fois "0

A+

 

Pièces jointes

• exp Pierre(1).xls

  27.5 KB · Affichages: 39

Dernière édition: 26 Juin 2014

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Juin 2014

• #7

Re : Compter des valeurs séparées par un point virgule

Re,
Salut Efgé
Oui peut-être, 2 interprétations différentes..

@ + +

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Juin 2014

• #8

Re : Compter des valeurs séparées par un point virgule

Re,
Salut Job75,
Peut-être que vous avez raison, mais on peut faire plus courte, en D3,

Code:

=NB.SI(A$3:A$9;"*"&LIGNES($3:3)&"*")

@ + +

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Juin 2014

• #9

Re : Compter des valeurs séparées par un point virgule

Re,
Problème de valeurs numériques, en D3,

Code:

=NB(1/CHERCHE(C2;A$3:A$9))

@ valider par Ctrl+Shift+Enter
@ tirer vers le bas

@ + +

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 26 Juin 2014

• #10

Re : Compter des valeurs séparées par un point virgule

Re,

La formule de mon post #6 fonctionne bien s'il n'y a pas de doublons dans une cellule.

S'il y a des doublons :

Code:

=SOMMEPROD((NBCAR(";"&SUBSTITUE(A$3:A$11;";";";;")&";")-NBCAR(SUBSTITUE(";"&SUBSTITUE(A$3:A$11;";";";;")&";";";"&C3&";";)))/(2+NBCAR(C3)))

Fichier (2).

A+

 

Pièces jointes

• exp Pierre(2).xls

  27 KB · Affichages: 34

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 26 Juin 2014

• #11

Re : Compter des valeurs séparées par un point virgule

Re,

Avant de dîner, une formule matricielle :

Code:

=SOMME(N(STXT(";"&A$3:A$11&";";TRANSPOSE(LIGNE($1:$99));NBCAR(C3)+2)=";"&C3&";"))

A valider par Ctrl+Maj+Entrée.

S'il y a plus de 99 caractères dans une cellule augmenter ce nombre.

Cette formule est plus courte mais en général les calculs seront moins rapides.

Fichier (3).

A+

 

Pièces jointes

• exp Pierre(3).xls

  27.5 KB · Affichages: 45

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 27 Juin 2014

• #12

Re : Compter des valeurs séparées par un point virgule

Bonjour le fil, le forum,

Fichier (3 bis) qui évite TRANSPOSE et la validation matricielle :

Code:

=SOMMEPROD(N(STXT(";"&A$3:A$11&";";COLONNE(A:CZ);NBCAR(C3)+2)=";"&C3&";"))

Les chaînes sont étudiées sur au plus COLONNES(A:CZ) = 104 caractères.

A+

 

Pièces jointes

• exp Pierre(3 bis).xls

  27 KB · Affichages: 34

Vote positif 0 Vote négatif