Classement & onglets ?

[boulou]

Bonjour à tous.

Comment puis-je obtenir ce résultat ?
- Sur une page nommée « Home » je veux lister par ordre alpha toutes les valeurs situées en cellule B2 de chaque feuille de mon classeur à l’exception si possible de celle de la feuille « Home » et ceci dans une plage BW5 :BW300.
- Dans la plage BX5 :BX300 je veux cette fois que s’affiche le nom de chaque onglet d’où sont extraites les valeurs B2.

Ceci relève d’un lourd classeur de suivi en bourse et le produit devrait donc donner à titre d’exemple.

AIR France ; AF
BCI NABIGATION ; BNA
MEDICREA ; ALMED
RECYLEX ; RX
SOITEC ; SOI
VALLOUREC ;VK

Merci dès à présent pour votre aide.

 

[Compte Supprimé 979]

Re : Classement & onglets ?

Bonjour Boulou 😉

Tu trouveras ci-dessous le code à utiliser

Sub Compilation()
  Dim Sht As Worksheet, Lig As Long
  ' Initialisation de la ligne
  Lig = 5
  ' Avec la feuille Home
  With Sheets("Home")
    ' Pour chaque feuille du classeur
    For Each Sht In ThisWorkbook.Worksheets
      ' Si le nom de la feuille n'est pas Home
      If Sht.Name <> "Home" Then
        ' Inscrire la valeur de la cellule B2 de la feuille
        .Range("BW" & Lig).Value = Sht.Range("B2").Value
        .Range("BX" & Lig).Value = Sht.Name
        Lig = Lig + 1
      End If
    Next Sht
    ' Faire le tri des données
    Lig = .Range("BW" & Rows.Count).End(xlUp).Row
    .Range("BW5:BX" & Lig).Sort Key1:=.Range("BW5"), Order1:=xlAscending, Header:=xlNo, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
  End With
End Sub

A+

 

[boulou]

Re : Classement & onglets ?

Bonjour Boulou 😉

Tu trouveras ci-dessous le code à utiliser

Sub Compilation()
  Dim Sht As Worksheet, Lig As Long
  ' Initialisation de la ligne
  Lig = 5
  ' Avec la feuille Home
  With Sheets("Home")
    ' Pour chaque feuille du classeur
    For Each Sht In ThisWorkbook.Worksheets
      ' Si le nom de la feuille n'est pas Home
      If Sht.Name <> "Home" Then
        ' Inscrire la valeur de la cellule B2 de la feuille
        .Range("BW" & Lig).Value = Sht.Range("B2").Value
        .Range("BX" & Lig).Value = Sht.Name
        Lig = Lig + 1
      End If
    Next Sht
    ' Faire le tri des données
    Lig = .Range("BW" & Rows.Count).End(xlUp).Row
    .Range("BW5:BX" & Lig).Sort Key1:=.Range("BW5"), Order1:=xlAscending, Header:=xlNo, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom
  End With
End Sub

A+

Ta solution est excellente mais est-il possible de la perfectionner de telle sorte qu'elle s'automatise dès la création d'un nouvel onglet ?