XL 2010 Comment calculer des nombres qui ne sont pas des nombres

Philippe LAMACHE · 13 Août 2019

Bonjour à tous,

J'ai une formule qui me récupère la fin d'un texte après les ":" (Nbre de lignes traitées : 7 801)

VB:

=SI(A2="";"";DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11"))))

J'en ai environ 15 et je souhaiterais les additionner (=SOMME(G2:G20)) mais comme ce ne sont pas des nombres, mon résultat est 0.

Quelqu'un a-t'il une solution ?
Par avance, merci.

eriiic · 13 Août 2019

Bonjour,

dans tes 2 parties de formule mettre

VB:

--(formule_partie1);--(formule_partie2))

Le 1er moins converti en numérique, le 2nd rétabli le signe.
eric

CHALET53 · 13 Août 2019

Peut-être :

=SI(A2="";"";DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11")))*1)
a+

Philippe LAMACHE · 13 Août 2019

eriiiic à dit:
Bonjour,

dans tes 2 parties de formule mettre

VB:

--(formule_part1);--(formule_part21)

eric

Bonjour Eric,

VB:

=SI(A2=0;0;DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11"))))

Comme ça ? cela ne fonctionne pas.

Philippe LAMACHE · 13 Août 2019

CHALET53 à dit:
Peut-être :

=SI(A2="";"";DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11")))*1)
a+

Bonjour Chalet53,
Non, ça me renvoie #VALEUR!

Philippe LAMACHE · 13 Août 2019

Dans le texte

Nbre de lignes traitées : 7 801

je récupère la partie 7 801 , je pense qu'un nombre donnerai 7801 (sans espace)

Jocelyn · 13 Août 2019

Bonjour le Forum,
Bonjour Philippe LAMACHE, eriiiic, CHALET53,

Si tu penses que le soucis provient de l'espace il reste à savoir si c'est un espace simple ou insécable donc a tester

avec espace simple

Code:

=SI(A2="";"";substitue(DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11")));car(32);"")*1)

avec espace insécable

Code:

=SI(A2="";"";substitue(DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11")));car(160);"")*1)

Cordialement

Philippe LAMACHE · 13 Août 2019

Bon ...
J'ai trouvé une solution qui fonctionne

VB:

=NBVAL(INDIRECT("'"&A2&"'!B14:B1048576"))

Merci à tous pour votre temps et vos suggestions.

Philippe LAMACHE · 13 Août 2019

Jocelyn à dit:
Bonjour le Forum,
Bonjour Philippe LAMACHE, eriiiic, CHALET53,

Si tu penses que le soucis provient de l'espace il reste à savoir si c'est un espace simple ou insécable donc a tester

avec espace simple

Code:

=SI(A2="";"";substitue(DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11")));car(32);"")*1)

avec espace insécable

Code:

=SI(A2="";"";substitue(DROITE(INDIRECT("'"&A2&"'!A11");NBCAR(INDIRECT("'"&A2&"'!A11"))-TROUVE(":";INDIRECT("'"&A2&"'!A11")));car(160);"")*1)

Cordialement

Bonjour Jocelyn,
La première solution me renvoie #VALEUR!
La deuxième me renvoie bien un nombre et ma somme fonctionne à présent.
Merci.

Victor21 · 13 Août 2019

Bonjour à tous.

Et pourquoi pas, en alternative, un format de nombres personnalisé :

Exemple en pj

Philippe LAMACHE · 14 Août 2019

Victor21 à dit:
Bonjour à tous.

Et pourquoi pas, en alternative, un format de nombres personnalisé :
Regarde la pièce jointe 1038085
Exemple en pj

Bonjour Patrick,
Merci d'avoir pris le temps pour moi.
Ce que je veux récupérer c'est la valeur (7801 dans mon exemple) et non le nombre de caractères (qui donnerait 4 avec ta solution).
La solution n°2 de Jocelyn (en réponse plus haut dans ce fil) réponds exactement à ce qu'il me fallait.
Bonne journée.

Victor21 · 14 Août 2019

Re, Philippe.

J'eusse été surpris que l'ami Jocelyn -bonjour, l'ami -ne répondît pas à votre problème.
Ma proposition (image et colonne D du fichier que j'avais joint) consiste à renvoyer directement un nombre (7801), s'affichant comme un texte (Nb de lignes traitées : 7801).
Le nombre de caractères en colonne F ne servait qu'à vous montrer que ce qui est affiché dans une cellule peut être différent de ce qu'elle contient.

Staple1600 · 14 Août 2019

Bonsoir à tous

J'ai surement pas tout compris
Mais si en A1, on a: Nbre de lignes traitées : 7 801
Cette formule en B1: =1*STXT(A1;CHERCHE(": ";A1)+2;9^9) renvoie 7801, non ?

Victor21 · 14 Août 2019

Bonsoir, Staple1600.

Staple1600 à dit:
Bonsoir à tous

J'ai surement pas tout compris
Mais si en A1, on a: Nbre de lignes traitées : 7 801
Cette formule en B1: =1*STXT(A1;CHERCHE(": ";A1)+2;9^9) renvoie 7801, non ?

Oui...
Sauf si l'espace entre le 7 et le 8 est de type ~~intraitable~~ insécable (car160)
D'où la 2° formule de @Jocelyn au #7

Staple1600 · 14 Août 2019

Re

Dans ce cas, en empruntant un chouia à Jocelyn
=SUBSTITUE(STXT(A1;CHERCHE(": ";A1)+2;9^9);CAR(160);"")*1

XL 2010 Comment calculer des nombres qui ne sont pas des nombres

Philippe LAMACHE

XLDnaute Junior

eriiic

XLDnaute Barbatruc

CHALET53

XLDnaute Barbatruc

Philippe LAMACHE

XLDnaute Junior

Philippe LAMACHE

XLDnaute Junior

Philippe LAMACHE

XLDnaute Junior

Jocelyn

XLDnaute Barbatruc

Philippe LAMACHE

XLDnaute Junior

Philippe LAMACHE

XLDnaute Junior

Victor21

XLDnaute Barbatruc

Pièces jointes

Philippe LAMACHE

XLDnaute Junior

Victor21

XLDnaute Barbatruc

Staple1600

XLDnaute Barbatruc

Victor21

XLDnaute Barbatruc

Staple1600

XLDnaute Barbatruc

Discussions similaires