Calcul d'une moyenne en fonction de la valeur d'une cellule

[MAZETTE]

Bonsoir,bonsoir le forum

Une petite question d'ordre technique...

Voilà j'ai une série de nombre dans la plage C2:C14 et je souhaiterai effectuer la moyenne en fonction de la valeur de A2.

Je m'explique :
si A2= 4 alors en résultat j'ai la moyenne de C2:C5
si A2= 8 alors en résultat j'ai la moyenne de C2:C9

le tous bien sur avec une formule

Une idée peut-être? Merci à vous

 

[phlaurent55]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Bonjour Mazette,

avec ceci en C14:

=SI(A2=4;MOYENNE(C2:C5);SI(A2=8;MOYENNE(C2:C9)))

à+
Philippe
.

 

[fhoest]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

bonsoir
a mettre dans la cellule que tu souhaite:

=SI(A2=4;MOYENNE(C2:C5);SI(A2=8;MOYENNE(C2:C9);""))

A+

 

[MAZETTE]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Bonsoir phlaurent55,

Merci pour ta proposition mais c'est un peu plus compliqué que cela.

En effet, la cellule A2 peux contenir par exemple une liste déroulante de 1 à 12 correspondant en fait au 12 valeur de la colonne C

Donc à tire d'exemple :

Si A2=1 alors moyenne (C2:C2)
Si A2=2 alors moyenne (C2:C3)
Si A2=3 alors moyenne ( C2:C4)

et ainsi de suite jusqu'à 12

Etant limité à 6 conditions max la formule SI ne convient pas ,peut-être passé par une matrice ou un sommeprod ou peut-etre un truc du genre

=moyenne(c2:concatener("C"&A2)) ...juste une idée mais comment l'écrire?

 

[phlaurent55]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Re,

mettre ceci en D2 et tirer la formule vers le bas

=MOYENNE($C$2:C2)

ça ne correspond pas tout à fait à tes souhaits mais ça marche

à+

 

[job75]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Bonsoir MAZETTE, le fil,

Essayez :

=SI(OU(A2<1;A2>12);"";MOYENNE(C2:DECALER(C1;A2;0)))

Edit : mieux :

=SI(OU(A2<1;A2>12);"";MOYENNE(DECALER(C2;;;A2)))

A+

 

[MAZETTE]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Bonsoir job75 et re phlaurent55

Merci à toi phlaurent55 mais la soluce de job est la plus adapté...

Toutefois une dernière question dans le cas où les premières cellules de la plage sont à zéro est-il posible de décaler la moyenne.

Je m'esplique :

Imaginons A2=4 la moyenne est faite sur C2:C5 qui ont de valeur <> de zéro

Mais imaginons toujours A2= 4 avec par exemple C2=0 est il possible de faire alors la moyenne sur C3:C5

De meme si C2=0, C3=0 avec toujours pour exemple A2=4 (où 1<A2<12) est il posible également que la moyenne soit sur la plage C4:C5 ?

 

[job75]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Re,

On ne peut plus alors utiliser la fonction MOYENNE.

Si toutes les valeurs de la plage sont des nombres, on exlut les 0 ainsi :

=SI(OU(A2<1;A2>12);"";SOMME(DECALER(C2;;;A2))/NB.SI(DECALER(C2;;;A2);"<>0"))

S'il y avait des cellules vides ou du texte, il faudrait une autre formule :

=SI(OU(A2<1;A2>12);"";SOMME(DECALER(C2;;;A2))/(NB(DECALER(C2;;;A2))-NB.SI(DECALER(C2;;;A2);0)))

A+

 

[MAZETTE]

Re : Calcul d'une moyenne en fonction de la valeur d'une cellule

Bonjour Job,

Milles excuses pour la réponse...

C'est tout à fait ça merci encore c'est super

Bonne journée