Microsoft 365 Comptage du nombre de cellules non vides, par groupe

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 23 Janvier 2025

• #2

Bonjour Diane,
Un essai en PJ avec :

VB:

=SIERREUR(NB.SI(INDIRECT("$A"&EQUIV(F3;$A:$A;0)&":$A"&EQUIV(G3;$A:$A;0)-1);"><");NB.SI(INDIRECT("$A"&EQUIV(F3;$A:$A;0)&":$A60000");"><"))

 

Pièces jointes

• Compte groupé.xlsx

  9.6 KB · Affichages: 6

Vote positif 0 Vote négatif

H

Hecatonchire

XLDnaute Occasionnel

• 23 Janvier 2025

• #3

Bonjour Diane, sylvanu,

Une formule dynamique générant les valeurs de la plage F3:I4

VB:

=LET(p;A1:A25;
s;SEQUENCE(;MAX(p));
n;TRANSPOSE(FREQUENCE(MAP(p;LAMBDA(v;SI(v=">";MAX(INDIRECT("A1:A"&LIGNE(v)));"")));EXCLURE(s;;-1)));
ASSEMB.V(s;n))

 

Pièces jointes

• Compte groupé.xlsx

  12.3 KB · Affichages: 3

Vote positif 0 Vote négatif

D

Diane272727

XLDnaute Junior

• 24 Janvier 2025

• #4

sylvanu à dit:

Bonjour Diane,
Un essai en PJ avec :

VB:

=SIERREUR(NB.SI(INDIRECT("$A"&EQUIV(F3;$A:$A;0)&":$A"&EQUIV(G3;$A:$A;0)-1);"><");NB.SI(INDIRECT("$A"&EQUIV(F3;$A:$A;0)&":$A60000");"><"))

Cliquez pour agrandir...

Merci beaucoup ça fonctionne super bien 🙂 !!
Par contre dans mon fichier réel, mes données sont en colonne B (et pas A comme dans le fichier test), et ça ne fonctionne plus. Impossible de trouver pourquoi. Aurais tu une idée ? Merci

 

Vote positif 0 Vote négatif

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 24 Janvier 2025

• #5

Bonjour,
Une PJ à jour avec données en colonne B, et aussi une formule plus simple.
NB:
Dans "INDIRECT("$A"&... " la colonne A est "en dur" ( une chaine ) donc non modifiable par XL si on glisse la colonne A vers B.

 

Pièces jointes

• Compte groupé.xlsx

  9.8 KB · Affichages: 2

Vote positif 0 Vote négatif

Solution

H

Hecatonchire

XLDnaute Occasionnel

• 24 Janvier 2025

• #6

Version colonne B et bien sur adapter 25 de B25 (60000 si on veux)

=LET(p;B1:B25;
s;SEQUENCE(;MAX(p));
n;TRANSPOSE(FREQUENCE(MAP(p;LAMBDA(v;SI(v=">";MAX(INDIRECT("B1:B"&LIGNE(v)));"")));EXCLURE(s;;-1)));
ASSEMB.V(s;n))

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 24 Janvier 2025

• #7

Bonjour le forum,

Avec cette fonction VBA à placer dans un module standard :

VB:

Function NbPlage(plage As Range, ref)
Dim c As Range, i&
Set c = plage.Find(ref, , xlValues, xlWhole)
If c Is Nothing Then NbPlage = "": Exit Function
i = 2
Do While Not IsNumeric(c(i))
    i = i + 1
Loop
NbPlage = i - 2
End Function

Formule en F4 à tirer vers la droite =NbPlage($A:$A;F3)

A+

 

Pièces jointes

• Compte groupé.xlsm

  16.6 KB · Affichages: 2

Vote positif 0 Vote négatif

D

danielco

XLDnaute Accro

• 24 Janvier 2025

• #8

Bonjour,

Un autre façon :

=LET(str;CONCAT(A1:A24);sbl;SUBSTITUE(str;" ";"");MAP(F3:I3;LAMBDA(x;NBCAR(INDEX(FRACTIONNER.TEXTE(sbl;F3:I3);x+1)))))

Daniel

 

Vote positif 0 Vote négatif

D

Diane272727

XLDnaute Junior

• 28 Janvier 2025

• #9

Merci à tous pour vos réponses vous êtes au top !!!!! 🙂

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 28 Janvier 2025

• #10

Hello sylvanu, tu t'es trompé de fil 😕

 

Vote positif 0 Vote négatif

sylvanu

XLDnaute Barbatruc

Supporter XLD

• 28 Janvier 2025

• #11

🤣 🤣 🤣 Oups!
Merci Job, et bonne journée.
Message supprimé. 🙂

 

Vote positif 0 Vote négatif