Comment ouvrir un classeur s'il ne l'est pas ?

[excelman]

J'ai la macro suivante qui ne fonctionne pas au niveau "if workbook.open..."

Sub vaencaisse()
ChDir "h:\mars 2010"
nomfichier = "phoneo" & Format(Date, "mm") & Format(Date, "yyyy") & ".xls"
"If Workbooks(monfichier).Open = True Then"
Exit Sub
Else: Workbooks.Open Filename:=nomfichier
Sheets(Day(Date)).Select
End If
end sub

Pourriez vous m'aider ?
En fait je voudrais que lorsque je lance la macro il m'ouvre le classeur s'il ne l'est pas et qu'il sorte de la macro s'il l'est.

Cdt
Merci d'avance

 

[Staple1600]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Bonsoir


Une exemple parmi moults

Option Explicit '<-Zack Barresse
Option Compare Text 
 
Function IsWbOpen(wbName As String) As Boolean 
    Dim i As Long 
    For i = Workbooks.Count To 1 Step -1 
        If Workbooks(i).Name = wbName Then Exit For 
    Next 
    If i <> 0 Then IsWbOpen = True 
End Function

Sub Test() 
    Dim wb As Workbook, strName As String, strPath As String 
    strName = "phoneo" & Format(Date, "mmyyyy") &  ".xls"
    strPath = "h:\mars 2010\"
    If IsWbOpen(strName) Then 
        Set wb = Workbooks(strName) 
         'Make the workbook the Active Workbook
        wb.Activate 
    Else 
        Set wb = Workbooks.Open(strPath & strName) 
    End If 
End Sub

 

[excelman]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Merci beaucoup stapple ca marche très bien...

J'ai simplement modifié la ligne suivante :

Set wb = Workbooks.Open(strPath & strName)

en

Set wb = Workbooks.Open(strPath & "\" & strName)

sinon il ne reconnait pas le fichier puisqu'il ne met pas l' \

Merci encore

Cdt
A+

 

[Staple1600]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Re


Oui exact

Tu peux aussi le mettre là ou je viens de le rajouter 😉

PS: Tu me remercies, je remercie Zach pour ma part

 

[soenda]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Bonsoir le fil, Excelman, Stapple1600

Une question parmis d'autres, que signifie "Zack Barresse" ?

Option Explicit '<-Zack Barresse

A plus

 

[Staple1600]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Re

soenda
C'est simplement le prénom et le nom de l'auteur du code que j'ai posté précédemment.

 

[excelman]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Alors merci à Zack aussi et bonne nuit à tous

Cdt

 

[soenda]

Re : Comment ouvrir un classeur s'il ne l'est pas ?

Re,

@Stapple1600
Merci pour la réponse 🙂

A plus