Comment creer un Lien Hyper Text (Index) pour es les feuil de mon classeur

[ssassam]

Bonjour,

Svp, Comment créer un Lien HyperText (Index) pour toutes les feuil de mon classeur
j'ai le code suivant mais il ne prend pas en charge ls feuil avec des nom qui contiens un ESPACE

   Sub Macro1()
    Dim Sh As Worksheet, ShIndex As Worksheet
    With Application
        .DisplayAlerts = False
        .ScreenUpdating = False
    End With
    On Error Resume Next
    Set ShIndex = Sheets("Index")
    ShIndex.Delete
    On Error GoTo 0
    Sheets.Add.Name = "Index"
    Set ShIndex = Sheets("Index")
    For Each Sh In Sheets
        With ShIndex
            If Sh.Name <> .Name Then
                .Hyperlinks.Add Anchor:=.Cells(Rows.Count, 1).End(xlUp)(2), Address:="", SubAddress:= _
                    Sh.Name & "!A1", TextToDisplay:=Sh.Name
            End If
           
        End With
    Next Sh
    ShIndex.Rows(1).Delete
    End Sub

Merci pour votre aide

 

[BOISGONTIER]

Re : Comment creer un Lien Hyper Text (Index) pour es les feuil de mon classeur

Bonjour,

Sommaire dynamique avec Lien hypertexte
Sommaire dynamique avec VBA


JB

 

[jpb388]

Re : Comment creer un Lien Hyper Text (Index) pour es les feuil de mon classeur

Bonjour le forum
il te manquait les apostrophes

Sub Macro1()
     Dim Sh As Worksheet, ShIndex As Worksheet
     With Application
         .DisplayAlerts = False
         .ScreenUpdating = False
     End With
     On Error Resume Next
     Set ShIndex = Sheets("Index")
     ShIndex.Delete
     On Error GoTo 0
     Sheets.Add.Name = "Index"
     Set ShIndex = Sheets("Index")
     For Each Sh In Sheets
         With ShIndex
             If Sh.Name <> .Name Then
                 .Hyperlinks.Add Anchor:=.Cells(Rows.Count, 1).End(xlUp)(2), Address:="", SubAddress:= _
                     "'" & Sh.Name & "'!A1", TextToDisplay:=Sh.Name
             End If
            
         End With
     Next Sh
     ShIndex.Rows(1).Delete
     End Sub

 

[ssassam]

Re : Comment creer un Lien Hyper Text (Index) pour es les feuil de mon classeur

Gracias !!! jpb388 CA marche a merveille merci pour ton aide