calcul d'heure d'une semaine

[ericTA]

Boujour à tous,
Voila mon PB j'ai un tableau (voir fichier joint) avec les jours de la semaine et à la dernière colonne je cherche à calculer le cumul des heures. Ca marche bien sauf pour le samedi car la fin est inférieur au début car l'heure et du jour suivant.
=SI(B9="";0;B9)-SI(A9="";0;A9)+SI(D9="";0;D9)-SI(C9="";0;C9)+SI(F9="";0;F9)-SI(E9="";0;E9)+SI(H9="";0;H9)-SI(G9="";0;G9)+SI(J9="";0;J9)-SI(I9="";0;I9)+SI(L9="";0;L9)-SI(K9="";0;MOD(K9;1))
j'ai essayé avec Mod mais ca ne marche pas .
Il y a t il une solution?

Merci d'avance.
Eric

 

[Softmama]

Re : calcul d'heure d'une semaine

Bonjour ericTA,

cette formule en O9 :

=SOMME(SI(MOD(COLONNE(B9:N9);2)=0;MOD(B9:N9-A9:M9;1);0))

Formule matricielle à valider par Ctrl+Maj+Entrée

cf. fichier joint

 

[JCGL]

Re : calcul d'heure d'une semaine

Bonjour à tous,

Peux-tu essayer en O9 et vers le bas :

=MOD(B9-A9;1)+MOD(D9-C9;1)+MOD(F9-E9;1)+MOD(H9-G9;1)+MOD(J9-I9;1)+MOD(L9-K9;1)+MOD(N9-M9;1)

Au format personnalisé :

[hh]:mm

A + à tous

 

[Monique]

Re : calcul d'heure d'une semaine

Bonjour,

Ou bien

=MOD(SOMME.SI(B$8:N$8;"fin";B9:N9)-SOMME.SI(A$8:M$8;"début";A9:M9);1)

 

[JCGL]

Re : calcul d'heure d'une semaine

Bonjour à tous,

Le comparatif ne renvoie pas les mêmes résultats.
Je pense avoir bien posé les formules proposées.

A + à tous

 

[Monique]

Re : calcul d'heure d'une semaine

Re,

Somme.Si ne fonctionne pas
Pourtant, une formule dans ce style avait fonctionné pour un fichier de Titoooooo

 

[ericTA]

Re : calcul d'heure d'une semaine

Merci ça marche super bien
Eric

 

[ericTA]

Re : calcul d'heure d'une semaine

Bonjour JCGL,
pour commencer merci pour ton aide.
Ta formule marche super bien, peux tu me dire comment traduire en VB =MOD(B9-A9;1)
Merci d'avance.
Eric

 

[Softmama]

Re : calcul d'heure d'une semaine

bonjour ericTA, et les autres,

x = (B9-A9) mod 1

 

[ericTA]

Re : calcul d'heure d'une semaine

Merci Softmama,
mais ca ne marche pas
j'ai aussi essayé Range("D9").value = (range(B9").value - range("A9").value) mod 1
mais le résultat est toujour 0
Une idée ?
Eric

 

[JCGL]

Re : calcul d'heure d'une semaine

Bonjour à tous,

Pour Monique
Ceci fonctionne pour ta formule :

=MOD(SOMME.SI(B$7:N$7;"Fin";B8:N8)-SOMME.SI(A$7:M$7;"Début";A8:M8);SI(SOMME(A8:N8)<1;1;2))

A + à tous

 

[Softmama]

Re : calcul d'heure d'une semaine

Re,

ericTa, désolé j'avais pas percuté que tu travaillais sur des heures.
Essaie ce code :

MsgBox Format(Range("B9") - Range("A9") - Int(Range("B9") - Range("A9")), "h:mm:ss")

ou encore :

MsgBox Format(Evaluate("Mod(B9-A9,1)"), "h:mm:ss")