Colorier les doublons par lignes en VBA! (RESOLU)

=NB.SI($A1:$D1;A1)>1

Sub ColoriageDoublonsNbSi()
  [A1].CurrentRegion.Interior.ColorIndex = xlNone
  Application.ScreenUpdating = False
  For i = 1 To [A65000].End(xlUp).Row
    Set champ = Cells(i, 1).Resize(, 4)
    For c = 1 To 4
     If Application.CountIf(champ, Cells(i, c)) > 1 Then Cells(i, c).Interior.ColorIndex = 6
    Next c
  Next i
End Sub

Sub MFC()
Cells.FormatConditions.Delete 'RAZ
With [A1].CurrentRegion
  .Cells(1).Select 'pour Excel 2003
  .FormatConditions.Add xlExpression, _
    Formula1:="=NB.SI(" & .Rows(1).Address(0, 1) & ";A1)>1"
  .FormatConditions(1).Interior.ColorIndex = 6 'jaune
End With
End Sub

Sub ColorierDoublons()
Application.ScreenUpdating = False
With [A1].CurrentRegion
  .EntireColumn.Interior.ColorIndex = xlNone 'RAZ
  '---entre les formules dans un 2ème tableau---
  .Cells(1).Offset(, .Columns.Count) = _
    "=LN(COUNTIF(" & .Rows(1).Address(0, 1) & ",A1)>1)"
  .Cells(1).Offset(, .Columns.Count).Copy .Offset(, .Columns.Count)
  '---copie les formats du 1er tableau sur le 2ème---
  .Copy
  .Offset(, .Columns.Count).PasteSpecial xlPasteFormats
  '---colorie le 2ème tableau---
  On Error Resume Next
  .Offset(, .Columns.Count).SpecialCells(xlCellTypeFormulas, 1) _
    .Interior.ColorIndex = 6 'jaune
  '---copie les formats du 2ème tableau sur le 1er---
  .Offset(, .Columns.Count).Copy
  .PasteSpecial xlPasteFormats
  '---supprime le 2ème tableau---
  .Offset(, .Columns.Count).EntireColumn.Delete
  .Cells(1).Select
End With
End Sub

Sub ColorierDoublons()
Dim cc%, i&
Application.ScreenUpdating = False
With [A1].CurrentRegion
  cc = .Columns.Count
  .EntireColumn.Interior.ColorIndex = xlNone 'RAZ
  '---entrée des formules dans un 2ème tableau---
  .Cells(1).Offset(, cc) = "=LN(COUNTIF(" & .Rows(1).Address(0, 1) & ",A1)>1)"
  .Cells(1).Offset(, cc).Copy .Offset(, cc)
  '---copie les formats du 1er tableau sur le 2ème---
  .Copy
  .Offset(, cc).PasteSpecial xlPasteFormats
  '---itérations par pas de 500 lignes---
  On Error Resume Next
  For i = 0 To .Rows.Count - 1 Step 500
    '---colorie le 2ème tableau---
    .Offset(i, cc).Resize(500).SpecialCells(xlCellTypeFormulas, 1) _
      .Interior.ColorIndex = 6 'jaune
    '---copie les formats du 2ème tableau sur le 1er---
    .Offset(i, cc).Resize(500).Copy
    .Offset(i).Resize(500).PasteSpecial xlPasteFormats
  Next
  '---supprime le 2ème tableau---
  .Offset(, cc).EntireColumn.Delete
  '---mise à jour de la barre de défilement verticale---
  .Offset(.Rows.Count).Resize(500).Delete xlUp
  .Parent.UsedRange.Select
  .Cells(1).Select
End With
End Sub