Classeurs fermés , récupérer une valeur?

[Claudy]

Bonsoir,
J'ai un classeur dans lequel, je voudrais récupérer la valeur de tous les classeurs fermés dans un dossier (" Dossier test") ...
J'ai commencé avec ceci, mais je rame...ça va pas!

Sub test1()
Dim Fichier As String, Chemin As String
Dim Wb As Workbook

Chemin = "C:\Documents and Settings\Claudy\Bureau\Dossier test\"
Fichier = Dir(Chemin & "*.xls")

Do While Fichier <> ""
Set Wb = Workbooks.Open(Chemin & Fichier)
lig = 1
Application.Workbooks("ClasseurTestClaudy.xls").Worksheets("test").Range("A" & lig) = Wb.Name
Application.Workbooks("ClasseurTestClaudy.xls").Worksheets("test").Range("B" & lig) = Fichier.Range("H10").Value

Wb.Close True
lig = lig + 1
Set Wb = Nothing

Fichier = Dir
Loop

End Sub
Merci d'avance, a+

 

[bqtr]

Re : Classeurs fermés , récupérer une valeur?

Bonsoir Claudy,

Essaye comme ça:

Sub test1()

Dim Fichier As String, Chemin As String, Lig As Integer

Chemin = "C:\Documents and Settings\Claudy\Bureau\Dossier test\"
Fichier = Dir(Chemin & "*.xls")
Lig = 1
Application.ScreenUpdating = False
Do While Fichier <> ""
    Sheets("test").Range("A" & Lig) = Fichier
    Sheets("test").Range("B" & Lig) = ExecuteExcel4Macro("'" & Chemin & "\[" & Fichier & "]" & "[B][COLOR=Blue]Nom Feuille[/COLOR][/B]" & "'!R10C8")
    Lig = Lig + 1
    Fichier = Dir
Loop
Application.ScreenUpdating = True

End Sub

Remplace Nom Feuille par le nom de la feuille où doit être extrait le contenu de la cellule H10. Ce nom de feuille doit être identique sur tous les fichiers.

A+