Comparaison + Modification automatique

[stefkeno]

Bonjour à tous,

Je vous explique mon problème :

J'ai 2 bases de données (BD1 et BD2). Le N° de Matricule (Colone A) est identique pour les 2 bases de données mais pas le reste (Nom, Prénom... de la BD2). Je souhaiterai faire une comparaison entre ces 2 bases de données par rapport au N° de Matricule de tel sorte que la BD1 modifie automatiquement (Formules ou Macros) toutes les autres colones (Nom, Prénom...) de la BD2 pour que les 2 bases de données soient identiques.

Je vous joins un fichier comme exemple.

Je vous remercie de votre aide.

Stéphane.

 

[Robert]

Re : Comparaison + Modification automatique

Bonjour Stekkeno, bonjour le forum,

Une proposition VBA avec le code ci-dessous :

Sub Macro1()
Dim dl As Integer 'déclare la variable dl (Dernière Ligne)
Dim pl As Range 'déclare la variable pl (PLage)
Dim cel As Range 'déclare la variable cel (CELlule)
Dim r As Range 'déclare la variable r (Recherche)

With Sheets("BD1") 'prend en compte l'onglet "BD1"
    dl = .Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne dl
    Set pl = .Range("A2:A" & dl) 'définit la plage pl
    For Each cel In pl 'boucle sur toutes les cellules cel de la plage pl
        Set r = Sheets("BD2").Columns(1).Find(cel.Value, , xlValues, xlWhole) 'définit la recherche r
        If Not r Is Nothing Then .Range(cel, cel.Offset(0, 3)).Copy r 'si il existe au moins une occurrence trouvée, récupère la ligne
    Next cel 'prochaine cellule de la boucle
End With 'fin de la prose en compte de l'onglet "BD1"
End Sub

 

[stefkeno]

Re : Comparaison + Modification automatique

Bonjour Robert,

Merci pour cette macro qui fonctionne très bien. C'est exactement ce qu'il me fallait.
Et merci pour la rapidité de votre réponse.

A+

Stéphane.