Choix repetoire en fonction

[sten83]

Bonjour a tous j'ai une macro pour nergistrer des factures en pdf dans un fichier.
Ce que je souhaiterai c'est pouvoir enregistrer la feuille dans un repertoire different en fonction de l'intitulé (FACTURE ou DEVIS).
Je joint le bout de code.
Merci pour votre aide précieuse.

Private Sub CmdPrintFacture_Click()
If obFacture.Value Then
SaveSetting "AppDevisFacture", "Facture", "Dernier", NumDoc + 1
If obCB.Value Then
frmFacture.[A41].Value = "Réglement par CB"
ElseIf obCheque.Value Then
frmFacture.[A41].Value = "Réglement par Chèque"
Else
frmFacture.[A41].Value = "Réglement en espèces"
End If
Else
SaveSetting "AppDevisFacture", "Devis", "Dernier", NumDoc + 1
frmFacture.[A41].ClearContents
End If
frmFacture.[A1:H57].ExportAsFixedFormat Type:=xlTypePDF, _
Filename:="c:\test\" & " " & Worksheets("FACTURE").Range("E2").Value & " " & "du" & " " & Format(Date, ("dd-mm-yy")), quality:= _
xlQualityStandard, includedocproperties:= _
False, ignoreprintareas:= _
True, openafterpublish:= _
True
frmFacture.Range("A19:E33,E2:E4,E5,F2,E3,F5,A41").Value = ""

Unload Me

End Sub

 

[Staple1600]

Re : Choix repetoire en fonction

Bonsoir à tous

sten83
Si tu as une macro, nous, ici dans ton fil, nous n'avons pas de fichier Excel joint...

Pourtant, cela serait bien utile pour avoir une base sur laquelle tester nos code VBA avant de te les soumettre, non ?

 

[sten83]

Re : Choix repetoire en fonction

Désoler je pensais que le morceau de code suffirait.
Ci-joint le classeur.
Merci

 

[Staple1600]

Re : Choix repetoire en fonction

Re, Bonjour le forum

sten83
Voici ma proposition
(NB: Les répertoires FACTURE et DEVIS sont créés au préalable manuellement.
Test OK sur mon PC avec ton fichier exemple)

Private Sub CmdPrintFacture_Click()
Dim Rep$, fName$
  If obFacture.Value Then
    SaveSetting "AppDevisFacture", "Facture", "Dernier", NumDoc + 1
    If obCB.Value Then
      frmFacture.[A41].Value = "Réglement par CB"
    ElseIf obCheque.Value Then
      frmFacture.[A41].Value = "Réglement par Chèque"
    Else
      frmFacture.[A41].Value = "Réglement en espèces"
    End If
  Else
   SaveSetting "AppDevisFacture", "Devis", "Dernier", NumDoc + 1
    frmFacture.[A41].ClearContents
  End If
    Rep = IIf(obFacture, "FACTURE", "DEVIS")
    Worksheets("FACTURE").Range("D8") = Rep
    fName = Worksheets("FACTURE").Range("E2").Value & Format(Date, """ du ""dd-mm-yy")
    frmFacture.[A1:H57].ExportAsFixedFormat Type:=xlTypePDF, _
    Filename:="c:\test\" & Rep & "\" & fName, quality:= _
    xlQualityStandard, includedocproperties:= _
    False, ignoreprintareas:= _
    True, openafterpublish:= _
    True
  frmFacture.Range("A19:E33,E2:E4,E5,F2,E3,F5,A41").Value = ""
Unload Me
End Sub

 

[sten83]

Re : Choix repetoire en fonction

Merci tout fonctionne a merveille
Je considére que le post et clos.

Encore merci!