Changer de format

[desatan]

bonjour,

j'ai ceci dans une cellule : 06MAR2003:00:00:00
Je voudrais le transormer en format date : 06/03/2003

Pouvez vous m'aider ?

Merci

 

[ROGER2327]

Re : Changer de format

Bonjour desatan,

Sans échantillon de données, c'est un peu risqué, mais allons-y ! Essayez​

=--SUBSTITUE(A1;":";" ";1)

Bon courage.



ROGER2327
#6288

Samedi 14 Sable 140 (Don Quichotte, champion du monde - fête Suprême Quarte)
24 Frimaire An CCXXI, 6,1817h - oseille
2012-W50-5T14:50:09Z

 

[Jocelyn]

Re : Changer de format

Bonjour le Forum,
Bonjour desatan,

tu peux tester avec une formule de ce type :

=DATE(STXT(A3;CHERCHE(":";A3)-4;4)*1;EQUIV(STXT(A3;3;CHERCHE(":";A3)-7);{"janv";"fev";"mar"};0);STXT(A3;1;2)*1)

attention cette partie de la formule permet de calculer le mois.

EQUIV(STXT(A3;3;CHERCHE(":";A3)-7);{"janv";"fev";"mar"};0)

ici c'est fait jusqu'en mars il faut que tu sache pour chacun des mois quel sera l'abréviation dans ta formule ici j'ai considéré les abréviation suivante

janvier => Janv
Février => Fev
Mars => Mar

donc a toi de voir quel sont réellement ses abréviation et de les mettre entre le crochets séparé par des ; et entourés par des "

Cordialement

EDIT : Oup's Bonjour ROGER2327 désolé pour la collision mais merci pour cette formule concise, pas comme la mienne 😱

 

[desatan]

Re : Changer de format

merci pour vos réponses,

j'ai tésté mais ca me met valeur ? Je joins un échantillon

Merci

 

[Jocelyn]

Re : Changer de format

re,
Bonjour ROGER2327,

revoila ton fichier echantillon, comme tous les mois n'étaient pas présent il faudra que tu vérifies et que tu corriges au besoin

 

[ROGER2327]

Re : Changer de format

Re... (Bonjour Jocelyn)

la formule proposée plus haut fonctionne lorsqu'il n'y a pas de fautes d'orthographe (genre fevrier pour février).

La formule de Jocelyn fonctionne parfaitement pour corriger les fautes.

En voici une autre un peu plus courte :

=--SUBSTITUE(SUBSTITUE(A2;":";" ";1);STXT(A2;3;3);"/"&CHERCHE(STXT(A2;3;3);"++JANFEVMARAPRMAYJUNJULAUGSEPOCTNOVDEC")/3&"/")

Bonne soirée.


ROGER2327
#6291

Samedi 14 Sable 140 (Don Quichotte, champion du monde - fête Suprême Quarte)
24 Frimaire An CCXXI, 6,8809h - oseille
2012-W50-5T16:30:51Z

 

[desatan]

Re : Changer de format

super merci cela fonctionne

 

[desatan]

Re : Changer de format

Bonsoir à tous,

Autre demande s'il vous plaît,
Dans le fichier joint, comment je peux changer 25FEV2003:00:00:00 en 20030225 ?
Merci par avance

 

[desatan]

Re : Changer de format

s'il vous plaît, si quelqu'un peut m'aider , ;-)

 

[Modeste geedee]

Re : Changer de format

Bonsour®

Re... (Bonjour Jocelyn)
En voici une autre un peu plus courte :

=--SUBSTITUE(SUBSTITUE(A2;":";" ";1);STXT(A2;3;3);"/"&CHERCHE(STXT(A2;3;3);"++JANFEVMARAPRMAYJUNJULAUGSEPOCTNOVDEC")/3&"/")

122


🙄 plus courte ... 118

=(GAUCHE(A2;2)&"/"&ENT(TROUVE(STXT(A2;3;3);"XXJANFEVMARAPRMAYJUNJULAUGSEPOCTNOVDEC")/3)&"/"&STXT(A2;6;4))+STXT(A2;11;8)

😛 encore plus courte ... 105

(GAUCHE(A2;2)&"/"&ENT(TROUVE(STXT(A2;4;2);"XANEVARPRAYUNULUGEPCTOVEC")/2)&"/"&STXT(A2;6;4))+STXT(A2;11;8)

pour le fun ...
😛 osons vivre dangereusement ...
plus courte encore : 79 caractères !
en nommant à ( alt +0195)
la constante "XANEVARPRAYUNULUGEPCTOVEC"

=(GAUCHE(A2;2)&"/"&ENT(TROUVE(STXT(A2;4;2);Ã)/2)&"/"&STXT(A2;6;4))+STXT(A2;11;8)

 

[Modeste geedee]

Re : Changer de format

Bonsoir à tous,

Autre demande s'il vous plaît,
Dans le fichier joint, comment je peux changer 25FEV2003:00:00:00 en 20030225 ?
Merci par avance

en d2

=TEXTE(C2;"aaaammjj")

 

[desatan]

Re : Changer de format

merci mais je ne comprends pas 🙁

 

[desatan]

Re : Changer de format

super ca marche merci enormement