Calculer la somme des valeurs jusqu'à O

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Août 2016

• #2

Bonjour,
en C18 :

Code:

=SOMME(DECALER(C3;;;SIERREUR(PETITE.VALEUR(SI(C3:C14=0;LIGNE(INDIRECT("1:"&LIGNES(C3:C14))));1)-1;LIGNES(C3:C14))))

@ valider par Ctrl+Shift+Enter
@ tirer vers la droite


@ + +

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 26 Août 2016

• #3

Bonjour à tous,

En "C16"

Code:

=SOMME(INDIRECT(CAR(64+COLONNE())&"3:"&CAR(64+COLONNE())&EQUIV(0;C$2:C$14;0)))

Copier vers la droite

Edit: Bonjour R@chid🙂

JHA

 

Vote positif 0 Vote négatif

Paf

XLDnaute Barbatruc

• 26 Août 2016

• #4

Bonjour Cydor001, R@chid, JHA,

une autre solution:

=SOMME(C3: DECALER(C3;;;EQUIV(0;C3:C14;0)))

A+

 

Vote positif 0 Vote négatif

C

Cydor007

XLDnaute Occasionnel

• 26 Août 2016

• #5

Merci pour ces réponses rapides.

JHA: ta solution fonctionne, mais je ne n'arrive pas à l'intégrer dans ma colonne. Mes valeurs se situent, en ce moment, dans la colonne FR. Que faut-il adapter pour que cela fonctionne bien?

Merci

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 26 Août 2016

• #6

Bonjour Paf🙂,

Evidemment, c'est évident, pourquoi faire simple quand on peut faire compliqué.
Bravo!
Pour Cydor007, reprends la formule de Paf, elle est mieux adaptée et tu auras moins de soucis.

JHA

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Août 2016

• #7

Re,
Dommage ma solution ne fonctionne pas
c'est vraiment dommage

Désolé

 

Vote positif 0 Vote négatif

C

Cydor007

XLDnaute Occasionnel

• 26 Août 2016

• #8

Paf à dit:

Bonjour Cydor001, R@chid, JHA,

une autre solution:

=SOMME(C3: DECALER(C3;;;EQUIV(0;C3:C14;0)))

A+

Cliquez pour agrandir...

Super PAF!! Cela fonctionne à merveille.

Je vais faire d'autre test et je vous laisse savoir si j'ai encore un souci.

Merci

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Août 2016

• #9

Re,

Paf à dit:

=SOMME(C3: DECALER(C3;;;EQUIV(0;C3:C14;0)))

Cliquez pour agrandir...

oui bien vu, bravo..
sauf que le premier C3: est superfétatoire.

Code:

=SOMME(DECALER(C3;;;SIERREUR(EQUIV(0;C3:C14;0);LIGNES(C3:C14))))

la SIERREUR() c'est au cas où il n'y a pas de 0 dans la plage.


@ + +

 

Vote positif 0 Vote négatif

C

Cydor007

XLDnaute Occasionnel

• 26 Août 2016

• #10

Cydor007 à dit:

Super PAF!! Cela fonctionne à merveille.

Je vais faire d'autre test et je vous laisse savoir si j'ai encore un souci.

Merci

Cliquez pour agrandir...

Bonjour à tous

Après validation, j'aimerais faire le même exercice, mais cette fois ci en calculant vers le haut.
C'est à dire aditionner les valeur jusqu'à la valeur 0, en partant vers le bas (en C14).

Quelqu'un à une idée de génie?

Merci

 

Dernière édition: 26 Août 2016

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Août 2016

• #11

Bonsoir @ tous,
Cydor007 :
combien de 0 on peut trouver dans la plage ?
est-ce que c'est toujours un seul 0 ?
est-ce qu'il y a des fois où le 0 n'existe pas ?

 

Vote positif 0 Vote négatif

C

Cydor007

XLDnaute Occasionnel

• 26 Août 2016

• #12

Bonjour R@chid,
Dans ma plage il n'y a qu'un seul 0. Il n'y pas de possibilité qu'il ai plus qu'un 0.
Le 0 existe toujours dans ma plage. C'est ma référence pour compter jusqu'à la cellule où est le 0.
Merci d 'éclaircir ce point.

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

Supporter XLD

• 26 Août 2016

• #13

Re,
ok parfait,

Code:

=SOMME(DECALER(C3;EQUIV(0;C3:C14;0);;LIGNES(C3:C14)-EQUIV(0;C3:C14;0)))

Ou bien plus simple :

Code:

=SOMME(C3:C14)-SOMME(DECALER(C3;;;EQUIV(0;C3:C14;0)))

la première formule

@ + +

 

Vote positif 0 Vote négatif

C

Cydor007

XLDnaute Occasionnel

• 26 Août 2016

• #14

Excellent, cela semble fonctionner.

Je vais l'adapter à mon application et je vous laisse savoir si cela fonctionne.

Merci

 

Vote positif 0 Vote négatif

mapomme

XLDnaute Barbatruc

Supporter XLD

• 28 Août 2016

• #15

Bonjour Cydor007 ,à tous,

Bon, je m'y mets aussi 😉. Pour changer, une formule matricielle en C16 à valider par Ctrl+Maj+Entrée au lieu de la seule touche Entrée, puis, à recopier vers la droite. Cette formule exclut les erreurs véritables de la colonne.

VB:

=SOMME(SIERREUR(C3:C14*(LIGNE(C3:C14)<LIGNE(C3)-1+EQUIV(0;C3:C14;0));0))

 

Pièces jointes

• Cydor007- Test calcul des sommes variables- v1.xlsx

  38.3 KB · Affichages: 53

Dernière édition: 28 Août 2016

Vote positif 0 Vote négatif