Code Thisworkbook

[Deleep]

Bonjour à tous,

Ne sachant pas si mon précédent message, s'inscrivant dans le fil d'un Post datant de 3 ans serait visible par tous, je me permets de vous resoumettre ma question : dans le code suivant :

CODE
Private Sub Workbook_Open()
With Worksheets("Feuil1")
.EnableAutoFilter = True
.EnableOutlining = True
.Protect Contents:=True, Password:="Toto", UserInterfaceOnly:=True
End With
End Sub

Quelle est la sytntaxe exacte pour rajouter des onglet (Feuil2, Feuil3,..)
j'ai essayé plusieurs solutions, mais il me donne toujours une erreur.

pour info, ce code permet de laisser l'utilisateur utilisé la fonction Grouper sur une feuille protégée.

Merci d'avance et désolé si ce post fait doublon avec l'autre.

 

[Robert]

Re : Code Thisworkbook

Bonjour Deleep, bonjour le forum,

peut-être avec une boucle :

Private Sub Workbook_Open()
For x = 1 To 3
    With Worksheets(x)
        .EnableAutoFilter = True
        .EnableOutlining = True
        .Protect Contents:=True, Password:="Toto", UserInterfaceOnly:=True
    End With
Next x
End Sub

 

[Deleep]

Re : Code Thisworkbook

Bonjour Robert,

Désolé de mon ignorance, mais je ne sais pas à quoi sert une boucle.
Pourrais-tu me remplacer le X par le nom de mes onglets afin que ce soit plus clair pour moi ?
Les onglet sont GestOp et Equipe

Un grand merci d'avance !

 

[Robert]

Re : Code Thisworkbook

Bonsoir Deleep, bonsoir le forum,

Une boucle est nécessaire pour faire faire une même action à plusieurs éléments. x est le numéro d'index des tes onglets et cela évite de les nommer. Le code que je t'ai donné va agir sur les trois premiers onglets de ton classeur (For x = 1 to 3 ). Tu peux l'adapter mais on pourrait aussi faire comme ça, si tu veux Utiliser le nom des onglets :

Private Sub Workbook_Open()
For x = 1 To Sheets.Count 'boucle sur tous les onglets du classeur
    Select Case Sheets(x).Name 'agit en fonction du nom de l'onglet
        Case "Feuil1", "GestOp", "Equipe" 'cas "Feuil1", "GestOp" et "Equipe"
        With Sheets(x)
            .EnableAutoFilter = True
            .EnableOutlining = True
            .Protect Contents:=True, Password:="Toto", UserInterfaceOnly:=True
        End With
    End Select 'fin de l'action en fonction du nom
Next x 'prochain onglet du classeur
End Sub

 

[Deleep]

Re : Code Thisworkbook

Merci beaucoup, beaucoup, ca fonctionne !!

Bonne soirée à toi !

Encore merci !